lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use strict;
   3 use warnings;
   4
   5 use Exporter;
   6
   7 use Carp qw(confess);
   8 use B ();
   9
  10 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  11
  12 our @ISA       = qw(Exporter);
  13 our @EXPORT_OK = qw(
  14     find_meta
  15     does_role
  16     resolve_metaclass_alias
  17     apply_all_roles
  18     english_list
  19
  20     load_class
  21     is_class_loaded
  22
  23     get_linear_isa
  24     get_code_info
  25
  26     get_code_package
  27
  28     not_supported
  29
  30     does meta dump
  31     _MOUSE_VERBOSE
  32 );
  33 our %EXPORT_TAGS = (
  34     all  => \@EXPORT_OK,
  35     meta => [qw(does meta dump _MOUSE_VERBOSE)],
  36 );
  37
  38 # aliases as public APIs
  39
  40 # it must be 'require', because Mouse::Meta::Module depends on Mouse::Util
  41 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  42
  43 BEGIN {
  44     *class_of                    = \&Mouse::Meta::Module::class_of;
  45     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  46     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  47     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  48 }
  49
  50 # Moose::Util compatible utilities
  51
  52 sub find_meta{
  53     return class_of( $_[0] );
  54 }
  55
  56 sub does_role{
  57     my ($class_or_obj, $role_name) = @_;
  58
  59     my $meta = class_of($class_or_obj);
  60
  61     (defined $role_name)
  62         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  63
  64     return defined($meta) && $meta->does_role($role_name);
  65 }
  66
  67 BEGIN {
  68     my $impl;
  69     if ($] >= 5.009_005) {
  70         require mro;
  71         $impl = \&mro::get_linear_isa;
  72     } else {
  73         my $e = do {
  74             local $@;
  75             eval { require MRO::Compat };
  76             $@;
  77         };
  78         if (!$e) {
  79             $impl = \&mro::get_linear_isa;
  80         } else {
  81 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
  82             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
  83             $_get_linear_isa_dfs = sub {
  84                 no strict 'refs';
  85
  86                 my $classname = shift;
  87
  88                 my @lin = ($classname);
  89                 my %stored;
  90                 foreach my $parent (@{"$classname\::ISA"}) {
  91                     my $plin = $_get_linear_isa_dfs->($parent);
  92                     foreach  my $p(@$plin) {
  93                         next if exists $stored{$p};
  94                         push(@lin, $p);
  95                         $stored{$p} = 1;
  96                     }
  97                 }
  98                 return \@lin;
  99             };
 100 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 101             $impl = $_get_linear_isa_dfs;
 102         }
 103     }
 104
 105
 106     no warnings 'once';
 107     *get_linear_isa = $impl;
 108 }
 109
 110 { # taken from Sub::Identify
 111     sub get_code_info($) {
 112         my ($coderef) = @_;
 113         ref($coderef) or return;
 114
 115         my $cv = B::svref_2object($coderef);
 116         $cv->isa('B::CV') or return;
 117
 118         my $gv = $cv->GV;
 119         $gv->isa('B::GV') or return;
 120
 121         return ($gv->STASH->NAME, $gv->NAME);
 122     }
 123
 124     sub get_code_package{
 125         my($coderef) = @_;
 126
 127         my $cv = B::svref_2object($coderef);
 128         $cv->isa('B::CV') or return '';
 129
 130         my $gv = $cv->GV;
 131         $gv->isa('B::GV') or return '';
 132
 133         return $gv->STASH->NAME;
 134     }
 135 }
 136
 137 # taken from Mouse::Util (0.90)
 138 {
 139     my %cache;
 140
 141     sub resolve_metaclass_alias {
 142         my ( $type, $metaclass_name, %options ) = @_;
 143
 144         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 145
 146         return $cache{$cache_key}{$metaclass_name} ||= do{
 147
 148             my $possible_full_name = join '::',
 149                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 150             ;
 151
 152             my $loaded_class = load_first_existing_class(
 153                 $possible_full_name,
 154                 $metaclass_name
 155             );
 156
 157             $loaded_class->can('register_implementation')
 158                 ? $loaded_class->register_implementation
 159                 : $loaded_class;
 160         };
 161     }
 162 }
 163
 164 # Utilities from Class::MOP
 165
 166
 167 # taken from Class/MOP.pm
 168 sub is_valid_class_name {
 169     my $class = shift;
 170
 171     return 0 if ref($class);
 172     return 0 unless defined($class);
 173
 174     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 175
 176     return 0;
 177 }
 178
 179 # taken from Class/MOP.pm
 180 sub load_first_existing_class {
 181     my @classes = @_
 182       or return;
 183
 184     my %exceptions;
 185     for my $class (@classes) {
 186         my $e = _try_load_one_class($class);
 187
 188         if ($e) {
 189             $exceptions{$class} = $e;
 190         }
 191         else {
 192             return $class;
 193         }
 194     }
 195
 196     # not found
 197     confess join(
 198         "\n",
 199         map {
 200             sprintf( "Could not load class (%s) because : %s",
 201                 $_, $exceptions{$_} )
 202           } @classes
 203     );
 204 }
 205
 206 # taken from Class/MOP.pm
 207 sub _try_load_one_class {
 208     my $class = shift;
 209
 210     unless ( is_valid_class_name($class) ) {
 211         my $display = defined($class) ? $class : 'undef';
 212         confess "Invalid class name ($display)";
 213     }
 214
 215     return if is_class_loaded($class);
 216
 217     my $file = $class . '.pm';
 218     $file =~ s{::}{/}g;
 219
 220     return do {
 221         local $@;
 222         eval { require($file) };
 223         $@;
 224     };
 225 }
 226
 227
 228 sub load_class {
 229     my $class = shift;
 230     my $e = _try_load_one_class($class);
 231     confess "Could not load class ($class) because : $e" if $e;
 232
 233     return 1;
 234 }
 235
 236 my %is_class_loaded_cache;
 237 sub is_class_loaded {
 238     my $class = shift;
 239
 240     return 0 if ref($class) || !defined($class) || !length($class);
 241
 242     return 1 if $is_class_loaded_cache{$class};
 243
 244     # walk the symbol table tree to avoid autovififying
 245     # \*{${main::}{"Foo::"}} == \*main::Foo::
 246
 247     my $pack = \%::;
 248     foreach my $part (split('::', $class)) {
 249         my $entry = \$pack->{$part . '::'};
 250         return 0 if ref($entry) ne 'GLOB';
 251         $pack = *{$entry}{HASH} or return 0;
 252     }
 253
 254     # check for $VERSION or @ISA
 255     return ++$is_class_loaded_cache{$class} if exists $pack->{VERSION}
 256              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
 257     return ++$is_class_loaded_cache{$class} if exists $pack->{ISA}
 258              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
 259
 260     # check for any method
 261     foreach my $name( keys %{$pack} ) {
 262         my $entry = \$pack->{$name};
 263         return ++$is_class_loaded_cache{$class} if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
 264     }
 265
 266     # fail
 267     return 0;
 268 }
 269
 270
 271 sub apply_all_roles {
 272     my $meta = Mouse::Meta::Class->initialize(shift);
 273
 274     my @roles;
 275
 276     # Basis of Data::OptList
 277     my $max = scalar(@_);
 278     for (my $i = 0; $i < $max ; $i++) {
 279         if ($i + 1 < $max && ref($_[$i + 1])) {
 280             push @roles, [ $_[$i++] => $_[$i] ];
 281         } else {
 282             push @roles, [ $_[$i]   => undef ];
 283         }
 284         my $role_name = $roles[-1][0];
 285         load_class($role_name);
 286         ( $role_name->can('meta') && $role_name->meta->isa('Mouse::Meta::Role') )
 287             || $meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 288     }
 289
 290     if ( scalar @roles == 1 ) {
 291         my ( $role, $params ) = @{ $roles[0] };
 292         $role->meta->apply( $meta, ( defined $params ? %$params : () ) );
 293     }
 294     else {
 295         Mouse::Meta::Role->combine_apply($meta, @roles);
 296     }
 297     return;
 298 }
 299
 300 # taken from Moose::Util 0.90
 301 sub english_list {
 302     return $_[0] if @_ == 1;
 303
 304     my @items = sort @_;
 305
 306     return "$items[0] and $items[1]" if @items == 2;
 307
 308     my $tail = pop @items;
 309
 310     return join q{, }, @items, "and $tail";
 311 }
 312
 313
 314 # common utilities
 315
 316 sub not_supported{
 317     my($feature) = @_;
 318
 319     $feature ||= ( caller(1) )[3]; # subroutine name
 320
 321     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 322     Carp::confess("Mouse does not currently support $feature");
 323 }
 324
 325 sub meta{
 326     return Mouse::Meta::Class->initialize($_[0]);
 327 }
 328
 329 sub dump {
 330     my($self, $maxdepth) = @_;
 331
 332     require 'Data/Dumper.pm'; # we don't want to create its namespace
 333     my $dd = Data::Dumper->new([$self]);
 334     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 335     $dd->Indent(1);
 336     return $dd->Dump();
 337 }
 338
 339 sub does :method;
 340 *does = \&does_role; # alias
 341
 342 1;
 343
 344 __END__
 345
 346 =head1 NAME
 347
 348 Mouse::Util - Features, with or without their dependencies
 349
 350 =head1 IMPLEMENTATIONS FOR
 351
 352 =head2 Moose::Util
 353
 354 =head3 C<find_meta>
 355
 356 =head3 C<does_role>
 357
 358 =head3 C<resolve_metaclass_alias>
 359
 360 =head3 C<apply_all_roles>
 361
 362 =head3 C<english_list>
 363
 364 =head2 Class::MOP
 365
 366 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 367
 368 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 369 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 370 locally-defined method.
 371
 372 =head3 C<< load_class(ClassName) >>
 373
 374 This will load a given C<ClassName> (or die if it is not loadable).
 375 This function can be used in place of tricks like
 376 C<eval "use $module"> or using C<require>.
 377
 378 =head2 C<< Mouse::Util::class_of(ClassName) >>
 379
 380 The counterpart of C<Class::MOP::class_of()>. This is not exportable.
 381
 382 =head2 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 383
 384 The counterpart of C<Class::MOP::get_metaclass_by_name()>. This is not exportable.
 385
 386 =head2 MRO::Compat
 387
 388 =head3 C<get_linear_isa>
 389
 390 =head2 Sub::Identify
 391
 392 =head3 C<get_code_info>
 393
 394 =head1 UTILITIES FOR MOUSE
 395
 396 =head3 C<not_supported>
 397
 398 =head1 SEE ALSO
 399
 400 L<Moose::Util>
 401
 402 L<Scalar::Util>
 403
 404 L<Sub::Identify>
 405
 406 L<MRO::Compat>
 407
 408 =cut
 409