lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.40_08';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         local $@;
  47
  48         # XXX: XSLoader tries to get the object path from caller's file name
  49         #      $hack_mouse_file fools its mechanism
  50
  51         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  52         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  53             require XSLoader;
  54             XSLoader::load('Mouse', $VERSION);
  55
  56             *Mouse::Meta::Method::Constructor::XS::meta = \&meta;
  57             *Mouse::Meta::Method::Destructor::XS::meta  = \&meta;
  58         };
  59         #warn $@ if $@;
  60     }
  61
  62     if(!$xs){
  63         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  64     }
  65
  66     *MOUSE_XS = sub(){ $xs };
  67 }
  68
  69
  70 use Carp         ();
  71 use Scalar::Util ();
  72
  73 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  74
  75 # aliases as public APIs
  76 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  77 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  78
  79 BEGIN {
  80     *class_of                    = \&Mouse::Meta::Module::_class_of;
  81     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  82     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  83     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  84
  85     # is-a predicates
  86     generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  87     generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  88     generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  89 }
  90
  91 our $in_global_destruction = 0;
  92 END{ $in_global_destruction = 1 }
  93
  94 # Moose::Util compatible utilities
  95
  96 sub find_meta{
  97     return class_of( $_[0] );
  98 }
  99
 100 sub does_role{
 101     my ($class_or_obj, $role_name) = @_;
 102
 103     my $meta = class_of($class_or_obj);
 104
 105     (defined $role_name)
 106         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 107
 108     return defined($meta) && $meta->does_role($role_name);
 109 }
 110
 111 BEGIN {
 112     my $get_linear_isa;
 113     if ($] >= 5.009_005) {
 114         require mro;
 115         $get_linear_isa = \&mro::get_linear_isa;
 116     } else {
 117         my $e = do {
 118             local $@;
 119             eval { require MRO::Compat };
 120             $@;
 121         };
 122         if (!$e) {
 123             $get_linear_isa = \&mro::get_linear_isa;
 124         } else {
 125 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 126             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 127             $_get_linear_isa_dfs = sub ($;$){
 128                 no strict 'refs';
 129
 130                 my $classname = shift;
 131
 132                 my @lin = ($classname);
 133                 my %stored;
 134                 foreach my $parent (@{"$classname\::ISA"}) {
 135                     my $plin = $_get_linear_isa_dfs->($parent);
 136                     foreach  my $p(@$plin) {
 137                         next if exists $stored{$p};
 138                         push(@lin, $p);
 139                         $stored{$p} = 1;
 140                     }
 141                 }
 142                 return \@lin;
 143             };
 144 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 145             $get_linear_isa = $_get_linear_isa_dfs;
 146         }
 147     }
 148
 149     *get_linear_isa = $get_linear_isa;
 150 }
 151
 152
 153 # taken from Mouse::Util (0.90)
 154 {
 155     my %cache;
 156
 157     sub resolve_metaclass_alias {
 158         my ( $type, $metaclass_name, %options ) = @_;
 159
 160         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 161
 162         return $cache{$cache_key}{$metaclass_name} ||= do{
 163
 164             my $possible_full_name = join '::',
 165                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 166             ;
 167
 168             my $loaded_class = load_first_existing_class(
 169                 $possible_full_name,
 170                 $metaclass_name
 171             );
 172
 173             $loaded_class->can('register_implementation')
 174                 ? $loaded_class->register_implementation
 175                 : $loaded_class;
 176         };
 177     }
 178 }
 179
 180 # Utilities from Class::MOP
 181
 182 sub get_code_info;
 183 sub get_code_package;
 184
 185 # taken from Class/MOP.pm
 186 sub is_valid_class_name {
 187     my $class = shift;
 188
 189     return 0 if ref($class);
 190     return 0 unless defined($class);
 191
 192     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 193
 194     return 0;
 195 }
 196
 197 # taken from Class/MOP.pm
 198 sub load_first_existing_class {
 199     my @classes = @_
 200       or return;
 201
 202     my %exceptions;
 203     for my $class (@classes) {
 204         my $e = _try_load_one_class($class);
 205
 206         if ($e) {
 207             $exceptions{$class} = $e;
 208         }
 209         else {
 210             return $class;
 211         }
 212     }
 213
 214     # not found
 215     Carp::confess join(
 216         "\n",
 217         map {
 218             sprintf( "Could not load class (%s) because : %s",
 219                 $_, $exceptions{$_} )
 220           } @classes
 221     );
 222 }
 223
 224 # taken from Class/MOP.pm
 225 my %is_class_loaded_cache;
 226 sub _try_load_one_class {
 227     my $class = shift;
 228
 229     unless ( is_valid_class_name($class) ) {
 230         my $display = defined($class) ? $class : 'undef';
 231         Carp::confess "Invalid class name ($display)";
 232     }
 233
 234     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 235
 236     my $file = $class . '.pm';
 237     $file =~ s{::}{/}g;
 238
 239     return do {
 240         local $@;
 241         eval { require($file) };
 242         $@;
 243     };
 244 }
 245
 246
 247 sub load_class {
 248     my $class = shift;
 249     my $e = _try_load_one_class($class);
 250     Carp::confess "Could not load class ($class) because : $e" if $e;
 251
 252     return 1;
 253 }
 254
 255 sub is_class_loaded;
 256
 257
 258 sub apply_all_roles {
 259     my $applicant = Scalar::Util::blessed($_[0])
 260         ?                                shift   # instance
 261         : Mouse::Meta::Class->initialize(shift); # class or role name
 262
 263     my @roles;
 264
 265     # Basis of Data::OptList
 266     my $max = scalar(@_);
 267     for (my $i = 0; $i < $max ; $i++) {
 268         if ($i + 1 < $max && ref($_[$i + 1])) {
 269             push @roles, [ $_[$i] => $_[++$i] ];
 270         } else {
 271             push @roles, [ $_[$i] => undef ];
 272         }
 273         my $role_name = $roles[-1][0];
 274         load_class($role_name);
 275
 276         is_a_metarole( get_metaclass_by_name($role_name) )
 277             || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 278     }
 279
 280     if ( scalar @roles == 1 ) {
 281         my ( $role_name, $params ) = @{ $roles[0] };
 282         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 283     }
 284     else {
 285         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 286     }
 287     return;
 288 }
 289
 290 # taken from Moose::Util 0.90
 291 sub english_list {
 292     return $_[0] if @_ == 1;
 293
 294     my @items = sort @_;
 295
 296     return "$items[0] and $items[1]" if @items == 2;
 297
 298     my $tail = pop @items;
 299
 300     return join q{, }, @items, "and $tail";
 301 }
 302
 303
 304 # common utilities
 305
 306 sub not_supported{
 307     my($feature) = @_;
 308
 309     $feature ||= ( caller(1) )[3]; # subroutine name
 310
 311     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 312     Carp::confess("Mouse does not currently support $feature");
 313 }
 314
 315 # general meta() method
 316 sub meta :method{
 317     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 318 }
 319
 320 # general dump() method
 321 sub dump :method {
 322     my($self, $maxdepth) = @_;
 323
 324     require 'Data/Dumper.pm'; # we don't want to create its namespace
 325     my $dd = Data::Dumper->new([$self]);
 326     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 327     $dd->Indent(1);
 328     return $dd->Dump();
 329 }
 330
 331 # general does() method
 332 sub does :method;
 333 *does = \&does_role; # alias
 334
 335 1;
 336
 337 __END__
 338
 339 =head1 NAME
 340
 341 Mouse::Util - Features, with or without their dependencies
 342
 343 =head1 VERSION
 344
 345 This document describes Mouse version 0.40_08
 346
 347 =head1 IMPLEMENTATIONS FOR
 348
 349 =head2 Moose::Util
 350
 351 =head3 C<find_meta>
 352
 353 =head3 C<does_role>
 354
 355 =head3 C<resolve_metaclass_alias>
 356
 357 =head3 C<apply_all_roles>
 358
 359 =head3 C<english_list>
 360
 361 =head2 Class::MOP
 362
 363 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 364
 365 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 366 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 367 locally-defined method.
 368
 369 =head3 C<< load_class(ClassName) >>
 370
 371 This will load a given C<ClassName> (or die if it is not loadable).
 372 This function can be used in place of tricks like
 373 C<eval "use $module"> or using C<require>.
 374
 375 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 376
 377 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 378
 379 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 380
 381 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 382
 383 =head2 MRO::Compat
 384
 385 =head3 C<get_linear_isa>
 386
 387 =head2 Sub::Identify
 388
 389 =head3 C<get_code_info>
 390
 391 =head1 UTILITIES FOR MOUSE
 392
 393 =head3 C<not_supported>
 394
 395 =head1 SEE ALSO
 396
 397 L<Moose::Util>
 398
 399 L<Class::MOP>
 400
 401 L<Sub::Identify>
 402
 403 L<MRO::Compat>
 404
 405 =cut
 406