lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.40_08';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         local $@;
  47
  48         # XXX: XSLoader tries to get the object path from caller's file name
  49         #      $hack_mouse_file fools its mechanism
  50
  51         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  52         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  53             require XSLoader;
  54             XSLoader::load('Mouse', $VERSION);
  55             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  56             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  57             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  58             return 1;
  59         };
  60         #warn $@ if $@;
  61     }
  62
  63     if(!$xs){
  64         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  65     }
  66
  67     *MOUSE_XS = sub(){ $xs };
  68 }
  69
  70
  71 use Carp         ();
  72 use Scalar::Util ();
  73
  74 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  75
  76 # aliases as public APIs
  77 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  78 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  79
  80 BEGIN {
  81     *class_of                    = \&Mouse::Meta::Module::_class_of;
  82     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  83     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  84     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  85
  86     # is-a predicates
  87     generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  88     generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  89     generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  90 }
  91
  92 our $in_global_destruction = 0;
  93 END{ $in_global_destruction = 1 }
  94
  95 # Moose::Util compatible utilities
  96
  97 sub find_meta{
  98     return class_of( $_[0] );
  99 }
 100
 101 sub does_role{
 102     my ($class_or_obj, $role_name) = @_;
 103
 104     my $meta = class_of($class_or_obj);
 105
 106     (defined $role_name)
 107         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 108
 109     return defined($meta) && $meta->does_role($role_name);
 110 }
 111
 112 BEGIN {
 113     my $get_linear_isa;
 114     if ($] >= 5.009_005) {
 115         require mro;
 116         $get_linear_isa = \&mro::get_linear_isa;
 117     } else {
 118         my $e = do {
 119             local $@;
 120             eval { require MRO::Compat };
 121             $@;
 122         };
 123         if (!$e) {
 124             $get_linear_isa = \&mro::get_linear_isa;
 125         } else {
 126 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 127             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 128             $_get_linear_isa_dfs = sub ($;$){
 129                 no strict 'refs';
 130
 131                 my $classname = shift;
 132
 133                 my @lin = ($classname);
 134                 my %stored;
 135                 foreach my $parent (@{"$classname\::ISA"}) {
 136                     my $plin = $_get_linear_isa_dfs->($parent);
 137                     foreach  my $p(@$plin) {
 138                         next if exists $stored{$p};
 139                         push(@lin, $p);
 140                         $stored{$p} = 1;
 141                     }
 142                 }
 143                 return \@lin;
 144             };
 145 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 146             $get_linear_isa = $_get_linear_isa_dfs;
 147         }
 148     }
 149
 150     *get_linear_isa = $get_linear_isa;
 151 }
 152
 153
 154 # taken from Mouse::Util (0.90)
 155 {
 156     my %cache;
 157
 158     sub resolve_metaclass_alias {
 159         my ( $type, $metaclass_name, %options ) = @_;
 160
 161         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 162
 163         return $cache{$cache_key}{$metaclass_name} ||= do{
 164
 165             my $possible_full_name = join '::',
 166                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 167             ;
 168
 169             my $loaded_class = load_first_existing_class(
 170                 $possible_full_name,
 171                 $metaclass_name
 172             );
 173
 174             $loaded_class->can('register_implementation')
 175                 ? $loaded_class->register_implementation
 176                 : $loaded_class;
 177         };
 178     }
 179 }
 180
 181 # Utilities from Class::MOP
 182
 183 sub get_code_info;
 184 sub get_code_package;
 185
 186 # taken from Class/MOP.pm
 187 sub is_valid_class_name {
 188     my $class = shift;
 189
 190     return 0 if ref($class);
 191     return 0 unless defined($class);
 192
 193     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 194
 195     return 0;
 196 }
 197
 198 # taken from Class/MOP.pm
 199 sub load_first_existing_class {
 200     my @classes = @_
 201       or return;
 202
 203     my %exceptions;
 204     for my $class (@classes) {
 205         my $e = _try_load_one_class($class);
 206
 207         if ($e) {
 208             $exceptions{$class} = $e;
 209         }
 210         else {
 211             return $class;
 212         }
 213     }
 214
 215     # not found
 216     Carp::confess join(
 217         "\n",
 218         map {
 219             sprintf( "Could not load class (%s) because : %s",
 220                 $_, $exceptions{$_} )
 221           } @classes
 222     );
 223 }
 224
 225 # taken from Class/MOP.pm
 226 my %is_class_loaded_cache;
 227 sub _try_load_one_class {
 228     my $class = shift;
 229
 230     unless ( is_valid_class_name($class) ) {
 231         my $display = defined($class) ? $class : 'undef';
 232         Carp::confess "Invalid class name ($display)";
 233     }
 234
 235     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 236
 237     my $file = $class . '.pm';
 238     $file =~ s{::}{/}g;
 239
 240     return do {
 241         local $@;
 242         eval { require($file) };
 243         $@;
 244     };
 245 }
 246
 247
 248 sub load_class {
 249     my $class = shift;
 250     my $e = _try_load_one_class($class);
 251     Carp::confess "Could not load class ($class) because : $e" if $e;
 252
 253     return 1;
 254 }
 255
 256 sub is_class_loaded;
 257
 258
 259 sub apply_all_roles {
 260     my $applicant = Scalar::Util::blessed($_[0])
 261         ?                                shift   # instance
 262         : Mouse::Meta::Class->initialize(shift); # class or role name
 263
 264     my @roles;
 265
 266     # Basis of Data::OptList
 267     my $max = scalar(@_);
 268     for (my $i = 0; $i < $max ; $i++) {
 269         if ($i + 1 < $max && ref($_[$i + 1])) {
 270             push @roles, [ $_[$i] => $_[++$i] ];
 271         } else {
 272             push @roles, [ $_[$i] => undef ];
 273         }
 274         my $role_name = $roles[-1][0];
 275         load_class($role_name);
 276
 277         is_a_metarole( get_metaclass_by_name($role_name) )
 278             || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 279     }
 280
 281     if ( scalar @roles == 1 ) {
 282         my ( $role_name, $params ) = @{ $roles[0] };
 283         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 284     }
 285     else {
 286         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 287     }
 288     return;
 289 }
 290
 291 # taken from Moose::Util 0.90
 292 sub english_list {
 293     return $_[0] if @_ == 1;
 294
 295     my @items = sort @_;
 296
 297     return "$items[0] and $items[1]" if @items == 2;
 298
 299     my $tail = pop @items;
 300
 301     return join q{, }, @items, "and $tail";
 302 }
 303
 304
 305 # common utilities
 306
 307 sub not_supported{
 308     my($feature) = @_;
 309
 310     $feature ||= ( caller(1) )[3]; # subroutine name
 311
 312     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 313     Carp::confess("Mouse does not currently support $feature");
 314 }
 315
 316 # general meta() method
 317 sub meta :method{
 318     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 319 }
 320
 321 # general dump() method
 322 sub dump :method {
 323     my($self, $maxdepth) = @_;
 324
 325     require 'Data/Dumper.pm'; # we don't want to create its namespace
 326     my $dd = Data::Dumper->new([$self]);
 327     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 328     $dd->Indent(1);
 329     return $dd->Dump();
 330 }
 331
 332 # general does() method
 333 sub does :method;
 334 *does = \&does_role; # alias
 335
 336 1;
 337
 338 __END__
 339
 340 =head1 NAME
 341
 342 Mouse::Util - Features, with or without their dependencies
 343
 344 =head1 VERSION
 345
 346 This document describes Mouse version 0.40_08
 347
 348 =head1 IMPLEMENTATIONS FOR
 349
 350 =head2 Moose::Util
 351
 352 =head3 C<find_meta>
 353
 354 =head3 C<does_role>
 355
 356 =head3 C<resolve_metaclass_alias>
 357
 358 =head3 C<apply_all_roles>
 359
 360 =head3 C<english_list>
 361
 362 =head2 Class::MOP
 363
 364 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 365
 366 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 367 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 368 locally-defined method.
 369
 370 =head3 C<< load_class(ClassName) >>
 371
 372 This will load a given C<ClassName> (or die if it is not loadable).
 373 This function can be used in place of tricks like
 374 C<eval "use $module"> or using C<require>.
 375
 376 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 377
 378 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 379
 380 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 381
 382 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 383
 384 =head2 MRO::Compat
 385
 386 =head3 C<get_linear_isa>
 387
 388 =head2 Sub::Identify
 389
 390 =head3 C<get_code_info>
 391
 392 =head1 UTILITIES FOR MOUSE
 393
 394 =head3 C<not_supported>
 395
 396 =head1 SEE ALSO
 397
 398 L<Moose::Util>
 399
 400 L<Class::MOP>
 401
 402 L<Sub::Identify>
 403
 404 L<MRO::Compat>
 405
 406 =cut
 407