lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use strict;
   3 use warnings;
   4
   5 use Exporter;
   6
   7 use Carp qw(confess);
   8 use B ();
   9
  10 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  11
  12 our @ISA       = qw(Exporter);
  13 our @EXPORT_OK = qw(
  14     find_meta
  15     does_role
  16     resolve_metaclass_alias
  17     apply_all_roles
  18     english_list
  19
  20     load_class
  21     is_class_loaded
  22
  23     get_linear_isa
  24     get_code_info
  25
  26     get_code_package
  27
  28     not_supported
  29
  30     does meta dump
  31     _MOUSE_VERBOSE
  32 );
  33 our %EXPORT_TAGS = (
  34     all  => \@EXPORT_OK,
  35     meta => [qw(does meta dump _MOUSE_VERBOSE)],
  36 );
  37
  38 # aliases as public APIs
  39
  40 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  41 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  42
  43 BEGIN {
  44     *class_of                    = \&Mouse::Meta::Module::class_of;
  45     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  46     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  47     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  48 }
  49
  50 # Moose::Util compatible utilities
  51
  52 sub find_meta{
  53     return class_of( $_[0] );
  54 }
  55
  56 sub does_role{
  57     my ($class_or_obj, $role_name) = @_;
  58
  59     my $meta = class_of($class_or_obj);
  60
  61     (defined $role_name)
  62         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  63
  64     return defined($meta) && $meta->does_role($role_name);
  65 }
  66
  67 BEGIN {
  68     my $impl;
  69     if ($] >= 5.009_005) {
  70         require mro;
  71         $impl = \&mro::get_linear_isa;
  72     } else {
  73         my $e = do {
  74             local $@;
  75             eval { require MRO::Compat };
  76             $@;
  77         };
  78         if (!$e) {
  79             $impl = \&mro::get_linear_isa;
  80         } else {
  81 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
  82             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
  83             $_get_linear_isa_dfs = sub {
  84                 no strict 'refs';
  85
  86                 my $classname = shift;
  87
  88                 my @lin = ($classname);
  89                 my %stored;
  90                 foreach my $parent (@{"$classname\::ISA"}) {
  91                     my $plin = $_get_linear_isa_dfs->($parent);
  92                     foreach  my $p(@$plin) {
  93                         next if exists $stored{$p};
  94                         push(@lin, $p);
  95                         $stored{$p} = 1;
  96                     }
  97                 }
  98                 return \@lin;
  99             };
 100 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 101             $impl = $_get_linear_isa_dfs;
 102         }
 103     }
 104
 105
 106     no warnings 'once';
 107     *get_linear_isa = $impl;
 108 }
 109
 110 { # taken from Sub::Identify
 111     sub get_code_info($) {
 112         my ($coderef) = @_;
 113         ref($coderef) or return;
 114
 115         my $cv = B::svref_2object($coderef);
 116         $cv->isa('B::CV') or return;
 117
 118         my $gv = $cv->GV;
 119         $gv->isa('B::GV') or return;
 120
 121         return ($gv->STASH->NAME, $gv->NAME);
 122     }
 123
 124     sub get_code_package{
 125         my($coderef) = @_;
 126
 127         my $cv = B::svref_2object($coderef);
 128         $cv->isa('B::CV') or return '';
 129
 130         my $gv = $cv->GV;
 131         $gv->isa('B::GV') or return '';
 132
 133         return $gv->STASH->NAME;
 134     }
 135 }
 136
 137 # taken from Mouse::Util (0.90)
 138 {
 139     my %cache;
 140
 141     sub resolve_metaclass_alias {
 142         my ( $type, $metaclass_name, %options ) = @_;
 143
 144         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 145
 146         return $cache{$cache_key}{$metaclass_name} ||= do{
 147
 148             my $possible_full_name = join '::',
 149                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 150             ;
 151
 152             my $loaded_class = load_first_existing_class(
 153                 $possible_full_name,
 154                 $metaclass_name
 155             );
 156
 157             $loaded_class->can('register_implementation')
 158                 ? $loaded_class->register_implementation
 159                 : $loaded_class;
 160         };
 161     }
 162 }
 163
 164 # Utilities from Class::MOP
 165
 166
 167 # taken from Class/MOP.pm
 168 sub is_valid_class_name {
 169     my $class = shift;
 170
 171     return 0 if ref($class);
 172     return 0 unless defined($class);
 173
 174     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 175
 176     return 0;
 177 }
 178
 179 # taken from Class/MOP.pm
 180 sub load_first_existing_class {
 181     my @classes = @_
 182       or return;
 183
 184     my %exceptions;
 185     for my $class (@classes) {
 186         my $e = _try_load_one_class($class);
 187
 188         if ($e) {
 189             $exceptions{$class} = $e;
 190         }
 191         else {
 192             return $class;
 193         }
 194     }
 195
 196     # not found
 197     confess join(
 198         "\n",
 199         map {
 200             sprintf( "Could not load class (%s) because : %s",
 201                 $_, $exceptions{$_} )
 202           } @classes
 203     );
 204 }
 205
 206 # taken from Class/MOP.pm
 207 my %is_class_loaded_cache;
 208 sub _try_load_one_class {
 209     my $class = shift;
 210
 211     unless ( is_valid_class_name($class) ) {
 212         my $display = defined($class) ? $class : 'undef';
 213         confess "Invalid class name ($display)";
 214     }
 215
 216     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 217
 218     my $file = $class . '.pm';
 219     $file =~ s{::}{/}g;
 220
 221     return do {
 222         local $@;
 223         eval { require($file) };
 224         $@;
 225     };
 226 }
 227
 228
 229 sub load_class {
 230     my $class = shift;
 231     my $e = _try_load_one_class($class);
 232     confess "Could not load class ($class) because : $e" if $e;
 233
 234     return 1;
 235 }
 236
 237
 238 sub is_class_loaded {
 239     my $class = shift;
 240
 241     return 0 if ref($class) || !defined($class) || !length($class);
 242
 243     # walk the symbol table tree to avoid autovififying
 244     # \*{${main::}{"Foo::"}} == \*main::Foo::
 245
 246     my $pack = \%::;
 247     foreach my $part (split('::', $class)) {
 248         my $entry = \$pack->{$part . '::'};
 249         return 0 if ref($entry) ne 'GLOB';
 250         $pack = *{$entry}{HASH} or return 0;
 251     }
 252
 253     # check for $VERSION or @ISA
 254     return 1 if exists $pack->{VERSION}
 255              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
 256     return 1 if exists $pack->{ISA}
 257              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
 258
 259     # check for any method
 260     foreach my $name( keys %{$pack} ) {
 261         my $entry = \$pack->{$name};
 262         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
 263     }
 264
 265     # fail
 266     return 0;
 267 }
 268
 269
 270 sub apply_all_roles {
 271     my $meta = Mouse::Meta::Class->initialize(shift);
 272
 273     my @roles;
 274
 275     # Basis of Data::OptList
 276     my $max = scalar(@_);
 277     for (my $i = 0; $i < $max ; $i++) {
 278         if ($i + 1 < $max && ref($_[$i + 1])) {
 279             push @roles, [ $_[$i++] => $_[$i] ];
 280         } else {
 281             push @roles, [ $_[$i]   => undef ];
 282         }
 283         my $role_name = $roles[-1][0];
 284         load_class($role_name);
 285         ( $role_name->can('meta') && $role_name->meta->isa('Mouse::Meta::Role') )
 286             || $meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 287     }
 288
 289     if ( scalar @roles == 1 ) {
 290         my ( $role, $params ) = @{ $roles[0] };
 291         $role->meta->apply( $meta, ( defined $params ? %$params : () ) );
 292     }
 293     else {
 294         Mouse::Meta::Role->combine_apply($meta, @roles);
 295     }
 296     return;
 297 }
 298
 299 # taken from Moose::Util 0.90
 300 sub english_list {
 301     return $_[0] if @_ == 1;
 302
 303     my @items = sort @_;
 304
 305     return "$items[0] and $items[1]" if @items == 2;
 306
 307     my $tail = pop @items;
 308
 309     return join q{, }, @items, "and $tail";
 310 }
 311
 312
 313 # common utilities
 314
 315 sub not_supported{
 316     my($feature) = @_;
 317
 318     $feature ||= ( caller(1) )[3]; # subroutine name
 319
 320     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 321     Carp::confess("Mouse does not currently support $feature");
 322 }
 323
 324 sub meta{
 325     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 326 }
 327
 328 sub dump {
 329     my($self, $maxdepth) = @_;
 330
 331     require 'Data/Dumper.pm'; # we don't want to create its namespace
 332     my $dd = Data::Dumper->new([$self]);
 333     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 334     $dd->Indent(1);
 335     return $dd->Dump();
 336 }
 337
 338 sub does :method;
 339 *does = \&does_role; # alias
 340
 341 1;
 342
 343 __END__
 344
 345 =head1 NAME
 346
 347 Mouse::Util - Features, with or without their dependencies
 348
 349 =head1 IMPLEMENTATIONS FOR
 350
 351 =head2 Moose::Util
 352
 353 =head3 C<find_meta>
 354
 355 =head3 C<does_role>
 356
 357 =head3 C<resolve_metaclass_alias>
 358
 359 =head3 C<apply_all_roles>
 360
 361 =head3 C<english_list>
 362
 363 =head2 Class::MOP
 364
 365 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 366
 367 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 368 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 369 locally-defined method.
 370
 371 =head3 C<< load_class(ClassName) >>
 372
 373 This will load a given C<ClassName> (or die if it is not loadable).
 374 This function can be used in place of tricks like
 375 C<eval "use $module"> or using C<require>.
 376
 377 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 378
 379 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 380
 381 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 382
 383 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 384
 385 =head2 MRO::Compat
 386
 387 =head3 C<get_linear_isa>
 388
 389 =head2 Sub::Identify
 390
 391 =head3 C<get_code_info>
 392
 393 =head1 UTILITIES FOR MOUSE
 394
 395 =head3 C<not_supported>
 396
 397 =head1 SEE ALSO
 398
 399 L<Moose::Util>
 400
 401 L<Class::MOP>
 402
 403 L<Sub::Identify>
 404
 405 L<MRO::Compat>
 406
 407 =cut
 408