lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 sub install_subroutines { # must be here
   7     my $into = shift;
   8
   9     while(my($name, $code) = splice @_, 0, 2){
  10         no strict 'refs';
  11         no warnings 'once', 'redefine';
  12         use warnings FATAL => 'uninitialized';
  13         *{$into . '::' . $name} = \&{$code};
  14     }
  15     return;
  16 }
  17
  18 BEGIN{
  19     # This is used in Mouse::PurePerl
  20     Mouse::Exporter->setup_import_methods(
  21         as_is => [qw(
  22             find_meta
  23             does_role
  24             resolve_metaclass_alias
  25             apply_all_roles
  26             english_list
  27
  28             load_class
  29             is_class_loaded
  30
  31             get_linear_isa
  32             get_code_info
  33
  34             get_code_package
  35             get_code_ref
  36
  37             not_supported
  38
  39             does meta dump
  40         )],
  41         groups => {
  42             default => [], # export no functions by default
  43
  44             # The ':meta' group is 'use metaclass' for Mouse
  45             meta    => [qw(does meta dump)],
  46         },
  47     );
  48
  49
  50     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  51     # XS loader is placed here, not in Mouse.pm.
  52
  53     our $VERSION = '0.50_03';
  54
  55     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  56
  57     if($xs){
  58         # XXX: XSLoader tries to get the object path from caller's file name
  59         #      $hack_mouse_file fools its mechanism
  60
  61         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  62         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  63             require XSLoader;
  64             XSLoader::load('Mouse', $VERSION);
  65             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  66             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  67             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  68             return 1;
  69         } || 0;
  70         #warn $@ if $@;
  71     }
  72
  73     if(!$xs){
  74         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  75     }
  76
  77     *MOUSE_XS = sub(){ $xs };
  78 }
  79
  80 use Carp         ();
  81 use Scalar::Util ();
  82
  83 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  84
  85 # aliases as public APIs
  86 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  87 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  88
  89 # aliases
  90 {
  91     *class_of                    = \&Mouse::Meta::Module::_class_of;
  92     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  93     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  94     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  95
  96     *Mouse::load_class           = \&load_class;
  97     *Mouse::is_class_loaded      = \&is_class_loaded;
  98
  99     # is-a predicates
 100     #generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
 101     #generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
 102     #generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
 103
 104     # duck type predicates
 105     generate_can_predicate_for(['_compiled_type_constraint']  => 'is_a_type_constraint');
 106     generate_can_predicate_for(['create_anon_class']          => 'is_a_metaclass');
 107     generate_can_predicate_for(['create_anon_role']           => 'is_a_metarole');
 108 }
 109
 110 our $in_global_destruction = 0;
 111 END{ $in_global_destruction = 1 }
 112
 113 # Moose::Util compatible utilities
 114
 115 sub find_meta{
 116     return class_of( $_[0] );
 117 }
 118
 119 sub does_role{
 120     my ($class_or_obj, $role_name) = @_;
 121
 122     my $meta = class_of($class_or_obj);
 123
 124     (defined $role_name)
 125         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 126
 127     return defined($meta) && $meta->does_role($role_name);
 128 }
 129
 130 BEGIN {
 131     my $get_linear_isa;
 132     if ($] >= 5.009_005) {
 133         require mro;
 134         $get_linear_isa = \&mro::get_linear_isa;
 135     } else {
 136         # this code is based on MRO::Compat::__get_linear_isa
 137         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 138         $_get_linear_isa_dfs = sub {
 139             my($classname) = @_;
 140
 141             my @lin = ($classname);
 142             my %stored;
 143
 144             no strict 'refs';
 145             foreach my $parent (@{"$classname\::ISA"}) {
 146                 foreach  my $p(@{ $_get_linear_isa_dfs->($parent) }) {
 147                     next if exists $stored{$p};
 148                     push(@lin, $p);
 149                     $stored{$p} = 1;
 150                 }
 151             }
 152             return \@lin;
 153         };
 154
 155         {
 156             package # hide from PAUSE
 157                 Class::C3;
 158             our %MRO; # work around 'once' warnings
 159         }
 160
 161         # MRO::Compat::__get_linear_isa has no prototype, so
 162         # we define a prototyped version for compatibility with core's
 163         # See also MRO::Compat::__get_linear_isa.
 164         $get_linear_isa = sub ($;$){
 165             my($classname, $type) = @_;
 166
 167             if(!defined $type){
 168                 $type = exists $Class::C3::MRO{$classname} ? 'c3' : 'dfs';
 169             }
 170             if($type eq 'c3'){
 171                 require Class::C3;
 172                 return [Class::C3::calculateMRO($classname)];
 173             }
 174             else{
 175                 return $_get_linear_isa_dfs->($classname);
 176             }
 177         };
 178     }
 179
 180     *get_linear_isa = $get_linear_isa;
 181 }
 182
 183
 184 # taken from Mouse::Util (0.90)
 185 {
 186     my %cache;
 187
 188     sub resolve_metaclass_alias {
 189         my ( $type, $metaclass_name, %options ) = @_;
 190
 191         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 192
 193         return $cache{$cache_key}{$metaclass_name} ||= do{
 194
 195             my $possible_full_name = join '::',
 196                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 197             ;
 198
 199             my $loaded_class = load_first_existing_class(
 200                 $possible_full_name,
 201                 $metaclass_name
 202             );
 203
 204             $loaded_class->can('register_implementation')
 205                 ? $loaded_class->register_implementation
 206                 : $loaded_class;
 207         };
 208     }
 209 }
 210
 211 # Utilities from Class::MOP
 212
 213 sub get_code_info;
 214 sub get_code_package;
 215
 216 sub is_valid_class_name;
 217
 218 # taken from Class/MOP.pm
 219 sub load_first_existing_class {
 220     my @classes = @_
 221       or return;
 222
 223     my %exceptions;
 224     for my $class (@classes) {
 225         my $e = _try_load_one_class($class);
 226
 227         if ($e) {
 228             $exceptions{$class} = $e;
 229         }
 230         else {
 231             return $class;
 232         }
 233     }
 234
 235     # not found
 236     Carp::confess join(
 237         "\n",
 238         map {
 239             sprintf( "Could not load class (%s) because : %s",
 240                 $_, $exceptions{$_} )
 241           } @classes
 242     );
 243 }
 244
 245 # taken from Class/MOP.pm
 246 my %is_class_loaded_cache;
 247 sub _try_load_one_class {
 248     my $class = shift;
 249
 250     unless ( is_valid_class_name($class) ) {
 251         my $display = defined($class) ? $class : 'undef';
 252         Carp::confess "Invalid class name ($display)";
 253     }
 254
 255     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 256
 257     $class  =~ s{::}{/}g;
 258     $class .= '.pm';
 259
 260     return do {
 261         local $@;
 262         eval { require $class };
 263         $@;
 264     };
 265 }
 266
 267
 268 sub load_class {
 269     my $class = shift;
 270     my $e = _try_load_one_class($class);
 271     Carp::confess "Could not load class ($class) because : $e" if $e;
 272
 273     return $class;
 274 }
 275
 276 sub is_class_loaded;
 277
 278 sub apply_all_roles {
 279     my $consumer = Scalar::Util::blessed($_[0])
 280         ?                                shift   # instance
 281         : Mouse::Meta::Class->initialize(shift); # class or role name
 282
 283     my @roles;
 284
 285     # Basis of Data::OptList
 286     my $max = scalar(@_);
 287     for (my $i = 0; $i < $max ; $i++) {
 288         if ($i + 1 < $max && ref($_[$i + 1])) {
 289             push @roles, [ $_[$i] => $_[++$i] ];
 290         } else {
 291             push @roles, [ $_[$i] => undef ];
 292         }
 293         my $role_name = $roles[-1][0];
 294         load_class($role_name);
 295
 296         is_a_metarole( get_metaclass_by_name($role_name) )
 297             || $consumer->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 298     }
 299
 300     if ( scalar @roles == 1 ) {
 301         my ( $role_name, $params ) = @{ $roles[0] };
 302         get_metaclass_by_name($role_name)->apply( $consumer, defined $params ? $params : () );
 303     }
 304     else {
 305         Mouse::Meta::Role->combine(@roles)->apply($consumer);
 306     }
 307     return;
 308 }
 309
 310 # taken from Moose::Util 0.90
 311 sub english_list {
 312     return $_[0] if @_ == 1;
 313
 314     my @items = sort @_;
 315
 316     return "$items[0] and $items[1]" if @items == 2;
 317
 318     my $tail = pop @items;
 319
 320     return join q{, }, @items, "and $tail";
 321 }
 322
 323 sub quoted_english_list {
 324     return english_list(map { qq{'$_'} } @_);
 325 }
 326
 327 # common utilities
 328
 329 sub not_supported{
 330     my($feature) = @_;
 331
 332     $feature ||= ( caller(1) )[3]; # subroutine name
 333
 334     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 335     Carp::confess("Mouse does not currently support $feature");
 336 }
 337
 338 # general meta() method
 339 sub meta :method{
 340     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 341 }
 342
 343 # general dump() method
 344 sub dump :method {
 345     my($self, $maxdepth) = @_;
 346
 347     require 'Data/Dumper.pm'; # we don't want to create its namespace
 348     my $dd = Data::Dumper->new([$self]);
 349     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 3);
 350     $dd->Indent(1);
 351     return $dd->Dump();
 352 }
 353
 354 # general does() method
 355 sub does :method {
 356     goto &does_role;
 357 }
 358
 359 1;
 360 __END__
 361
 362 =head1 NAME
 363
 364 Mouse::Util - Features, with or without their dependencies
 365
 366 =head1 VERSION
 367
 368 This document describes Mouse version 0.50_03
 369
 370 =head1 IMPLEMENTATIONS FOR
 371
 372 =head2 Moose::Util
 373
 374 =head3 C<find_meta>
 375
 376 =head3 C<does_role>
 377
 378 =head3 C<resolve_metaclass_alias>
 379
 380 =head3 C<apply_all_roles>
 381
 382 =head3 C<english_list>
 383
 384 =head2 Class::MOP
 385
 386 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 387
 388 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 389 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 390 locally-defined method.
 391
 392 =head3 C<< load_class(ClassName) >>
 393
 394 This will load a given C<ClassName> (or die if it is not loadable).
 395 This function can be used in place of tricks like
 396 C<eval "use $module"> or using C<require>.
 397
 398 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 399
 400 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 401
 402 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 403
 404 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 405
 406 =head2 MRO::Compat
 407
 408 =head3 C<get_linear_isa>
 409
 410 =head2 Sub::Identify
 411
 412 =head3 C<get_code_info>
 413
 414 =head1 Mouse specific utilities
 415
 416 =head3 C<not_supported>
 417
 418 =head3 C<get_code_package>
 419
 420 =head3 C<get_code_ref>
 421
 422 =head1 SEE ALSO
 423
 424 L<Moose::Util>
 425
 426 L<Class::MOP>
 427
 428 L<Sub::Identify>
 429
 430 L<MRO::Compat>
 431
 432 =cut
 433