lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.50_03';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         # XXX: XSLoader tries to get the object path from caller's file name
  47         #      $hack_mouse_file fools its mechanism
  48
  49         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  50         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  51             require XSLoader;
  52             XSLoader::load('Mouse', $VERSION);
  53             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  54             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  55             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  56             return 1;
  57         } || 0;
  58         #warn $@ if $@;
  59     }
  60
  61     if(!$xs){
  62         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  63     }
  64
  65     *MOUSE_XS = sub(){ $xs };
  66 }
  67
  68 use Carp         ();
  69 use Scalar::Util ();
  70
  71 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  72
  73 # aliases as public APIs
  74 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  75 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  76
  77 # aliases
  78 {
  79     *class_of                    = \&Mouse::Meta::Module::_class_of;
  80     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  81     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  82     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  83
  84     *Mouse::load_class           = \&load_class;
  85     *Mouse::is_class_loaded      = \&is_class_loaded;
  86
  87     # is-a predicates
  88     #generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  89     #generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  90     #generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  91
  92     # duck type predicates
  93     generate_can_predicate_for(['_compiled_type_constraint']  => 'is_a_type_constraint');
  94     generate_can_predicate_for(['create_anon_class']          => 'is_a_metaclass');
  95     generate_can_predicate_for(['create_anon_role']           => 'is_a_metarole');
  96 }
  97
  98 our $in_global_destruction = 0;
  99 END{ $in_global_destruction = 1 }
 100
 101 # Moose::Util compatible utilities
 102
 103 sub find_meta{
 104     return class_of( $_[0] );
 105 }
 106
 107 sub does_role{
 108     my ($class_or_obj, $role_name) = @_;
 109
 110     my $meta = class_of($class_or_obj);
 111
 112     (defined $role_name)
 113         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 114
 115     return defined($meta) && $meta->does_role($role_name);
 116 }
 117
 118 BEGIN {
 119     my $get_linear_isa;
 120     if ($] >= 5.009_005) {
 121         require mro;
 122         $get_linear_isa = \&mro::get_linear_isa;
 123     } else {
 124 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 125         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 126         $_get_linear_isa_dfs = sub {
 127             my($classname) = @_;
 128
 129             my @lin = ($classname);
 130             my %stored;
 131
 132             no strict 'refs';
 133             foreach my $parent (@{"$classname\::ISA"}) {
 134                 my $plin = $_get_linear_isa_dfs->($parent);
 135                 foreach  my $p(@$plin) {
 136                     next if exists $stored{$p};
 137                     push(@lin, $p);
 138                     $stored{$p} = 1;
 139                 }
 140             }
 141             return \@lin;
 142         };
 143 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 144
 145         eval{ require Class::C3 };
 146
 147         # MRO::Compat::__get_linear_isa has no prototype, so
 148         # we define a prototyped version for compatibility with core's
 149         # See also MRO::Compat::__get_linear_isa.
 150         $get_linear_isa = sub ($;$){
 151             my($classname, $type) = @_;
 152             package # hide from PAUSE
 153                 Class::C3;
 154             if(!defined $type){
 155                 our %MRO;
 156                 $type = exists $MRO{$classname} ? 'c3' : 'dfs';
 157             }
 158             return $type eq 'c3'
 159                 ? [calculateMRO($classname)]
 160                 : $_get_linear_isa_dfs->($classname);
 161         };
 162     }
 163
 164     *get_linear_isa = $get_linear_isa;
 165 }
 166
 167
 168 # taken from Mouse::Util (0.90)
 169 {
 170     my %cache;
 171
 172     sub resolve_metaclass_alias {
 173         my ( $type, $metaclass_name, %options ) = @_;
 174
 175         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 176
 177         return $cache{$cache_key}{$metaclass_name} ||= do{
 178
 179             my $possible_full_name = join '::',
 180                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 181             ;
 182
 183             my $loaded_class = load_first_existing_class(
 184                 $possible_full_name,
 185                 $metaclass_name
 186             );
 187
 188             $loaded_class->can('register_implementation')
 189                 ? $loaded_class->register_implementation
 190                 : $loaded_class;
 191         };
 192     }
 193 }
 194
 195 # Utilities from Class::MOP
 196
 197 sub get_code_info;
 198 sub get_code_package;
 199
 200 # taken from Class/MOP.pm
 201 sub is_valid_class_name {
 202     my $class = shift;
 203
 204     return 0 if ref($class);
 205     return 0 unless defined($class);
 206
 207     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 208
 209     return 0;
 210 }
 211
 212 # taken from Class/MOP.pm
 213 sub load_first_existing_class {
 214     my @classes = @_
 215       or return;
 216
 217     my %exceptions;
 218     for my $class (@classes) {
 219         my $e = _try_load_one_class($class);
 220
 221         if ($e) {
 222             $exceptions{$class} = $e;
 223         }
 224         else {
 225             return $class;
 226         }
 227     }
 228
 229     # not found
 230     Carp::confess join(
 231         "\n",
 232         map {
 233             sprintf( "Could not load class (%s) because : %s",
 234                 $_, $exceptions{$_} )
 235           } @classes
 236     );
 237 }
 238
 239 # taken from Class/MOP.pm
 240 my %is_class_loaded_cache;
 241 sub _try_load_one_class {
 242     my $class = shift;
 243
 244     unless ( is_valid_class_name($class) ) {
 245         my $display = defined($class) ? $class : 'undef';
 246         Carp::confess "Invalid class name ($display)";
 247     }
 248
 249     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 250
 251     $class  =~ s{::}{/}g;
 252     $class .= '.pm';
 253
 254     return do {
 255         local $@;
 256         eval { require $class };
 257         $@;
 258     };
 259 }
 260
 261
 262 sub load_class {
 263     my $class = shift;
 264     my $e = _try_load_one_class($class);
 265     Carp::confess "Could not load class ($class) because : $e" if $e;
 266
 267     return $class;
 268 }
 269
 270 sub is_class_loaded;
 271
 272 sub apply_all_roles {
 273     my $consumer = Scalar::Util::blessed($_[0])
 274         ?                                shift   # instance
 275         : Mouse::Meta::Class->initialize(shift); # class or role name
 276
 277     my @roles;
 278
 279     # Basis of Data::OptList
 280     my $max = scalar(@_);
 281     for (my $i = 0; $i < $max ; $i++) {
 282         if ($i + 1 < $max && ref($_[$i + 1])) {
 283             push @roles, [ $_[$i] => $_[++$i] ];
 284         } else {
 285             push @roles, [ $_[$i] => undef ];
 286         }
 287         my $role_name = $roles[-1][0];
 288         load_class($role_name);
 289
 290         is_a_metarole( get_metaclass_by_name($role_name) )
 291             || $consumer->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 292     }
 293
 294     if ( scalar @roles == 1 ) {
 295         my ( $role_name, $params ) = @{ $roles[0] };
 296         get_metaclass_by_name($role_name)->apply( $consumer, defined $params ? $params : () );
 297     }
 298     else {
 299         Mouse::Meta::Role->combine(@roles)->apply($consumer);
 300     }
 301     return;
 302 }
 303
 304 # taken from Moose::Util 0.90
 305 sub english_list {
 306     return $_[0] if @_ == 1;
 307
 308     my @items = sort @_;
 309
 310     return "$items[0] and $items[1]" if @items == 2;
 311
 312     my $tail = pop @items;
 313
 314     return join q{, }, @items, "and $tail";
 315 }
 316
 317 sub quoted_english_list {
 318     return english_list(map { qq{'$_'} } @_);
 319 }
 320
 321 # common utilities
 322
 323 sub not_supported{
 324     my($feature) = @_;
 325
 326     $feature ||= ( caller(1) )[3]; # subroutine name
 327
 328     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 329     Carp::confess("Mouse does not currently support $feature");
 330 }
 331
 332 # general meta() method
 333 sub meta :method{
 334     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 335 }
 336
 337 # general dump() method
 338 sub dump :method {
 339     my($self, $maxdepth) = @_;
 340
 341     require 'Data/Dumper.pm'; # we don't want to create its namespace
 342     my $dd = Data::Dumper->new([$self]);
 343     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 3);
 344     $dd->Indent(1);
 345     return $dd->Dump();
 346 }
 347
 348 # general does() method
 349 sub does :method {
 350     goto &does_role;
 351 }
 352
 353 1;
 354 __END__
 355
 356 =head1 NAME
 357
 358 Mouse::Util - Features, with or without their dependencies
 359
 360 =head1 VERSION
 361
 362 This document describes Mouse version 0.50_03
 363
 364 =head1 IMPLEMENTATIONS FOR
 365
 366 =head2 Moose::Util
 367
 368 =head3 C<find_meta>
 369
 370 =head3 C<does_role>
 371
 372 =head3 C<resolve_metaclass_alias>
 373
 374 =head3 C<apply_all_roles>
 375
 376 =head3 C<english_list>
 377
 378 =head2 Class::MOP
 379
 380 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 381
 382 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 383 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 384 locally-defined method.
 385
 386 =head3 C<< load_class(ClassName) >>
 387
 388 This will load a given C<ClassName> (or die if it is not loadable).
 389 This function can be used in place of tricks like
 390 C<eval "use $module"> or using C<require>.
 391
 392 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 393
 394 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 395
 396 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 397
 398 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 399
 400 =head2 MRO::Compat
 401
 402 =head3 C<get_linear_isa>
 403
 404 =head2 Sub::Identify
 405
 406 =head3 C<get_code_info>
 407
 408 =head1 Mouse specific utilities
 409
 410 =head3 C<not_supported>
 411
 412 =head3 C<get_code_package>
 413
 414 =head3 C<get_code_ref>
 415
 416 =head1 SEE ALSO
 417
 418 L<Moose::Util>
 419
 420 L<Class::MOP>
 421
 422 L<Sub::Identify>
 423
 424 L<MRO::Compat>
 425
 426 =cut
 427