lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 sub install_subroutines { # must be here
   7     my $into = shift;
   8
   9     while(my($name, $code) = splice @_, 0, 2){
  10         no strict 'refs';
  11         no warnings 'once', 'redefine';
  12         use warnings FATAL => 'uninitialized';
  13         *{$into . '::' . $name} = \&{$code};
  14     }
  15     return;
  16 }
  17
  18 BEGIN{
  19     # This is used in Mouse::PurePerl
  20     Mouse::Exporter->setup_import_methods(
  21         as_is => [qw(
  22             find_meta
  23             does_role
  24             resolve_metaclass_alias
  25             apply_all_roles
  26             english_list
  27
  28             load_class
  29             is_class_loaded
  30
  31             get_linear_isa
  32             get_code_info
  33
  34             get_code_package
  35             get_code_ref
  36
  37             not_supported
  38
  39             does meta dump
  40         )],
  41         groups => {
  42             default => [], # export no functions by default
  43
  44             # The ':meta' group is 'use metaclass' for Mouse
  45             meta    => [qw(does meta dump)],
  46         },
  47     );
  48
  49
  50     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  51     # XS loader is placed here, not in Mouse.pm.
  52
  53     our $VERSION = '0.50_04';
  54
  55     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  56
  57     if($xs){
  58         # XXX: XSLoader tries to get the object path from caller's file name
  59         #      $hack_mouse_file fools its mechanism
  60
  61         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  62         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  63             local $^W = 0; # work around 'redefine' warning to &install_subroutines
  64             require XSLoader;
  65             XSLoader::load('Mouse', $VERSION);
  66             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  67             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  68             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  69             return 1;
  70         } || 0;
  71         #warn $@ if $@;
  72     }
  73
  74     if(!$xs){
  75         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  76     }
  77
  78     *MOUSE_XS = sub(){ $xs };
  79 }
  80
  81 use Carp         ();
  82 use Scalar::Util ();
  83
  84 # aliases as public APIs
  85 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  86 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  87
  88 # aliases
  89 {
  90     *class_of                    = \&Mouse::Meta::Module::_class_of;
  91     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  92     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  93     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  94
  95     *Mouse::load_class           = \&load_class;
  96     *Mouse::is_class_loaded      = \&is_class_loaded;
  97
  98     # is-a predicates
  99     #generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
 100     #generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
 101     #generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
 102
 103     # duck type predicates
 104     generate_can_predicate_for(['_compiled_type_constraint']  => 'is_a_type_constraint');
 105     generate_can_predicate_for(['create_anon_class']          => 'is_a_metaclass');
 106     generate_can_predicate_for(['create_anon_role']           => 'is_a_metarole');
 107 }
 108
 109 our $in_global_destruction = 0;
 110 END{ $in_global_destruction = 1 }
 111
 112 # Moose::Util compatible utilities
 113
 114 sub find_meta{
 115     return class_of( $_[0] );
 116 }
 117
 118 sub does_role{
 119     my ($class_or_obj, $role_name) = @_;
 120
 121     my $meta = class_of($class_or_obj);
 122
 123     (defined $role_name)
 124         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 125
 126     return defined($meta) && $meta->does_role($role_name);
 127 }
 128
 129 BEGIN {
 130     my $get_linear_isa;
 131     if ($] >= 5.009_005) {
 132         require mro;
 133         $get_linear_isa = \&mro::get_linear_isa;
 134     } else {
 135         # this code is based on MRO::Compat::__get_linear_isa
 136         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 137         $_get_linear_isa_dfs = sub {
 138             my($classname) = @_;
 139
 140             my @lin = ($classname);
 141             my %stored;
 142
 143             no strict 'refs';
 144             foreach my $parent (@{"$classname\::ISA"}) {
 145                 foreach  my $p(@{ $_get_linear_isa_dfs->($parent) }) {
 146                     next if exists $stored{$p};
 147                     push(@lin, $p);
 148                     $stored{$p} = 1;
 149                 }
 150             }
 151             return \@lin;
 152         };
 153
 154         {
 155             package # hide from PAUSE
 156                 Class::C3;
 157             our %MRO; # work around 'once' warnings
 158         }
 159
 160         # MRO::Compat::__get_linear_isa has no prototype, so
 161         # we define a prototyped version for compatibility with core's
 162         # See also MRO::Compat::__get_linear_isa.
 163         $get_linear_isa = sub ($;$){
 164             my($classname, $type) = @_;
 165
 166             if(!defined $type){
 167                 $type = exists $Class::C3::MRO{$classname} ? 'c3' : 'dfs';
 168             }
 169             if($type eq 'c3'){
 170                 require Class::C3;
 171                 return [Class::C3::calculateMRO($classname)];
 172             }
 173             else{
 174                 return $_get_linear_isa_dfs->($classname);
 175             }
 176         };
 177     }
 178
 179     *get_linear_isa = $get_linear_isa;
 180 }
 181
 182
 183 # taken from Mouse::Util (0.90)
 184 {
 185     my %cache;
 186
 187     sub resolve_metaclass_alias {
 188         my ( $type, $metaclass_name, %options ) = @_;
 189
 190         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 191
 192         return $cache{$cache_key}{$metaclass_name} ||= do{
 193
 194             my $possible_full_name = join '::',
 195                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 196             ;
 197
 198             my $loaded_class = load_first_existing_class(
 199                 $possible_full_name,
 200                 $metaclass_name
 201             );
 202
 203             $loaded_class->can('register_implementation')
 204                 ? $loaded_class->register_implementation
 205                 : $loaded_class;
 206         };
 207     }
 208 }
 209
 210 # Utilities from Class::MOP
 211
 212 sub get_code_info;
 213 sub get_code_package;
 214
 215 sub is_valid_class_name;
 216
 217 # taken from Class/MOP.pm
 218 sub load_first_existing_class {
 219     my @classes = @_
 220       or return;
 221
 222     my %exceptions;
 223     for my $class (@classes) {
 224         my $e = _try_load_one_class($class);
 225
 226         if ($e) {
 227             $exceptions{$class} = $e;
 228         }
 229         else {
 230             return $class;
 231         }
 232     }
 233
 234     # not found
 235     Carp::confess join(
 236         "\n",
 237         map {
 238             sprintf( "Could not load class (%s) because : %s",
 239                 $_, $exceptions{$_} )
 240           } @classes
 241     );
 242 }
 243
 244 # taken from Class/MOP.pm
 245 my %is_class_loaded_cache;
 246 sub _try_load_one_class {
 247     my $class = shift;
 248
 249     unless ( is_valid_class_name($class) ) {
 250         my $display = defined($class) ? $class : 'undef';
 251         Carp::confess "Invalid class name ($display)";
 252     }
 253
 254     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 255
 256     $class  =~ s{::}{/}g;
 257     $class .= '.pm';
 258
 259     return do {
 260         local $@;
 261         eval { require $class };
 262         $@;
 263     };
 264 }
 265
 266
 267 sub load_class {
 268     my $class = shift;
 269     my $e = _try_load_one_class($class);
 270     Carp::confess "Could not load class ($class) because : $e" if $e;
 271
 272     return $class;
 273 }
 274
 275 sub is_class_loaded;
 276
 277 sub apply_all_roles {
 278     my $consumer = Scalar::Util::blessed($_[0])
 279         ?                                shift   # instance
 280         : Mouse::Meta::Class->initialize(shift); # class or role name
 281
 282     my @roles;
 283
 284     # Basis of Data::OptList
 285     my $max = scalar(@_);
 286     for (my $i = 0; $i < $max ; $i++) {
 287         if ($i + 1 < $max && ref($_[$i + 1])) {
 288             push @roles, [ $_[$i] => $_[++$i] ];
 289         } else {
 290             push @roles, [ $_[$i] => undef ];
 291         }
 292         my $role_name = $roles[-1][0];
 293         load_class($role_name);
 294
 295         is_a_metarole( get_metaclass_by_name($role_name) )
 296             || $consumer->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 297     }
 298
 299     if ( scalar @roles == 1 ) {
 300         my ( $role_name, $params ) = @{ $roles[0] };
 301         get_metaclass_by_name($role_name)->apply( $consumer, defined $params ? $params : () );
 302     }
 303     else {
 304         Mouse::Meta::Role->combine(@roles)->apply($consumer);
 305     }
 306     return;
 307 }
 308
 309 # taken from Moose::Util 0.90
 310 sub english_list {
 311     return $_[0] if @_ == 1;
 312
 313     my @items = sort @_;
 314
 315     return "$items[0] and $items[1]" if @items == 2;
 316
 317     my $tail = pop @items;
 318
 319     return join q{, }, @items, "and $tail";
 320 }
 321
 322 sub quoted_english_list {
 323     return english_list(map { qq{'$_'} } @_);
 324 }
 325
 326 # common utilities
 327
 328 sub not_supported{
 329     my($feature) = @_;
 330
 331     $feature ||= ( caller(1) )[3]; # subroutine name
 332
 333     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 334     Carp::confess("Mouse does not currently support $feature");
 335 }
 336
 337 # general meta() method
 338 sub meta :method{
 339     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 340 }
 341
 342 # general dump() method
 343 sub dump :method {
 344     my($self, $maxdepth) = @_;
 345
 346     require 'Data/Dumper.pm'; # we don't want to create its namespace
 347     my $dd = Data::Dumper->new([$self]);
 348     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 3);
 349     $dd->Indent(1);
 350     return $dd->Dump();
 351 }
 352
 353 # general does() method
 354 sub does :method {
 355     goto &does_role;
 356 }
 357
 358 1;
 359 __END__
 360
 361 =head1 NAME
 362
 363 Mouse::Util - Features, with or without their dependencies
 364
 365 =head1 VERSION
 366
 367 This document describes Mouse version 0.50_04
 368
 369 =head1 IMPLEMENTATIONS FOR
 370
 371 =head2 Moose::Util
 372
 373 =head3 C<find_meta>
 374
 375 =head3 C<does_role>
 376
 377 =head3 C<resolve_metaclass_alias>
 378
 379 =head3 C<apply_all_roles>
 380
 381 =head3 C<english_list>
 382
 383 =head2 Class::MOP
 384
 385 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 386
 387 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 388 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 389 locally-defined method.
 390
 391 =head3 C<< load_class(ClassName) >>
 392
 393 This will load a given C<ClassName> (or die if it is not loadable).
 394 This function can be used in place of tricks like
 395 C<eval "use $module"> or using C<require>.
 396
 397 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 398
 399 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 400
 401 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 402
 403 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 404
 405 =head2 MRO::Compat
 406
 407 =head3 C<get_linear_isa>
 408
 409 =head2 Sub::Identify
 410
 411 =head3 C<get_code_info>
 412
 413 =head1 Mouse specific utilities
 414
 415 =head3 C<not_supported>
 416
 417 =head3 C<get_code_package>
 418
 419 =head3 C<get_code_ref>
 420
 421 =head1 SEE ALSO
 422
 423 L<Moose::Util>
 424
 425 L<Class::MOP>
 426
 427 L<Sub::Identify>
 428
 429 L<MRO::Compat>
 430
 431 =cut
 432