lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.42';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         # XXX: XSLoader tries to get the object path from caller's file name
  47         #      $hack_mouse_file fools its mechanism
  48
  49         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  50         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  51             require XSLoader;
  52             XSLoader::load('Mouse', $VERSION);
  53             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  54             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  55             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  56             return 1;
  57         };
  58         #warn $@ if $@;
  59     }
  60
  61     if(!$xs){
  62         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  63     }
  64
  65     *MOUSE_XS = sub(){ $xs };
  66 }
  67
  68 use Carp         ();
  69 use Scalar::Util ();
  70
  71 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  72
  73 # aliases as public APIs
  74 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  75 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  76
  77 BEGIN {
  78     *class_of                    = \&Mouse::Meta::Module::_class_of;
  79     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  80     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  81     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  82
  83     # is-a predicates
  84     generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  85     generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  86     generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  87 }
  88
  89 our $in_global_destruction = 0;
  90 END{ $in_global_destruction = 1 }
  91
  92 # Moose::Util compatible utilities
  93
  94 sub find_meta{
  95     return class_of( $_[0] );
  96 }
  97
  98 sub does_role{
  99     my ($class_or_obj, $role_name) = @_;
 100
 101     my $meta = class_of($class_or_obj);
 102
 103     (defined $role_name)
 104         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 105
 106     return defined($meta) && $meta->does_role($role_name);
 107 }
 108
 109 BEGIN {
 110     my $get_linear_isa;
 111     if ($] >= 5.009_005) {
 112         require mro;
 113         $get_linear_isa = \&mro::get_linear_isa;
 114     } else {
 115 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 116         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 117         $_get_linear_isa_dfs = sub {
 118             my($classname) = @_;
 119
 120             my @lin = ($classname);
 121             my %stored;
 122
 123             no strict 'refs';
 124             foreach my $parent (@{"$classname\::ISA"}) {
 125                 my $plin = $_get_linear_isa_dfs->($parent);
 126                 foreach  my $p(@$plin) {
 127                     next if exists $stored{$p};
 128                     push(@lin, $p);
 129                     $stored{$p} = 1;
 130                 }
 131             }
 132             return \@lin;
 133         };
 134 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 135
 136         eval{ require Class::C3 };
 137
 138         # MRO::Compat::__get_linear_isa has no prototype, so
 139         # we define a prototyped version for compatibility with core's
 140         # See also MRO::Compat::__get_linear_isa.
 141         $get_linear_isa = sub ($;$){
 142             my($classname, $type) = @_;
 143             package # hide from PAUSE
 144                 Class::C3;
 145             if(!defined $type){
 146                 our %MRO;
 147                 $type = exists $MRO{$classname} ? 'c3' : 'dfs';
 148             }
 149             return $type eq 'c3'
 150                 ? [calculateMRO($classname)]
 151                 : $_get_linear_isa_dfs->($classname);\r
 152         };
 153     }
 154
 155     *get_linear_isa = $get_linear_isa;
 156 }
 157
 158
 159 # taken from Mouse::Util (0.90)
 160 {
 161     my %cache;
 162
 163     sub resolve_metaclass_alias {
 164         my ( $type, $metaclass_name, %options ) = @_;
 165
 166         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 167
 168         return $cache{$cache_key}{$metaclass_name} ||= do{
 169
 170             my $possible_full_name = join '::',
 171                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 172             ;
 173
 174             my $loaded_class = load_first_existing_class(
 175                 $possible_full_name,
 176                 $metaclass_name
 177             );
 178
 179             $loaded_class->can('register_implementation')
 180                 ? $loaded_class->register_implementation
 181                 : $loaded_class;
 182         };
 183     }
 184 }
 185
 186 # Utilities from Class::MOP
 187
 188 sub get_code_info;
 189 sub get_code_package;
 190
 191 # taken from Class/MOP.pm
 192 sub is_valid_class_name {
 193     my $class = shift;
 194
 195     return 0 if ref($class);
 196     return 0 unless defined($class);
 197
 198     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 199
 200     return 0;
 201 }
 202
 203 # taken from Class/MOP.pm
 204 sub load_first_existing_class {
 205     my @classes = @_
 206       or return;
 207
 208     my %exceptions;
 209     for my $class (@classes) {
 210         my $e = _try_load_one_class($class);
 211
 212         if ($e) {
 213             $exceptions{$class} = $e;
 214         }
 215         else {
 216             return $class;
 217         }
 218     }
 219
 220     # not found
 221     Carp::confess join(
 222         "\n",
 223         map {
 224             sprintf( "Could not load class (%s) because : %s",
 225                 $_, $exceptions{$_} )
 226           } @classes
 227     );
 228 }
 229
 230 # taken from Class/MOP.pm
 231 my %is_class_loaded_cache;
 232 sub _try_load_one_class {
 233     my $class = shift;
 234
 235     unless ( is_valid_class_name($class) ) {
 236         my $display = defined($class) ? $class : 'undef';
 237         Carp::confess "Invalid class name ($display)";
 238     }
 239
 240     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 241
 242     my $file = $class . '.pm';
 243     $file =~ s{::}{/}g;
 244
 245     return do {
 246         local $@;
 247         eval { require($file) };
 248         $@;
 249     };
 250 }
 251
 252
 253 sub load_class {
 254     my $class = shift;
 255     my $e = _try_load_one_class($class);
 256     Carp::confess "Could not load class ($class) because : $e" if $e;
 257
 258     return 1;
 259 }
 260
 261 sub is_class_loaded;
 262
 263 sub apply_all_roles {
 264     my $applicant = Scalar::Util::blessed($_[0])
 265         ?                                shift   # instance
 266         : Mouse::Meta::Class->initialize(shift); # class or role name
 267
 268     my @roles;
 269
 270     # Basis of Data::OptList
 271     my $max = scalar(@_);
 272     for (my $i = 0; $i < $max ; $i++) {
 273         if ($i + 1 < $max && ref($_[$i + 1])) {
 274             push @roles, [ $_[$i] => $_[++$i] ];
 275         } else {
 276             push @roles, [ $_[$i] => undef ];
 277         }
 278         my $role_name = $roles[-1][0];
 279         load_class($role_name);
 280
 281         is_a_metarole( get_metaclass_by_name($role_name) )
 282             || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 283     }
 284
 285     if ( scalar @roles == 1 ) {
 286         my ( $role_name, $params ) = @{ $roles[0] };
 287         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 288     }
 289     else {
 290         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 291     }
 292     return;
 293 }
 294
 295 # taken from Moose::Util 0.90
 296 sub english_list {
 297     return $_[0] if @_ == 1;
 298
 299     my @items = sort @_;
 300
 301     return "$items[0] and $items[1]" if @items == 2;
 302
 303     my $tail = pop @items;
 304
 305     return join q{, }, @items, "and $tail";
 306 }
 307
 308 # common utilities
 309
 310 sub not_supported{
 311     my($feature) = @_;
 312
 313     $feature ||= ( caller(1) )[3]; # subroutine name
 314
 315     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 316     Carp::confess("Mouse does not currently support $feature");
 317 }
 318
 319 # general meta() method
 320 sub meta :method{
 321     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 322 }
 323
 324 # general dump() method
 325 sub dump :method {
 326     my($self, $maxdepth) = @_;
 327
 328     require 'Data/Dumper.pm'; # we don't want to create its namespace
 329     my $dd = Data::Dumper->new([$self]);
 330     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 331     $dd->Indent(1);
 332     return $dd->Dump();
 333 }
 334
 335 # general does() method
 336 sub does :method;
 337 *does = \&does_role; # alias
 338
 339 1;
 340 __END__
 341
 342 =head1 NAME
 343
 344 Mouse::Util - Features, with or without their dependencies
 345
 346 =head1 VERSION
 347
 348 This document describes Mouse version 0.42
 349
 350 =head1 IMPLEMENTATIONS FOR
 351
 352 =head2 Moose::Util
 353
 354 =head3 C<find_meta>
 355
 356 =head3 C<does_role>
 357
 358 =head3 C<resolve_metaclass_alias>
 359
 360 =head3 C<apply_all_roles>
 361
 362 =head3 C<english_list>
 363
 364 =head2 Class::MOP
 365
 366 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 367
 368 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 369 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 370 locally-defined method.
 371
 372 =head3 C<< load_class(ClassName) >>
 373
 374 This will load a given C<ClassName> (or die if it is not loadable).
 375 This function can be used in place of tricks like
 376 C<eval "use $module"> or using C<require>.
 377
 378 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 379
 380 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 381
 382 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 383
 384 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 385
 386 =head2 MRO::Compat
 387
 388 =head3 C<get_linear_isa>
 389
 390 =head2 Sub::Identify
 391
 392 =head3 C<get_code_info>
 393
 394 =head1 Mouse specific utilities
 395
 396 =head3 C<not_supported>
 397
 398 =head3 C<get_code_package>
 399
 400 =head3 C<get_code_ref>
 401
 402 =head1 SEE ALSO
 403
 404 L<Moose::Util>
 405
 406 L<Class::MOP>
 407
 408 L<Sub::Identify>
 409
 410 L<MRO::Compat>
 411
 412 =cut
 413