lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 BEGIN{
   5     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
   6     # XS loader is placed here, not in Mouse.pm.
   7
   8     our $VERSION = '0.40_03';
   9
  10     my $need_pp = !!$ENV{MOUSE_PUREPERL};
  11
  12     if(!$need_pp && !exists $INC{'Mouse/PurePerl.pm'}){
  13         local $@;
  14
  15         # XXX: XSLoader tries to get the object path from caller's file name
  16         #      $hack_mouse_file fools its mechanism
  17
  18         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  19         $need_pp = !eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  20             require XSLoader;
  21             XSLoader::load('Mouse', $VERSION);
  22         };
  23         #warn $@ if $@;
  24     }
  25
  26     if($need_pp){
  27         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  28     }
  29 }
  30
  31
  32 use Carp         ();
  33 use Scalar::Util ();
  34
  35 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  36
  37 Mouse::Exporter->setup_import_methods(
  38     as_is => [qw(
  39         find_meta
  40         does_role
  41         resolve_metaclass_alias
  42         apply_all_roles
  43         english_list
  44
  45         load_class
  46         is_class_loaded
  47
  48         get_linear_isa
  49         get_code_info
  50
  51         get_code_package
  52         get_code_ref
  53
  54         not_supported
  55
  56         does meta dump
  57         _MOUSE_VERBOSE
  58     )],
  59     groups => {
  60         default => [], # export no functions by default
  61
  62         # The ':meta' group is 'use metaclass' for Mouse
  63         meta    => [qw(does meta dump _MOUSE_VERBOSE)],
  64     },
  65 );
  66
  67 # aliases as public APIs
  68 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  69 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  70
  71 BEGIN {
  72     *class_of                    = \&Mouse::Meta::Module::class_of;
  73     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  74     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  75     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  76 }
  77
  78 # Moose::Util compatible utilities
  79
  80 sub find_meta{
  81     return class_of( $_[0] );
  82 }
  83
  84 sub does_role{
  85     my ($class_or_obj, $role_name) = @_;
  86
  87     my $meta = class_of($class_or_obj);
  88
  89     (defined $role_name)
  90         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  91
  92     return defined($meta) && $meta->does_role($role_name);
  93 }
  94
  95 BEGIN {
  96     my $impl;
  97     if ($] >= 5.009_005) {
  98         require mro;
  99         $impl = \&mro::get_linear_isa;
 100     } else {
 101         my $e = do {
 102             local $@;
 103             eval { require MRO::Compat };
 104             $@;
 105         };
 106         if (!$e) {
 107             $impl = \&mro::get_linear_isa;
 108         } else {
 109 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 110             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 111             $_get_linear_isa_dfs = sub {
 112                 no strict 'refs';
 113
 114                 my $classname = shift;
 115
 116                 my @lin = ($classname);
 117                 my %stored;
 118                 foreach my $parent (@{"$classname\::ISA"}) {
 119                     my $plin = $_get_linear_isa_dfs->($parent);
 120                     foreach  my $p(@$plin) {
 121                         next if exists $stored{$p};
 122                         push(@lin, $p);
 123                         $stored{$p} = 1;
 124                     }
 125                 }
 126                 return \@lin;
 127             };
 128 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 129             $impl = $_get_linear_isa_dfs;
 130         }
 131     }
 132
 133
 134     no warnings 'once';
 135     *get_linear_isa = $impl;
 136 }
 137
 138
 139 # taken from Mouse::Util (0.90)
 140 {
 141     my %cache;
 142
 143     sub resolve_metaclass_alias {
 144         my ( $type, $metaclass_name, %options ) = @_;
 145
 146         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 147
 148         return $cache{$cache_key}{$metaclass_name} ||= do{
 149
 150             my $possible_full_name = join '::',
 151                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 152             ;
 153
 154             my $loaded_class = load_first_existing_class(
 155                 $possible_full_name,
 156                 $metaclass_name
 157             );
 158
 159             $loaded_class->can('register_implementation')
 160                 ? $loaded_class->register_implementation
 161                 : $loaded_class;
 162         };
 163     }
 164 }
 165
 166 # Utilities from Class::MOP
 167
 168 sub get_code_info;
 169 sub get_code_package;
 170
 171 # taken from Class/MOP.pm
 172 sub is_valid_class_name {
 173     my $class = shift;
 174
 175     return 0 if ref($class);
 176     return 0 unless defined($class);
 177
 178     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 179
 180     return 0;
 181 }
 182
 183 # taken from Class/MOP.pm
 184 sub load_first_existing_class {
 185     my @classes = @_
 186       or return;
 187
 188     my %exceptions;
 189     for my $class (@classes) {
 190         my $e = _try_load_one_class($class);
 191
 192         if ($e) {
 193             $exceptions{$class} = $e;
 194         }
 195         else {
 196             return $class;
 197         }
 198     }
 199
 200     # not found
 201     Carp::confess join(
 202         "\n",
 203         map {
 204             sprintf( "Could not load class (%s) because : %s",
 205                 $_, $exceptions{$_} )
 206           } @classes
 207     );
 208 }
 209
 210 # taken from Class/MOP.pm
 211 my %is_class_loaded_cache;
 212 sub _try_load_one_class {
 213     my $class = shift;
 214
 215     unless ( is_valid_class_name($class) ) {
 216         my $display = defined($class) ? $class : 'undef';
 217         Carp::confess "Invalid class name ($display)";
 218     }
 219
 220     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 221
 222     my $file = $class . '.pm';
 223     $file =~ s{::}{/}g;
 224
 225     return do {
 226         local $@;
 227         eval { require($file) };
 228         $@;
 229     };
 230 }
 231
 232
 233 sub load_class {
 234     my $class = shift;
 235     my $e = _try_load_one_class($class);
 236     Carp::confess "Could not load class ($class) because : $e" if $e;
 237
 238     return 1;
 239 }
 240
 241 sub is_class_loaded;
 242
 243
 244 sub apply_all_roles {
 245     my $applicant = Scalar::Util::blessed($_[0])
 246         ?                                shift   # instance
 247         : Mouse::Meta::Class->initialize(shift); # class or role name
 248
 249     my @roles;
 250
 251     # Basis of Data::OptList
 252     my $max = scalar(@_);
 253     for (my $i = 0; $i < $max ; $i++) {
 254         if ($i + 1 < $max && ref($_[$i + 1])) {
 255             push @roles, [ $_[$i] => $_[++$i] ];
 256         } else {
 257             push @roles, [ $_[$i] => undef ];
 258         }
 259         my $role_name = $roles[-1][0];
 260         load_class($role_name);
 261
 262         Mouse::Util::TypeConstraints::_is_a_metarole( get_metaclass_by_name($role_name) )
 263             || $applicant->meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 264     }
 265
 266     if ( scalar @roles == 1 ) {
 267         my ( $role_name, $params ) = @{ $roles[0] };
 268         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 269     }
 270     else {
 271         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 272     }
 273     return;
 274 }
 275
 276 # taken from Moose::Util 0.90
 277 sub english_list {
 278     return $_[0] if @_ == 1;
 279
 280     my @items = sort @_;
 281
 282     return "$items[0] and $items[1]" if @items == 2;
 283
 284     my $tail = pop @items;
 285
 286     return join q{, }, @items, "and $tail";
 287 }
 288
 289
 290 # common utilities
 291
 292 sub not_supported{
 293     my($feature) = @_;
 294
 295     $feature ||= ( caller(1) )[3]; # subroutine name
 296
 297     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 298     Carp::confess("Mouse does not currently support $feature");
 299 }
 300
 301 # general meta() method
 302 sub meta :method{
 303     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 304 }
 305
 306 # general dump() method
 307 sub dump :method {
 308     my($self, $maxdepth) = @_;
 309
 310     require 'Data/Dumper.pm'; # we don't want to create its namespace
 311     my $dd = Data::Dumper->new([$self]);
 312     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 313     $dd->Indent(1);
 314     return $dd->Dump();
 315 }
 316
 317 # general does() method
 318 sub does :method;
 319 *does = \&does_role; # alias
 320
 321 1;
 322
 323 __END__
 324
 325 =head1 NAME
 326
 327 Mouse::Util - Features, with or without their dependencies
 328
 329 =head1 VERSION
 330
 331 This document describes Mouse version 0.40_03
 332
 333 =head1 IMPLEMENTATIONS FOR
 334
 335 =head2 Moose::Util
 336
 337 =head3 C<find_meta>
 338
 339 =head3 C<does_role>
 340
 341 =head3 C<resolve_metaclass_alias>
 342
 343 =head3 C<apply_all_roles>
 344
 345 =head3 C<english_list>
 346
 347 =head2 Class::MOP
 348
 349 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 350
 351 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 352 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 353 locally-defined method.
 354
 355 =head3 C<< load_class(ClassName) >>
 356
 357 This will load a given C<ClassName> (or die if it is not loadable).
 358 This function can be used in place of tricks like
 359 C<eval "use $module"> or using C<require>.
 360
 361 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 362
 363 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 364
 365 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 366
 367 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 368
 369 =head2 MRO::Compat
 370
 371 =head3 C<get_linear_isa>
 372
 373 =head2 Sub::Identify
 374
 375 =head3 C<get_code_info>
 376
 377 =head1 UTILITIES FOR MOUSE
 378
 379 =head3 C<not_supported>
 380
 381 =head1 SEE ALSO
 382
 383 L<Moose::Util>
 384
 385 L<Class::MOP>
 386
 387 L<Sub::Identify>
 388
 389 L<MRO::Compat>
 390
 391 =cut
 392