lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use Mouse::Exporter; # enables strict and warnings
   3
   4 sub get_linear_isa($;$); # must be here
   5
   6 BEGIN{
   7     # This is used in Mouse::PurePerl
   8     Mouse::Exporter->setup_import_methods(
   9         as_is => [qw(
  10             find_meta
  11             does_role
  12             resolve_metaclass_alias
  13             apply_all_roles
  14             english_list
  15
  16             load_class
  17             is_class_loaded
  18
  19             get_linear_isa
  20             get_code_info
  21
  22             get_code_package
  23             get_code_ref
  24
  25             not_supported
  26
  27             does meta dump
  28         )],
  29         groups => {
  30             default => [], # export no functions by default
  31
  32             # The ':meta' group is 'use metaclass' for Mouse
  33             meta    => [qw(does meta dump)],
  34         },
  35     );
  36
  37
  38     # Because Mouse::Util is loaded first in all the Mouse sub-modules,
  39     # XS loader is placed here, not in Mouse.pm.
  40
  41     our $VERSION = '0.40_08';
  42
  43     my $xs = !(exists $INC{'Mouse/PurePerl.pm'} || $ENV{MOUSE_PUREPERL});
  44
  45     if($xs){
  46         # XXX: XSLoader tries to get the object path from caller's file name
  47         #      $hack_mouse_file fools its mechanism
  48
  49         (my $hack_mouse_file = __FILE__) =~ s/.Util//; # .../Mouse/Util.pm -> .../Mouse.pm
  50         $xs = eval sprintf("#line %d %s\n", __LINE__, $hack_mouse_file) . q{
  51             require XSLoader;
  52             XSLoader::load('Mouse', $VERSION);
  53             Mouse::Util->import({ into => 'Mouse::Meta::Method::Constructor::XS' }, ':meta');
  54             Mouse::Util->import({ into => 'Mouse::Meta::Method::Destructor::XS'  }, ':meta');
  55             Mouse::Util->import({ into => 'Mouse::Meta::Method::Accessor::XS'    }, ':meta');
  56             return 1;
  57         };
  58         #warn $@ if $@;
  59     }
  60
  61     if(!$xs){
  62         require 'Mouse/PurePerl.pm'; # we don't want to create its namespace
  63     }
  64
  65     *MOUSE_XS = sub(){ $xs };
  66 }
  67
  68
  69 use Carp         ();
  70 use Scalar::Util ();
  71
  72 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  73
  74 # aliases as public APIs
  75 # it must be 'require', not 'use', because Mouse::Meta::Module depends on Mouse::Util
  76 require Mouse::Meta::Module; # for the entities of metaclass cache utilities
  77
  78 BEGIN {
  79     *class_of                    = \&Mouse::Meta::Module::_class_of;
  80     *get_metaclass_by_name       = \&Mouse::Meta::Module::_get_metaclass_by_name;
  81     *get_all_metaclass_instances = \&Mouse::Meta::Module::_get_all_metaclass_instances;
  82     *get_all_metaclass_names     = \&Mouse::Meta::Module::_get_all_metaclass_names;
  83
  84     # is-a predicates
  85     generate_isa_predicate_for('Mouse::Meta::TypeConstraint' => 'is_a_type_constraint');
  86     generate_isa_predicate_for('Mouse::Meta::Class'          => 'is_a_metaclass');
  87     generate_isa_predicate_for('Mouse::Meta::Role'           => 'is_a_metarole');
  88 }
  89
  90 our $in_global_destruction = 0;
  91 END{ $in_global_destruction = 1 }
  92
  93 # Moose::Util compatible utilities
  94
  95 sub find_meta{
  96     return class_of( $_[0] );
  97 }
  98
  99 sub does_role{
 100     my ($class_or_obj, $role_name) = @_;
 101
 102     my $meta = class_of($class_or_obj);
 103
 104     (defined $role_name)
 105         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
 106
 107     return defined($meta) && $meta->does_role($role_name);
 108 }
 109
 110 BEGIN {
 111     my $get_linear_isa;
 112     if ($] >= 5.009_005) {
 113         require mro;
 114         $get_linear_isa = \&mro::get_linear_isa;
 115     } else {
 116 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
 117         my $_get_linear_isa_dfs; # this recurses so it isn't pretty
 118         $_get_linear_isa_dfs = sub {
 119             my($classname) = @_;
 120
 121             my @lin = ($classname);
 122             my %stored;
 123
 124             no strict 'refs';
 125             foreach my $parent (@{"$classname\::ISA"}) {
 126                 my $plin = $_get_linear_isa_dfs->($parent);
 127                 foreach  my $p(@$plin) {
 128                     next if exists $stored{$p};
 129                     push(@lin, $p);
 130                     $stored{$p} = 1;
 131                 }
 132             }
 133             return \@lin;
 134         };
 135 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
 136
 137         eval{ require Class::C3 };
 138
 139         # MRO::Compat::__get_linear_isa has no prototype, so
 140         # we define a prototyped version for compatibility with core's
 141         # See also MRO::Compat::__get_linear_isa.
 142         $get_linear_isa = sub ($;$){
 143             my($classname, $type) = @_;
 144             if(!defined $type){
 145                 package Class::C3;
 146                 our %MRO;
 147                 $type = exists $MRO{$classname} ? 'c3' : 'dfs';
 148             }
 149             return $type eq 'c3'
 150                 ? [Class::C3::calculateMRO($classname)]
 151                 : $_get_linear_isa_dfs->($classname);\r
 152         };
 153     }
 154
 155     *get_linear_isa = $get_linear_isa;
 156 }
 157
 158
 159 # taken from Mouse::Util (0.90)
 160 {
 161     my %cache;
 162
 163     sub resolve_metaclass_alias {
 164         my ( $type, $metaclass_name, %options ) = @_;
 165
 166         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 167
 168         return $cache{$cache_key}{$metaclass_name} ||= do{
 169
 170             my $possible_full_name = join '::',
 171                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 172             ;
 173
 174             my $loaded_class = load_first_existing_class(
 175                 $possible_full_name,
 176                 $metaclass_name
 177             );
 178
 179             $loaded_class->can('register_implementation')
 180                 ? $loaded_class->register_implementation
 181                 : $loaded_class;
 182         };
 183     }
 184 }
 185
 186 # Utilities from Class::MOP
 187
 188 sub get_code_info;
 189 sub get_code_package;
 190
 191 # taken from Class/MOP.pm
 192 sub is_valid_class_name {
 193     my $class = shift;
 194
 195     return 0 if ref($class);
 196     return 0 unless defined($class);
 197
 198     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
 199
 200     return 0;
 201 }
 202
 203 # taken from Class/MOP.pm
 204 sub load_first_existing_class {
 205     my @classes = @_
 206       or return;
 207
 208     my %exceptions;
 209     for my $class (@classes) {
 210         my $e = _try_load_one_class($class);
 211
 212         if ($e) {
 213             $exceptions{$class} = $e;
 214         }
 215         else {
 216             return $class;
 217         }
 218     }
 219
 220     # not found
 221     Carp::confess join(
 222         "\n",
 223         map {
 224             sprintf( "Could not load class (%s) because : %s",
 225                 $_, $exceptions{$_} )
 226           } @classes
 227     );
 228 }
 229
 230 # taken from Class/MOP.pm
 231 my %is_class_loaded_cache;
 232 sub _try_load_one_class {
 233     my $class = shift;
 234
 235     unless ( is_valid_class_name($class) ) {
 236         my $display = defined($class) ? $class : 'undef';
 237         Carp::confess "Invalid class name ($display)";
 238     }
 239
 240     return undef if $is_class_loaded_cache{$class} ||= is_class_loaded($class);
 241
 242     my $file = $class . '.pm';
 243     $file =~ s{::}{/}g;
 244
 245     return do {
 246         local $@;
 247         eval { require($file) };
 248         $@;
 249     };
 250 }
 251
 252
 253 sub load_class {
 254     my $class = shift;
 255     my $e = _try_load_one_class($class);
 256     Carp::confess "Could not load class ($class) because : $e" if $e;
 257
 258     return 1;
 259 }
 260
 261 sub is_class_loaded;
 262
 263
 264 sub apply_all_roles {
 265     my $applicant = Scalar::Util::blessed($_[0])
 266         ?                                shift   # instance
 267         : Mouse::Meta::Class->initialize(shift); # class or role name
 268
 269     my @roles;
 270
 271     # Basis of Data::OptList
 272     my $max = scalar(@_);
 273     for (my $i = 0; $i < $max ; $i++) {
 274         if ($i + 1 < $max && ref($_[$i + 1])) {
 275             push @roles, [ $_[$i] => $_[++$i] ];
 276         } else {
 277             push @roles, [ $_[$i] => undef ];
 278         }
 279         my $role_name = $roles[-1][0];
 280         load_class($role_name);
 281
 282         is_a_metarole( get_metaclass_by_name($role_name) )
 283             || $applicant->meta->throw_error("You can only consume roles, $role_name is not a Mouse role");
 284     }
 285
 286     if ( scalar @roles == 1 ) {
 287         my ( $role_name, $params ) = @{ $roles[0] };
 288         get_metaclass_by_name($role_name)->apply( $applicant, defined $params ? $params : () );
 289     }
 290     else {
 291         Mouse::Meta::Role->combine(@roles)->apply($applicant);
 292     }
 293     return;
 294 }
 295
 296 # taken from Moose::Util 0.90
 297 sub english_list {
 298     return $_[0] if @_ == 1;
 299
 300     my @items = sort @_;
 301
 302     return "$items[0] and $items[1]" if @items == 2;
 303
 304     my $tail = pop @items;
 305
 306     return join q{, }, @items, "and $tail";
 307 }
 308
 309
 310 # common utilities
 311
 312 sub not_supported{
 313     my($feature) = @_;
 314
 315     $feature ||= ( caller(1) )[3]; # subroutine name
 316
 317     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 318     Carp::confess("Mouse does not currently support $feature");
 319 }
 320
 321 # general meta() method
 322 sub meta :method{
 323     return Mouse::Meta::Class->initialize(ref($_[0]) || $_[0]);
 324 }
 325
 326 # general dump() method
 327 sub dump :method {
 328     my($self, $maxdepth) = @_;
 329
 330     require 'Data/Dumper.pm'; # we don't want to create its namespace
 331     my $dd = Data::Dumper->new([$self]);
 332     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 333     $dd->Indent(1);
 334     return $dd->Dump();
 335 }
 336
 337 # general does() method
 338 sub does :method;
 339 *does = \&does_role; # alias
 340
 341 1;
 342
 343 __END__
 344
 345 =head1 NAME
 346
 347 Mouse::Util - Features, with or without their dependencies
 348
 349 =head1 VERSION
 350
 351 This document describes Mouse version 0.40_08
 352
 353 =head1 IMPLEMENTATIONS FOR
 354
 355 =head2 Moose::Util
 356
 357 =head3 C<find_meta>
 358
 359 =head3 C<does_role>
 360
 361 =head3 C<resolve_metaclass_alias>
 362
 363 =head3 C<apply_all_roles>
 364
 365 =head3 C<english_list>
 366
 367 =head2 Class::MOP
 368
 369 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 370
 371 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 372 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 373 locally-defined method.
 374
 375 =head3 C<< load_class(ClassName) >>
 376
 377 This will load a given C<ClassName> (or die if it is not loadable).
 378 This function can be used in place of tricks like
 379 C<eval "use $module"> or using C<require>.
 380
 381 =head3 C<< Mouse::Util::class_of(ClassName or Object) >>
 382
 383 =head3 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 384
 385 =head3 C<< Mouse::Util::get_all_metaclass_instances() >>
 386
 387 =head3 C<< Mouse::Util::get_all_metaclass_names() >>
 388
 389 =head2 MRO::Compat
 390
 391 =head3 C<get_linear_isa>
 392
 393 =head2 Sub::Identify
 394
 395 =head3 C<get_code_info>
 396
 397 =head1 UTILITIES FOR MOUSE
 398
 399 =head3 C<not_supported>
 400
 401 =head1 SEE ALSO
 402
 403 L<Moose::Util>
 404
 405 L<Class::MOP>
 406
 407 L<Sub::Identify>
 408
 409 L<MRO::Compat>
 410
 411 =cut
 412