lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use strict;
   3 use warnings;
   4
   5 use Exporter;
   6
   7 use Carp qw(confess);
   8 use B ();
   9
  10 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  11
  12 our @ISA       = qw(Exporter);
  13 our @EXPORT_OK = qw(
  14     find_meta
  15     does_role
  16     resolve_metaclass_alias
  17     apply_all_roles
  18     english_list
  19
  20     load_class
  21     is_class_loaded
  22
  23     get_linear_isa
  24     get_code_info
  25
  26     get_code_package
  27
  28     not_supported
  29
  30     does meta dump
  31     _MOUSE_VERBOSE
  32 );
  33 our %EXPORT_TAGS = (
  34     all  => \@EXPORT_OK,
  35     meta => [qw(does meta dump _MOUSE_VERBOSE)],
  36 );
  37
  38 # Moose::Util compatible utilities
  39
  40 sub find_meta{
  41     return Mouse::Meta::Module::class_of( $_[0] );
  42 }
  43
  44 sub does_role{
  45     my ($class_or_obj, $role_name) = @_;
  46
  47     my $meta = Mouse::Meta::Module::class_of($class_or_obj);
  48
  49     (defined $role_name)
  50         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  51
  52     return defined($meta) && $meta->does_role($role_name);
  53 }
  54
  55
  56
  57 BEGIN {
  58     my $impl;
  59     if ($] >= 5.009_005) {
  60         require mro;
  61         $impl = \&mro::get_linear_isa;
  62     } else {
  63         my $e = do {
  64             local $@;
  65             eval { require MRO::Compat };
  66             $@;
  67         };
  68         if (!$e) {
  69             $impl = \&mro::get_linear_isa;
  70         } else {
  71 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
  72             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
  73             $_get_linear_isa_dfs = sub {
  74                 no strict 'refs';
  75
  76                 my $classname = shift;
  77
  78                 my @lin = ($classname);
  79                 my %stored;
  80                 foreach my $parent (@{"$classname\::ISA"}) {
  81                     my $plin = $_get_linear_isa_dfs->($parent);
  82                     foreach  my $p(@$plin) {
  83                         next if exists $stored{$p};
  84                         push(@lin, $p);
  85                         $stored{$p} = 1;
  86                     }
  87                 }
  88                 return \@lin;
  89             };
  90 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
  91             $impl = $_get_linear_isa_dfs;
  92         }
  93     }
  94
  95
  96     no warnings 'once';
  97     *get_linear_isa = $impl;
  98 }
  99
 100 { # taken from Sub::Identify
 101     sub get_code_info($) {
 102         my ($coderef) = @_;
 103         ref($coderef) or return;
 104
 105         my $cv = B::svref_2object($coderef);
 106         $cv->isa('B::CV') or return;
 107
 108         my $gv = $cv->GV;
 109         $gv->isa('B::GV') or return;
 110
 111         return ($gv->STASH->NAME, $gv->NAME);
 112     }
 113
 114     sub get_code_package{
 115         my($coderef) = @_;
 116
 117         my $cv = B::svref_2object($coderef);
 118         $cv->isa('B::CV') or return '';
 119
 120         my $gv = $cv->GV;
 121         $gv->isa('B::GV') or return '';
 122
 123         return $gv->STASH->NAME;
 124     }
 125 }
 126
 127 # taken from Mouse::Util (0.90)
 128 {
 129     my %cache;
 130
 131     sub resolve_metaclass_alias {
 132         my ( $type, $metaclass_name, %options ) = @_;
 133
 134         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 135
 136         return $cache{$cache_key}{$metaclass_name} ||= do{
 137
 138             my $possible_full_name = join '::',
 139                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 140             ;
 141
 142             my $loaded_class = load_first_existing_class(
 143                 $possible_full_name,
 144                 $metaclass_name
 145             );
 146
 147             $loaded_class->can('register_implementation')
 148                 ? $loaded_class->register_implementation
 149                 : $loaded_class;
 150         };
 151     }
 152 }
 153
 154 # taken from Class/MOP.pm
 155 sub is_valid_class_name {
 156     my $class = shift;
 157
 158     return 0 if ref($class);
 159     return 0 unless defined($class);
 160
 161     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 162
 163     return 0;
 164 }
 165
 166 # taken from Class/MOP.pm
 167 sub load_first_existing_class {
 168     my @classes = @_
 169       or return;
 170
 171     my %exceptions;
 172     for my $class (@classes) {
 173         my $e = _try_load_one_class($class);
 174
 175         if ($e) {
 176             $exceptions{$class} = $e;
 177         }
 178         else {
 179             return $class;
 180         }
 181     }
 182
 183     # not found
 184     confess join(
 185         "\n",
 186         map {
 187             sprintf( "Could not load class (%s) because : %s",
 188                 $_, $exceptions{$_} )
 189           } @classes
 190     );
 191 }
 192
 193 # taken from Class/MOP.pm
 194 sub _try_load_one_class {
 195     my $class = shift;
 196
 197     unless ( is_valid_class_name($class) ) {
 198         my $display = defined($class) ? $class : 'undef';
 199         confess "Invalid class name ($display)";
 200     }
 201
 202     return if is_class_loaded($class);
 203
 204     my $file = $class . '.pm';
 205     $file =~ s{::}{/}g;
 206
 207     return do {
 208         local $@;
 209         eval { require($file) };
 210         $@;
 211     };
 212 }
 213
 214
 215 sub load_class {
 216     my $class = shift;
 217     my $e = _try_load_one_class($class);
 218     confess "Could not load class ($class) because : $e" if $e;
 219
 220     return 1;
 221 }
 222
 223 my %is_class_loaded_cache;
 224 sub is_class_loaded {
 225     my $class = shift;
 226
 227     return 0 if ref($class) || !defined($class) || !length($class);
 228
 229     return 1 if $is_class_loaded_cache{$class};
 230
 231     # walk the symbol table tree to avoid autovififying
 232     # \*{${main::}{"Foo::"}} == \*main::Foo::
 233
 234     my $pack = \%::;
 235     foreach my $part (split('::', $class)) {
 236         my $entry = \$pack->{$part . '::'};
 237         return 0 if ref($entry) ne 'GLOB';
 238         $pack = *{$entry}{HASH} or return 0;
 239     }
 240
 241     # check for $VERSION or @ISA
 242     return ++$is_class_loaded_cache{$class} if exists $pack->{VERSION}
 243              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
 244     return ++$is_class_loaded_cache{$class} if exists $pack->{ISA}
 245              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
 246
 247     # check for any method
 248     foreach my $name( keys %{$pack} ) {
 249         my $entry = \$pack->{$name};
 250         return ++$is_class_loaded_cache{$class} if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
 251     }
 252
 253     # fail
 254     return 0;
 255 }
 256
 257
 258 sub apply_all_roles {
 259     my $meta = Mouse::Meta::Class->initialize(shift);
 260
 261     my @roles;
 262
 263     # Basis of Data::OptList
 264     my $max = scalar(@_);
 265     for (my $i = 0; $i < $max ; $i++) {
 266         if ($i + 1 < $max && ref($_[$i + 1])) {
 267             push @roles, [ $_[$i++] => $_[$i] ];
 268         } else {
 269             push @roles, [ $_[$i]   => undef ];
 270         }
 271         my $role_name = $roles[-1][0];
 272         load_class($role_name);
 273         ( $role_name->can('meta') && $role_name->meta->isa('Mouse::Meta::Role') )
 274             || $meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 275     }
 276
 277     if ( scalar @roles == 1 ) {
 278         my ( $role, $params ) = @{ $roles[0] };
 279         $role->meta->apply( $meta, ( defined $params ? %$params : () ) );
 280     }
 281     else {
 282         Mouse::Meta::Role->combine_apply($meta, @roles);
 283     }
 284     return;
 285 }
 286
 287 # taken from Moose::Util 0.90
 288 sub english_list {
 289     return $_[0] if @_ == 1;
 290
 291     my @items = sort @_;
 292
 293     return "$items[0] and $items[1]" if @items == 2;
 294
 295     my $tail = pop @items;
 296
 297     return join q{, }, @items, "and $tail";
 298 }
 299
 300
 301 # common utilities
 302
 303 sub not_supported{
 304     my($feature) = @_;
 305
 306     $feature ||= ( caller(1) )[3]; # subroutine name
 307
 308     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 309     Carp::confess("Mouse does not currently support $feature");
 310 }
 311
 312 sub meta{
 313     return Mouse::Meta::Class->initialize($_[0]);
 314 }
 315
 316 sub dump {
 317     my($self, $maxdepth) = @_;
 318
 319     require 'Data/Dumper.pm'; # we don't want to create its namespace
 320     my $dd = Data::Dumper->new([$self]);
 321     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 322     $dd->Indent(1);
 323     return $dd->Dump();
 324 }
 325
 326 sub does :method;
 327 *does = \&does_role; # alias
 328
 329 1;
 330
 331 __END__
 332
 333 =head1 NAME
 334
 335 Mouse::Util - features, with or without their dependencies
 336
 337 =head1 IMPLEMENTATIONS FOR
 338
 339 =head2 Moose::Util
 340
 341 =head3 C<find_meta>
 342
 343 =head3 C<does_role>
 344
 345 =head3 C<resolve_metaclass_alias>
 346
 347 =head3 C<apply_all_roles>
 348
 349 =head3 C<english_list>
 350
 351 =head2 Class::MOP
 352
 353 =head2 C<< is_class_loaded(ClassName) -> Bool >>
 354
 355 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 356 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 357 locally-defined method.
 358
 359 =head3 C<< load_class(ClassName) >>
 360
 361 This will load a given C<ClassName> (or die if it's not loadable).
 362 This function can be used in place of tricks like
 363 C<eval "use $module"> or using C<require>.
 364
 365 =head2 MRO::Compat
 366
 367 =head3 C<get_linear_isa>
 368
 369 =head2 Sub::Identify
 370
 371 =head3 C<get_code_info>
 372
 373 =head1 UTILITIES FOR MOUSE
 374
 375 =over 4
 376
 377 =item *
 378
 379 C<not_supported>
 380
 381 =back
 382
 383 =head1 SEE ALSO
 384
 385 L<Moose::Util>
 386
 387 L<Scalar::Util>
 388
 389 L<Sub::Identify>
 390
 391 L<MRO::Compat>
 392
 393 =cut
 394