lib/Mouse/Util.pm

   1 package Mouse::Util;
   2 use strict;
   3 use warnings;
   4
   5 use Exporter;
   6
   7 use Carp qw(confess);
   8 use B ();
   9
  10 use constant _MOUSE_VERBOSE => !!$ENV{MOUSE_VERBOSE};
  11
  12 our @ISA       = qw(Exporter);
  13 our @EXPORT_OK = qw(
  14     find_meta
  15     does_role
  16     resolve_metaclass_alias
  17     apply_all_roles
  18     english_list
  19
  20     load_class
  21     is_class_loaded
  22
  23     get_linear_isa
  24     get_code_info
  25
  26     get_code_package
  27
  28     not_supported
  29
  30     does meta dump
  31     _MOUSE_VERBOSE
  32 );
  33 our %EXPORT_TAGS = (
  34     all  => \@EXPORT_OK,
  35     meta => [qw(does meta dump _MOUSE_VERBOSE)],
  36 );
  37
  38 # aliases as public APIs
  39
  40 BEGIN{
  41     *class_of                    = \&Mouse::Meta::Module::class_of;
  42     *get_metaclass_by_name       = \&Mouse::Meta::Module::get_metaclass_by_name;
  43     *get_all_metaclass_instances = \&Mouse::Meta::Module::get_all_metaclass_instances;
  44     *get_all_metaclass_names     = \&Mouse::Meta::Module::get_all_metaclass_names;
  45 }
  46
  47 # Moose::Util compatible utilities
  48
  49 sub find_meta{
  50     return class_of( $_[0] );
  51 }
  52
  53 sub does_role{
  54     my ($class_or_obj, $role_name) = @_;
  55
  56     my $meta = class_of($class_or_obj);
  57
  58     (defined $role_name)
  59         || ($meta || 'Mouse::Meta::Class')->throw_error("You must supply a role name to does()");
  60
  61     return defined($meta) && $meta->does_role($role_name);
  62 }
  63
  64 BEGIN {
  65     my $impl;
  66     if ($] >= 5.009_005) {
  67         require mro;
  68         $impl = \&mro::get_linear_isa;
  69     } else {
  70         my $e = do {
  71             local $@;
  72             eval { require MRO::Compat };
  73             $@;
  74         };
  75         if (!$e) {
  76             $impl = \&mro::get_linear_isa;
  77         } else {
  78 #       VVVVV   CODE TAKEN FROM MRO::COMPAT   VVVVV
  79             my $_get_linear_isa_dfs; # this recurses so it isn't pretty
  80             $_get_linear_isa_dfs = sub {
  81                 no strict 'refs';
  82
  83                 my $classname = shift;
  84
  85                 my @lin = ($classname);
  86                 my %stored;
  87                 foreach my $parent (@{"$classname\::ISA"}) {
  88                     my $plin = $_get_linear_isa_dfs->($parent);
  89                     foreach  my $p(@$plin) {
  90                         next if exists $stored{$p};
  91                         push(@lin, $p);
  92                         $stored{$p} = 1;
  93                     }
  94                 }
  95                 return \@lin;
  96             };
  97 #       ^^^^^   CODE TAKEN FROM MRO::COMPAT   ^^^^^
  98             $impl = $_get_linear_isa_dfs;
  99         }
 100     }
 101
 102
 103     no warnings 'once';
 104     *get_linear_isa = $impl;
 105 }
 106
 107 { # taken from Sub::Identify
 108     sub get_code_info($) {
 109         my ($coderef) = @_;
 110         ref($coderef) or return;
 111
 112         my $cv = B::svref_2object($coderef);
 113         $cv->isa('B::CV') or return;
 114
 115         my $gv = $cv->GV;
 116         $gv->isa('B::GV') or return;
 117
 118         return ($gv->STASH->NAME, $gv->NAME);
 119     }
 120
 121     sub get_code_package{
 122         my($coderef) = @_;
 123
 124         my $cv = B::svref_2object($coderef);
 125         $cv->isa('B::CV') or return '';
 126
 127         my $gv = $cv->GV;
 128         $gv->isa('B::GV') or return '';
 129
 130         return $gv->STASH->NAME;
 131     }
 132 }
 133
 134 # taken from Mouse::Util (0.90)
 135 {
 136     my %cache;
 137
 138     sub resolve_metaclass_alias {
 139         my ( $type, $metaclass_name, %options ) = @_;
 140
 141         my $cache_key = $type . q{ } . ( $options{trait} ? '-Trait' : '' );
 142
 143         return $cache{$cache_key}{$metaclass_name} ||= do{
 144
 145             my $possible_full_name = join '::',
 146                 'Mouse::Meta', $type, 'Custom', ($options{trait} ? 'Trait' : ()), $metaclass_name
 147             ;
 148
 149             my $loaded_class = load_first_existing_class(
 150                 $possible_full_name,
 151                 $metaclass_name
 152             );
 153
 154             $loaded_class->can('register_implementation')
 155                 ? $loaded_class->register_implementation
 156                 : $loaded_class;
 157         };
 158     }
 159 }
 160
 161 # Utilities from Class::MOP
 162
 163
 164 # taken from Class/MOP.pm
 165 sub is_valid_class_name {
 166     my $class = shift;
 167
 168     return 0 if ref($class);
 169     return 0 unless defined($class);
 170
 171     return 1 if $class =~ /^\w+(?:::\w+)*$/;
 172
 173     return 0;
 174 }
 175
 176 # taken from Class/MOP.pm
 177 sub load_first_existing_class {
 178     my @classes = @_
 179       or return;
 180
 181     my %exceptions;
 182     for my $class (@classes) {
 183         my $e = _try_load_one_class($class);
 184
 185         if ($e) {
 186             $exceptions{$class} = $e;
 187         }
 188         else {
 189             return $class;
 190         }
 191     }
 192
 193     # not found
 194     confess join(
 195         "\n",
 196         map {
 197             sprintf( "Could not load class (%s) because : %s",
 198                 $_, $exceptions{$_} )
 199           } @classes
 200     );
 201 }
 202
 203 # taken from Class/MOP.pm
 204 sub _try_load_one_class {
 205     my $class = shift;
 206
 207     unless ( is_valid_class_name($class) ) {
 208         my $display = defined($class) ? $class : 'undef';
 209         confess "Invalid class name ($display)";
 210     }
 211
 212     return if is_class_loaded($class);
 213
 214     my $file = $class . '.pm';
 215     $file =~ s{::}{/}g;
 216
 217     return do {
 218         local $@;
 219         eval { require($file) };
 220         $@;
 221     };
 222 }
 223
 224
 225 sub load_class {
 226     my $class = shift;
 227     my $e = _try_load_one_class($class);
 228     confess "Could not load class ($class) because : $e" if $e;
 229
 230     return 1;
 231 }
 232
 233 my %is_class_loaded_cache;
 234 sub is_class_loaded {
 235     my $class = shift;
 236
 237     return 0 if ref($class) || !defined($class) || !length($class);
 238
 239     return 1 if $is_class_loaded_cache{$class};
 240
 241     # walk the symbol table tree to avoid autovififying
 242     # \*{${main::}{"Foo::"}} == \*main::Foo::
 243
 244     my $pack = \%::;
 245     foreach my $part (split('::', $class)) {
 246         my $entry = \$pack->{$part . '::'};
 247         return 0 if ref($entry) ne 'GLOB';
 248         $pack = *{$entry}{HASH} or return 0;
 249     }
 250
 251     # check for $VERSION or @ISA
 252     return ++$is_class_loaded_cache{$class} if exists $pack->{VERSION}
 253              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
 254     return ++$is_class_loaded_cache{$class} if exists $pack->{ISA}
 255              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
 256
 257     # check for any method
 258     foreach my $name( keys %{$pack} ) {
 259         my $entry = \$pack->{$name};
 260         return ++$is_class_loaded_cache{$class} if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
 261     }
 262
 263     # fail
 264     return 0;
 265 }
 266
 267
 268 sub apply_all_roles {
 269     my $meta = Mouse::Meta::Class->initialize(shift);
 270
 271     my @roles;
 272
 273     # Basis of Data::OptList
 274     my $max = scalar(@_);
 275     for (my $i = 0; $i < $max ; $i++) {
 276         if ($i + 1 < $max && ref($_[$i + 1])) {
 277             push @roles, [ $_[$i++] => $_[$i] ];
 278         } else {
 279             push @roles, [ $_[$i]   => undef ];
 280         }
 281         my $role_name = $roles[-1][0];
 282         load_class($role_name);
 283         ( $role_name->can('meta') && $role_name->meta->isa('Mouse::Meta::Role') )
 284             || $meta->throw_error("You can only consume roles, $role_name(".$role_name->meta.") is not a Mouse role");
 285     }
 286
 287     if ( scalar @roles == 1 ) {
 288         my ( $role, $params ) = @{ $roles[0] };
 289         $role->meta->apply( $meta, ( defined $params ? %$params : () ) );
 290     }
 291     else {
 292         Mouse::Meta::Role->combine_apply($meta, @roles);
 293     }
 294     return;
 295 }
 296
 297 # taken from Moose::Util 0.90
 298 sub english_list {
 299     return $_[0] if @_ == 1;
 300
 301     my @items = sort @_;
 302
 303     return "$items[0] and $items[1]" if @items == 2;
 304
 305     my $tail = pop @items;
 306
 307     return join q{, }, @items, "and $tail";
 308 }
 309
 310
 311 # common utilities
 312
 313 sub not_supported{
 314     my($feature) = @_;
 315
 316     $feature ||= ( caller(1) )[3]; # subroutine name
 317
 318     local $Carp::CarpLevel = $Carp::CarpLevel + 1;
 319     Carp::confess("Mouse does not currently support $feature");
 320 }
 321
 322 sub meta{
 323     return Mouse::Meta::Class->initialize($_[0]);
 324 }
 325
 326 sub dump {
 327     my($self, $maxdepth) = @_;
 328
 329     require 'Data/Dumper.pm'; # we don't want to create its namespace
 330     my $dd = Data::Dumper->new([$self]);
 331     $dd->Maxdepth(defined($maxdepth) ? $maxdepth : 2);
 332     $dd->Indent(1);
 333     return $dd->Dump();
 334 }
 335
 336 sub does :method;
 337 *does = \&does_role; # alias
 338
 339 1;
 340
 341 __END__
 342
 343 =head1 NAME
 344
 345 Mouse::Util - Features, with or without their dependencies
 346
 347 =head1 IMPLEMENTATIONS FOR
 348
 349 =head2 Moose::Util
 350
 351 =head3 C<find_meta>
 352
 353 =head3 C<does_role>
 354
 355 =head3 C<resolve_metaclass_alias>
 356
 357 =head3 C<apply_all_roles>
 358
 359 =head3 C<english_list>
 360
 361 =head2 Class::MOP
 362
 363 =head3 C<< is_class_loaded(ClassName) -> Bool >>
 364
 365 Returns whether C<ClassName> is actually loaded or not. It uses a heuristic which
 366 involves checking for the existence of C<$VERSION>, C<@ISA>, and any
 367 locally-defined method.
 368
 369 =head3 C<< load_class(ClassName) >>
 370
 371 This will load a given C<ClassName> (or die if it is not loadable).
 372 This function can be used in place of tricks like
 373 C<eval "use $module"> or using C<require>.
 374
 375 =head2 C<< Mouse::Util::class_of(ClassName) >>
 376
 377 The counterpart of C<Class::MOP::class_of()>. This is not exportable.
 378
 379 =head2 C<< Mouse::Util::get_metaclass_by_name(ClassName) >>
 380
 381 The counterpart of C<Class::MOP::get_metaclass_by_name()>. This is not exportable.
 382
 383 =head2 MRO::Compat
 384
 385 =head3 C<get_linear_isa>
 386
 387 =head2 Sub::Identify
 388
 389 =head3 C<get_code_info>
 390
 391 =head1 UTILITIES FOR MOUSE
 392
 393 =head3 C<not_supported>
 394
 395 =head1 SEE ALSO
 396
 397 L<Moose::Util>
 398
 399 L<Scalar::Util>
 400
 401 L<Sub::Identify>
 402
 403 L<MRO::Compat>
 404
 405 =cut
 406