lib/Mouse/TypeRegistry.pm

   1 #!/usr/bin/env perl
   2 package Mouse::TypeRegistry;
   3 use strict;
   4 use warnings;
   5
   6 use Carp ();
   7 use Scalar::Util qw/blessed looks_like_number openhandle/;
   8
   9 my %SUBTYPE;
  10 my %COERCE;
  11 my %COERCE_KEYS;
  12
  13 #find_type_constraint register_type_constraint
  14 sub import {
  15     my $class  = shift;
  16     my %args   = @_;
  17     my $caller = $args{callee} || caller(0);
  18
  19     no strict 'refs';
  20     *{"$caller\::as"}          = \&_as;
  21     *{"$caller\::where"}       = \&_where;
  22     *{"$caller\::message"}     = \&_message;
  23     *{"$caller\::from"}        = \&_from;
  24     *{"$caller\::via"}         = \&_via;
  25     *{"$caller\::subtype"}     = \&_subtype;
  26     *{"$caller\::coerce"}      = \&_coerce;
  27     *{"$caller\::class_type"}  = \&_class_type;
  28     *{"$caller\::role_type"}   = \&_role_type;
  29 }
  30
  31
  32 sub _as ($) {
  33     as => $_[0]
  34 }
  35 sub _where (&) {
  36     where => $_[0]
  37 }
  38 sub _message ($) {
  39     message => $_[0]
  40 }
  41
  42 sub _from { @_ }
  43 sub _via (&) {
  44     $_[0]
  45 }
  46
  47 my $optimized_constraints;
  48 my $optimized_constraints_base;
  49 {
  50     no warnings 'uninitialized';
  51     %SUBTYPE = (
  52         Any        => sub { 1 },
  53         Item       => sub { 1 },
  54         Bool       => sub {
  55             !defined($_) || $_ eq "" || "$_" eq '1' || "$_" eq '0'
  56         },
  57         Undef      => sub { !defined($_) },
  58         Defined    => sub { defined($_) },
  59         Value      => sub { defined($_) && !ref($_) },
  60         Num        => sub { !ref($_) && looks_like_number($_) },
  61         Int        => sub { defined($_) && !ref($_) && /^-?[0-9]+$/ },
  62         Str        => sub { defined($_) && !ref($_) },
  63         ClassName  => sub { Mouse::is_class_loaded($_) },
  64         Ref        => sub { ref($_) },
  65
  66         ScalarRef  => sub { ref($_) eq 'SCALAR' },
  67         ArrayRef   => sub { ref($_) eq 'ARRAY'  },
  68         HashRef    => sub { ref($_) eq 'HASH'   },
  69         CodeRef    => sub { ref($_) eq 'CODE'   },
  70         RegexpRef  => sub { ref($_) eq 'Regexp' },
  71         GlobRef    => sub { ref($_) eq 'GLOB'   },
  72
  73         FileHandle => sub {
  74                 ref($_) eq 'GLOB'
  75                 && openhandle($_)
  76             or
  77                 blessed($_)
  78                 && $_->isa("IO::Handle")
  79             },
  80
  81         Object     => sub { blessed($_) && blessed($_) ne 'Regexp' },
  82     );
  83
  84     sub optimized_constraints { \%SUBTYPE }
  85     my @SUBTYPE_KEYS = keys %SUBTYPE;
  86     sub list_all_builtin_type_constraints { @SUBTYPE_KEYS }
  87 }
  88
  89 sub _subtype {
  90     my $pkg = caller(0);
  91     my($name, %conf) = @_;
  92     if (my $type = $SUBTYPE{$name}) {
  93         Carp::croak "The type constraint '$name' has already been created, cannot be created again in $pkg";
  94     };
  95     my $as = $conf{as};
  96     my $stuff = $conf{where} || $SUBTYPE{$as};
  97
  98     $SUBTYPE{$name} = $stuff;
  99 }
 100
 101 sub _coerce {
 102     my($name, %conf) = @_;
 103
 104     Carp::croak "Cannot find type '$name', perhaps you forgot to load it."
 105         unless $SUBTYPE{$name};
 106
 107     unless ($COERCE{$name}) {
 108         $COERCE{$name}      = {};
 109         $COERCE_KEYS{$name} = [];
 110     }
 111     while (my($type, $code) = each %conf) {
 112         Carp::croak "A coercion action already exists for '$type'"
 113             if $COERCE{$name}->{$type};
 114
 115         Carp::croak "Could not find the type constraint ($type) to coerce from"
 116             unless $SUBTYPE{$type};
 117
 118         push @{ $COERCE_KEYS{$name} }, $type;
 119         $COERCE{$name}->{$type} = $code;
 120     }
 121 }
 122
 123 sub _class_type {
 124     my $pkg = caller(0);
 125     my($name, $conf) = @_;
 126     my $class = $conf->{class};
 127     _subtype(
 128         $name => where => sub {
 129             defined $_ && ref($_) eq $class;
 130         }
 131     );
 132 }
 133
 134 sub _role_type {
 135     my($name, $conf) = @_;
 136     my $role = $conf->{role};
 137     _subtype(
 138         $name => where => sub {
 139             return unless defined $_ && ref($_) && $_->isa('Mouse::Object');
 140             $_->meta->does_role($role);
 141         }
 142     );
 143 }
 144
 145 sub typecast_constraints {
 146     my($class, $pkg, $type_constraint, $types, $value) = @_;
 147
 148     local $_;
 149     for my $type (ref($types) eq 'ARRAY' ? @{ $types } : ( $types )) {
 150         next unless $COERCE{$type};
 151         for my $coerce_type (@{ $COERCE_KEYS{$type}}) {
 152             $_ = $value;
 153             next unless $SUBTYPE{$coerce_type}->();
 154             $_ = $value;
 155             $_ = $COERCE{$type}->{$coerce_type}->();
 156             return $_ if $type_constraint->();
 157         }
 158     }
 159     return $value;
 160 }
 161
 162 1;
 163
 164 __END__
 165
 166 =head1 NAME
 167
 168 Mouse::TypeRegistry - simple type constraints
 169
 170 =head1 METHODS
 171
 172 =head2 optimized_constraints -> HashRef[CODE]
 173
 174 Returns the simple type constraints that Mouse understands.
 175
 176 =cut
 177
 178