lib/Mouse/Role.pm

   1 package Mouse::Role;
   2 use strict;
   3 use warnings;
   4 use base 'Exporter';
   5
   6 use Carp 'confess';
   7 use Scalar::Util 'blessed';
   8
   9 use Mouse::Meta::Role;
  10
  11 our @EXPORT = qw(before after around has extends with requires excludes confess blessed);
  12
  13 sub before {
  14     my $meta = Mouse::Meta::Role->initialize(caller);
  15
  16     my $code = pop;
  17     for (@_) {
  18         $meta->add_before_method_modifier($_ => $code);
  19     }
  20 }
  21
  22 sub after {
  23     my $meta = Mouse::Meta::Role->initialize(caller);
  24
  25     my $code = pop;
  26     for (@_) {
  27         $meta->add_after_method_modifier($_ => $code);
  28     }
  29 }
  30
  31 sub around {
  32     my $meta = Mouse::Meta::Role->initialize(caller);
  33
  34     my $code = pop;
  35     for (@_) {
  36         $meta->add_around_method_modifier($_ => $code);
  37     }
  38 }
  39
  40 sub has {
  41     my $meta = Mouse::Meta::Role->initialize(caller);
  42
  43     my $name = shift;
  44     my %opts = @_;
  45
  46     $meta->add_attribute($name => \%opts);
  47 }
  48
  49 sub extends  { confess "Roles do not support 'extends'" }
  50
  51 sub with     {
  52     my $meta = Mouse::Meta::Role->initialize(caller);
  53     my $role  = shift;
  54     my $args  = shift || {};
  55     confess "Mouse::Role only supports 'with' on individual roles at a time" if @_ || !ref $args;
  56
  57     Mouse::load_class($role);
  58     $role->meta->apply($meta, %$args);
  59 }
  60
  61 sub requires {
  62     my $meta = Mouse::Meta::Role->initialize(caller);
  63     Carp::croak "Must specify at least one method" unless @_;
  64     $meta->add_required_methods(@_);
  65 }
  66
  67 sub excludes { confess "Mouse::Role does not currently support 'excludes'" }
  68
  69 sub import {
  70     strict->import;
  71     warnings->import;
  72
  73     my $caller = caller;
  74     my $meta = Mouse::Meta::Role->initialize(caller);
  75
  76     no strict 'refs';
  77     no warnings 'redefine';
  78     *{$caller.'::meta'} = sub { $meta };
  79
  80     Mouse::Role->export_to_level(1, @_);
  81 }
  82
  83 sub unimport {
  84     my $caller = caller;
  85
  86     no strict 'refs';
  87     for my $keyword (@EXPORT) {
  88         delete ${ $caller . '::' }{$keyword};
  89     }
  90 }
  91
  92 1;
  93
  94 __END__
  95
  96 =head1 NAME
  97
  98 Mouse::Role
  99
 100 =head1 KEYWORDS
 101
 102 =head2 meta -> Mouse::Meta::Role
 103
 104 Returns this role's metaclass instance.
 105
 106 =head2 before (method|methods) => Code
 107
 108 Sets up a "before" method modifier. See L<Moose/before> or
 109 L<Class::Method::Modifiers/before>.
 110
 111 =head2 after (method|methods) => Code
 112
 113 Sets up an "after" method modifier. See L<Moose/after> or
 114 L<Class::Method::Modifiers/after>.
 115
 116 =head2 around (method|methods) => Code
 117
 118 Sets up an "around" method modifier. See L<Moose/around> or
 119 L<Class::Method::Modifiers/around>.
 120
 121 =head2 has (name|names) => parameters
 122
 123 Sets up an attribute (or if passed an arrayref of names, multiple attributes) to
 124 this role. See L<Mouse/has>.
 125
 126 =head2 confess error -> BOOM
 127
 128 L<Carp/confess> for your convenience.
 129
 130 =head2 blessed value -> ClassName | undef
 131
 132 L<Scalar::Util/blessed> for your convenience.
 133
 134 =head1 MISC
 135
 136 =head2 import
 137
 138 Importing Mouse::Role will give you sugar.
 139
 140 =head2 unimport
 141
 142 Please unimport Mouse (C<no Mouse::Role>) so that if someone calls one of the
 143 keywords (such as L</has>) it will break loudly instead breaking subtly.
 144
 145 =cut
 146