lib/Mouse/Role.pm

   1 package Mouse::Role;
   2 use Mouse::Util qw(not_supported); # enables strict and warnings
   3
   4 use Carp ();
   5 use Scalar::Util ();
   6
   7 use Mouse ();
   8 use Mouse::Exporter;
   9
  10 Mouse::Exporter->setup_import_methods(
  11     as_is => [qw(
  12         extends with
  13         has
  14         before after around
  15         override super
  16         augment  inner
  17
  18         requires excludes
  19     ),
  20         \&Scalar::Util::blessed,
  21         \&Carp::confess,
  22     ],
  23 );
  24
  25
  26 sub before {
  27     my $meta = Mouse::Meta::Role->initialize(scalar caller);
  28
  29     my $code = pop;
  30     for (@_) {
  31         $meta->add_before_method_modifier($_ => $code);
  32     }
  33 }
  34
  35 sub after {
  36     my $meta = Mouse::Meta::Role->initialize(scalar caller);
  37
  38     my $code = pop;
  39     for (@_) {
  40         $meta->add_after_method_modifier($_ => $code);
  41     }
  42 }
  43
  44 sub around {
  45     my $meta = Mouse::Meta::Role->initialize(scalar caller);
  46
  47     my $code = pop;
  48     for (@_) {
  49         $meta->add_around_method_modifier($_ => $code);
  50     }
  51 }
  52
  53
  54 sub super {
  55     return if !defined $Mouse::SUPER_BODY;
  56     $Mouse::SUPER_BODY->(@Mouse::SUPER_ARGS);
  57 }
  58
  59 sub override {
  60     # my($name, $code) = @_;
  61     Mouse::Meta::Role->initialize(scalar caller)->add_override_method_modifier(@_);
  62 }
  63
  64 # We keep the same errors messages as Moose::Role emits, here.
  65 sub inner {
  66     Carp::croak "Roles cannot support 'inner'";
  67 }
  68
  69 sub augment {
  70     Carp::croak "Roles cannot support 'augment'";
  71 }
  72
  73 sub has {
  74     my $meta = Mouse::Meta::Role->initialize(scalar caller);
  75     my $name = shift;
  76
  77     $meta->add_attribute($_ => @_) for ref($name) ? @{$name} : $name;
  78 }
  79
  80 sub extends  {
  81     Carp::croak "Roles do not support 'extends'"
  82 }
  83
  84 sub with     {
  85     my $meta = Mouse::Meta::Role->initialize(scalar caller);
  86     Mouse::Util::apply_all_roles($meta->name, @_);
  87 }
  88
  89 sub requires {
  90     my $meta = Mouse::Meta::Role->initialize(scalar caller);
  91     $meta->throw_error("Must specify at least one method") unless @_;
  92     $meta->add_required_methods(@_);
  93 }
  94
  95 sub excludes {
  96     not_supported;
  97 }
  98
  99 sub init_meta{
 100     my($class, %args) = @_;
 101
 102     my $for_class = $args{for_class}
 103         or Carp::confess("Cannot call init_meta without specifying a for_class");
 104
 105     my $metaclass  = $args{metaclass}  || 'Mouse::Meta::Role';
 106
 107     my $meta = $metaclass->initialize($for_class);
 108
 109     $meta->add_method(meta => sub{
 110         $metaclass->initialize(ref($_[0]) || $_[0]);
 111     });
 112
 113     return $meta;
 114 }
 115
 116 1;
 117
 118 __END__
 119
 120 =head1 NAME
 121
 122 Mouse::Role - The Mouse Role
 123
 124 =head1 SYNOPSIS
 125
 126     package MyRole;
 127     use Mouse::Role;
 128
 129 =head1 KEYWORDS
 130
 131 =head2 C<< meta -> Mouse::Meta::Role >>
 132
 133 Returns this role's metaclass instance.
 134
 135 =head2 C<< before (method|methods) -> CodeRef >>
 136
 137 Sets up a B<before> method modifier. See L<Moose/before> or
 138 L<Class::Method::Modifiers/before>.
 139
 140 =head2 C<< after (method|methods) => CodeRef >>
 141
 142 Sets up an B<after> method modifier. See L<Moose/after> or
 143 L<Class::Method::Modifiers/after>.
 144
 145 =head2 C<< around (method|methods) => CodeRef >>
 146
 147 Sets up an B<around> method modifier. See L<Moose/around> or
 148 L<Class::Method::Modifiers/around>.
 149
 150 =head2 C<super>
 151
 152 Sets up the B<super> keyword. See L<Moose/super>.
 153
 154 =head2  C<< override method => CodeRef >>
 155
 156 Sets up an B<override> method modifier. See L<Moose/Role/override>.
 157
 158 =head2 C<inner>
 159
 160 This is not supported in roles and emits an error. See L<Moose/Role>.
 161
 162 =head2 C<< augment method => CodeRef >>
 163
 164 This is not supported in roles and emits an error. See L<Moose/Role>.
 165
 166 =head2 C<< has (name|names) => parameters >>
 167
 168 Sets up an attribute (or if passed an arrayref of names, multiple attributes) to
 169 this role. See L<Mouse/has>.
 170
 171 =head2 C<< confess(error) -> BOOM >>
 172
 173 L<Carp/confess> for your convenience.
 174
 175 =head2 C<< blessed(value) -> ClassName | undef >>
 176
 177 L<Scalar::Util/blessed> for your convenience.
 178
 179 =head1 MISC
 180
 181 =head2 import
 182
 183 Importing Mouse::Role will give you sugar.
 184
 185 =head2 unimport
 186
 187 Please unimport (C<< no Mouse::Role >>) so that if someone calls one of the
 188 keywords (such as L</has>) it will break loudly instead breaking subtly.
 189
 190 =head1 SEE ALSO
 191
 192 L<Moose::Role>
 193
 194 =cut
 195