lib/Mouse/Role.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Role;
   3 use strict;
   4 use warnings;
   5 use base 'Exporter';
   6
   7 use Carp 'confess';
   8 use Mouse::Util 'blessed';
   9
  10 use Mouse::Meta::Role;
  11
  12 our @EXPORT = qw(before after around has extends with requires excludes confess blessed);
  13
  14 sub before {
  15     my $meta = Mouse::Meta::Role->initialize(caller);
  16
  17     my $code = pop;
  18     for (@_) {
  19         $meta->add_before_method_modifier($_ => $code);
  20     }
  21 }
  22
  23 sub after {
  24     my $meta = Mouse::Meta::Role->initialize(caller);
  25
  26     my $code = pop;
  27     for (@_) {
  28         $meta->add_after_method_modifier($_ => $code);
  29     }
  30 }
  31
  32 sub around {
  33     my $meta = Mouse::Meta::Role->initialize(caller);
  34
  35     my $code = pop;
  36     for (@_) {
  37         $meta->add_around_method_modifier($_ => $code);
  38     }
  39 }
  40
  41 sub has {
  42     my $meta = Mouse::Meta::Role->initialize(caller);
  43
  44     my $name = shift;
  45     my %opts = @_;
  46
  47     $meta->add_attribute($name => \%opts);
  48 }
  49
  50 sub extends  { confess "Roles do not support 'extends'" }
  51
  52 sub with     { confess "Mouse::Role does not currently support 'with'" }
  53
  54 sub requires {
  55     my $meta = Mouse::Meta::Role->initialize(caller);
  56     Carp::croak "Must specify at least one method" unless @_;
  57     $meta->add_required_methods(@_);
  58 }
  59
  60 sub excludes { confess "Mouse::Role does not currently support 'excludes'" }
  61
  62 sub import {
  63     strict->import;
  64     warnings->import;
  65
  66     my $caller = caller;
  67     my $meta = Mouse::Meta::Role->initialize(caller);
  68
  69     no strict 'refs';
  70     no warnings 'redefine';
  71     *{$caller.'::meta'} = sub { $meta };
  72
  73     Mouse::Role->export_to_level(1, @_);
  74 }
  75
  76 sub unimport {
  77     my $caller = caller;
  78
  79     no strict 'refs';
  80     for my $keyword (@EXPORT) {
  81         delete ${ $caller . '::' }{$keyword};
  82     }
  83 }
  84
  85 1;
  86
  87 __END__
  88
  89 =head1 NAME
  90
  91 Mouse::Role
  92
  93 =head1 KEYWORDS
  94
  95 =head2 meta -> Mouse::Meta::Role
  96
  97 Returns this role's metaclass instance.
  98
  99 =head2 before (method|methods) => Code
 100
 101 Sets up a "before" method modifier. See L<Moose/before> or
 102 L<Class::Method::Modifiers/before>.
 103
 104 =head2 after (method|methods) => Code
 105
 106 Sets up an "after" method modifier. See L<Moose/after> or
 107 L<Class::Method::Modifiers/after>.
 108
 109 =head2 around (method|methods) => Code
 110
 111 Sets up an "around" method modifier. See L<Moose/around> or
 112 L<Class::Method::Modifiers/around>.
 113
 114 =head2 has (name|names) => parameters
 115
 116 Sets up an attribute (or if passed an arrayref of names, multiple attributes) to
 117 this role. See L<Mouse/has>.
 118
 119 =head2 confess error -> BOOM
 120
 121 L<Carp/confess> for your convenience.
 122
 123 =head2 blessed value -> ClassName | undef
 124
 125 L<Scalar::Util/blessed> for your convenience.
 126
 127 =head1 MISC
 128
 129 =head2 import
 130
 131 Importing Mouse::Role will give you sugar.
 132
 133 =head2 unimport
 134
 135 Please unimport Mouse (C<no Mouse::Role>) so that if someone calls one of the
 136 keywords (such as L</has>) it will break loudly instead breaking subtly.
 137
 138 =cut
 139