lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2
   3 require Mouse::Util;
   4
   5 package Mouse::Util;
   6
   7 use strict;
   8 use warnings;
   9
  10 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
  11
  12 use B ();
  13
  14
  15 # taken from Class/MOP.pm
  16 sub is_valid_class_name {
  17     my $class = shift;
  18
  19     return 0 if ref($class);
  20     return 0 unless defined($class);
  21
  22     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
  23
  24     return 0;
  25 }
  26
  27 sub is_class_loaded {
  28     my $class = shift;
  29
  30     return 0 if ref($class) || !defined($class) || !length($class);
  31
  32     # walk the symbol table tree to avoid autovififying
  33     # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::
  34
  35     my $pack = \%::;
  36     foreach my $part (split('::', $class)) {
  37         $part .= '::';
  38         return 0 if !exists $pack->{$part};
  39
  40         my $entry = \$pack->{$part};
  41         return 0 if ref($entry) ne 'GLOB';
  42         $pack = *{$entry}{HASH};
  43     }
  44
  45     return 0 if !%{$pack};
  46
  47     # check for $VERSION or @ISA
  48     return 1 if exists $pack->{VERSION}
  49              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  50     return 1 if exists $pack->{ISA}
  51              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  52
  53     # check for any method
  54     foreach my $name( keys %{$pack} ) {
  55         my $entry = \$pack->{$name};
  56         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  57     }
  58
  59     # fail
  60     return 0;
  61 }
  62
  63
  64 # taken from Sub::Identify
  65 sub get_code_info {
  66     my ($coderef) = @_;
  67     ref($coderef) or return;
  68
  69     my $cv = B::svref_2object($coderef);
  70     $cv->isa('B::CV') or return;
  71
  72     my $gv = $cv->GV;
  73     $gv->isa('B::GV') or return;
  74
  75     return ($gv->STASH->NAME, $gv->NAME);
  76 }
  77
  78 sub get_code_package{
  79     my($coderef) = @_;
  80
  81     my $cv = B::svref_2object($coderef);
  82     $cv->isa('B::CV') or return '';
  83
  84     my $gv = $cv->GV;
  85     $gv->isa('B::GV') or return '';
  86
  87     return $gv->STASH->NAME;
  88 }
  89
  90 sub get_code_ref{
  91     my($package, $name) = @_;
  92     no strict 'refs';
  93     no warnings 'once';
  94     use warnings FATAL => 'uninitialized';
  95     return *{$package . '::' . $name}{CODE};
  96 }
  97
  98 sub generate_isa_predicate_for {
  99     my($for_class, $name) = @_;
 100
 101     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
 102
 103     if(defined $name){
 104         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 105         return;
 106     }
 107
 108     return $predicate;
 109 }
 110
 111 sub generate_can_predicate_for {
 112     my($methods_ref, $name) = @_;
 113
 114     my @methods = @{$methods_ref};
 115
 116     my $predicate = sub{
 117         my($instance) = @_;
 118         if(Scalar::Util::blessed($instance)){
 119             foreach my $method(@methods){
 120                 if(!$instance->can($method)){
 121                     return 0;
 122                 }
 123             }
 124             return 1;
 125         }
 126         return 0;
 127     };
 128
 129     if(defined $name){
 130         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 131         return;
 132     }
 133
 134     return $predicate;
 135 }
 136
 137 package Mouse::Util::TypeConstraints;
 138
 139 use Scalar::Util qw(blessed looks_like_number openhandle);
 140
 141 sub Any        { 1 }
 142 sub Item       { 1 }
 143
 144 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 145 sub Undef      { !defined($_[0]) }
 146 sub Defined    {  defined($_[0])  }
 147 sub Value      {  defined($_[0]) && !ref($_[0]) }
 148 sub Num        {  looks_like_number($_[0]) }
 149 sub Int        {
 150     my($value) = @_;
 151     looks_like_number($value) && $value =~ /\A [+-]? [0-9]+  \z/xms;
 152 }
 153 sub Str        {
 154     my($value) = @_;
 155     return defined($value) && ref(\$value) eq 'SCALAR';
 156 }
 157
 158 sub Ref        { ref($_[0]) }
 159 sub ScalarRef  {
 160     my($value) = @_;
 161     return ref($value) eq 'SCALAR'
 162 }
 163 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 164 sub HashRef    { ref($_[0]) eq 'HASH'   }
 165 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 166 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 167 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 168
 169 sub FileHandle {
 170     return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 171 }
 172
 173 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 174
 175 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 176 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 177
 178 sub _parameterize_ArrayRef_for {
 179     my($type_parameter) = @_;
 180     my $check = $type_parameter->_compiled_type_constraint;
 181
 182     return sub {
 183         foreach my $value (@{$_}) {
 184             return undef unless $check->($value);
 185         }
 186         return 1;
 187     }
 188 }
 189
 190 sub _parameterize_HashRef_for {
 191     my($type_parameter) = @_;
 192     my $check = $type_parameter->_compiled_type_constraint;
 193
 194     return sub {
 195         foreach my $value(values %{$_}){
 196             return undef unless $check->($value);
 197         }
 198         return 1;
 199     };
 200 }
 201
 202 # 'Maybe' type accepts 'Any', so it requires parameters
 203 sub _parameterize_Maybe_for {
 204     my($type_parameter) = @_;
 205     my $check = $type_parameter->_compiled_type_constraint;
 206
 207     return sub{
 208         return !defined($_) || $check->($_);
 209     };
 210 }
 211
 212 package Mouse::Meta::Module;
 213
 214 sub name          { $_[0]->{package} }
 215
 216 sub _method_map   { $_[0]->{methods} }
 217 sub _attribute_map{ $_[0]->{attributes} }
 218
 219 sub namespace{
 220     my $name = $_[0]->{package};
 221     no strict 'refs';
 222     return \%{ $name . '::' };
 223 }
 224
 225 sub add_method {
 226     my($self, $name, $code) = @_;
 227
 228     if(!defined $name){
 229         $self->throw_error('You must pass a defined name');
 230     }
 231     if(!defined $code){
 232         $self->throw_error('You must pass a defined code');
 233     }
 234
 235     if(ref($code) ne 'CODE'){
 236         $code = \&{$code}; # coerce
 237     }
 238
 239     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 240
 241     Mouse::Util::install_subroutines($self->name,
 242         $name => $code,
 243     );
 244     return;
 245 }
 246
 247 package Mouse::Meta::Class;
 248
 249 use Mouse::Meta::Method::Constructor;
 250 use Mouse::Meta::Method::Destructor;
 251
 252 sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
 253 sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }
 254
 255 sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
 256 sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }
 257
 258 sub is_anon_class{
 259     return exists $_[0]->{anon_serial_id};
 260 }
 261
 262 sub roles { $_[0]->{roles} }
 263
 264 sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
 265
 266 sub get_all_attributes {
 267     my($self) = @_;
 268     my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
 269     return values %attrs;
 270 }
 271
 272 sub new_object {
 273     my $self = shift;
 274     my %args = (@_ == 1 ? %{$_[0]} : @_);
 275
 276     my $object = bless {}, $self->name;
 277
 278     $self->_initialize_object($object, \%args);
 279     return $object;
 280 }
 281
 282 sub _initialize_object{
 283     my($self, $object, $args, $is_cloning) = @_;
 284
 285     my @triggers_queue;
 286
 287     foreach my $attribute ($self->get_all_attributes) {
 288         my $init_arg = $attribute->init_arg;
 289         my $slot     = $attribute->name;
 290
 291         if (defined($init_arg) && exists($args->{$init_arg})) {
 292             $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
 293
 294             weaken($object->{$slot})
 295                 if ref($object->{$slot}) && $attribute->is_weak_ref;
 296
 297             if ($attribute->has_trigger) {
 298                 push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
 299             }
 300         }
 301         elsif(!$is_cloning) { # no init arg, noop while cloning
 302             if ($attribute->has_default || $attribute->has_builder) {
 303                 if (!$attribute->is_lazy) {
 304                     my $default = $attribute->default;
 305                     my $builder = $attribute->builder;
 306                     my $value =   $builder                ? $object->$builder()
 307                                 : ref($default) eq 'CODE' ? $object->$default()
 308                                 :                           $default;
 309
 310                     $object->{$slot} = $attribute->_coerce_and_verify($value, $object);
 311
 312                     weaken($object->{$slot})
 313                         if ref($object->{$slot}) && $attribute->is_weak_ref;
 314                 }
 315             }
 316             elsif($attribute->is_required) {
 317                 $self->throw_error("Attribute (".$attribute->name.") is required");
 318             }
 319         }
 320     }
 321
 322     if(@triggers_queue){
 323         foreach my $trigger_and_value(@triggers_queue){
 324             my($trigger, $value) = @{$trigger_and_value};
 325             $trigger->($object, $value);
 326         }
 327     }
 328
 329     if($self->is_anon_class){
 330         $object->{__METACLASS__} = $self;
 331     }
 332
 333     return;
 334 }
 335
 336 sub is_immutable {  $_[0]->{is_immutable} }
 337
 338 sub __strict_constructor{ $_[0]->{strict_constructor} }
 339
 340 package Mouse::Meta::Role;
 341
 342 sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }
 343
 344 sub is_anon_role{
 345     return exists $_[0]->{anon_serial_id};
 346 }
 347
 348 sub get_roles { $_[0]->{roles} }
 349
 350 sub add_before_method_modifier {
 351     my ($self, $method_name, $method) = @_;
 352
 353     push @{ $self->{before_method_modifiers}{$method_name} ||= [] }, $method;
 354     return;
 355 }
 356 sub add_around_method_modifier {
 357     my ($self, $method_name, $method) = @_;
 358
 359     push @{ $self->{around_method_modifiers}{$method_name} ||= [] }, $method;
 360     return;
 361 }
 362 sub add_after_method_modifier {
 363     my ($self, $method_name, $method) = @_;
 364
 365     push @{ $self->{after_method_modifiers}{$method_name} ||= [] }, $method;
 366     return;
 367 }
 368
 369 sub get_before_method_modifiers {
 370     my ($self, $method_name) = @_;
 371     return @{ $self->{before_method_modifiers}{$method_name} ||= [] }
 372 }
 373 sub get_around_method_modifiers {
 374     my ($self, $method_name) = @_;
 375     return @{ $self->{around_method_modifiers}{$method_name} ||= [] }
 376 }
 377 sub get_after_method_modifiers {
 378     my ($self, $method_name) = @_;
 379     return @{ $self->{after_method_modifiers}{$method_name} ||= [] }
 380 }
 381
 382 package Mouse::Meta::Attribute;
 383
 384 require Mouse::Meta::Method::Accessor;
 385
 386 sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }
 387
 388 # readers
 389
 390 sub name                 { $_[0]->{name}                   }
 391 sub associated_class     { $_[0]->{associated_class}       }
 392
 393 sub accessor             { $_[0]->{accessor}               }
 394 sub reader               { $_[0]->{reader}                 }
 395 sub writer               { $_[0]->{writer}                 }
 396 sub predicate            { $_[0]->{predicate}              }
 397 sub clearer              { $_[0]->{clearer}                }
 398 sub handles              { $_[0]->{handles}                }
 399
 400 sub _is_metadata         { $_[0]->{is}                     }
 401 sub is_required          { $_[0]->{required}               }
 402 sub default              { $_[0]->{default}                }
 403 sub is_lazy              { $_[0]->{lazy}                   }
 404 sub is_lazy_build        { $_[0]->{lazy_build}             }
 405 sub is_weak_ref          { $_[0]->{weak_ref}               }
 406 sub init_arg             { $_[0]->{init_arg}               }
 407 sub type_constraint      { $_[0]->{type_constraint}        }
 408
 409 sub trigger              { $_[0]->{trigger}                }
 410 sub builder              { $_[0]->{builder}                }
 411 sub should_auto_deref    { $_[0]->{auto_deref}             }
 412 sub should_coerce        { $_[0]->{coerce}                 }
 413
 414 sub documentation        { $_[0]->{documentation}          }
 415
 416 # predicates
 417
 418 sub has_accessor         { exists $_[0]->{accessor}        }
 419 sub has_reader           { exists $_[0]->{reader}          }
 420 sub has_writer           { exists $_[0]->{writer}          }
 421 sub has_predicate        { exists $_[0]->{predicate}       }
 422 sub has_clearer          { exists $_[0]->{clearer}         }
 423 sub has_handles          { exists $_[0]->{handles}         }
 424
 425 sub has_default          { exists $_[0]->{default}         }
 426 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 427 sub has_trigger          { exists $_[0]->{trigger}         }
 428 sub has_builder          { exists $_[0]->{builder}         }
 429
 430 sub has_documentation    { exists $_[0]->{documentation}   }
 431
 432 sub _process_options{
 433     my($class, $name, $args) = @_;
 434
 435     # taken from Class::MOP::Attribute::new
 436
 437     defined($name)
 438         or $class->throw_error('You must provide a name for the attribute');
 439
 440     if(!exists $args->{init_arg}){
 441         $args->{init_arg} = $name;
 442     }
 443
 444     # 'required' requires eigher 'init_arg', 'builder', or 'default'
 445     my $can_be_required = defined( $args->{init_arg} );
 446
 447     if(exists $args->{builder}){
 448         # XXX:
 449         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
 450         # This feature will be changed in a future. (gfx)
 451         $class->throw_error('builder must be a defined scalar value which is a method name')
 452             #if ref $args->{builder} || !defined $args->{builder};
 453             if !defined $args->{builder};
 454
 455         $can_be_required++;
 456     }
 457     elsif(exists $args->{default}){
 458         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
 459             $class->throw_error("References are not allowed as default values, you must "
 460                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
 461         }
 462         $can_be_required++;
 463     }
 464
 465     if( $args->{required} && !$can_be_required ) {
 466         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
 467     }
 468
 469     # taken from Mouse::Meta::Attribute->new and ->_process_args
 470
 471     if(exists $args->{is}){
 472         my $is = $args->{is};
 473
 474         if($is eq 'ro'){
 475             $args->{reader} ||= $name;
 476         }
 477         elsif($is eq 'rw'){
 478             if(exists $args->{writer}){
 479                 $args->{reader} ||= $name;
 480              }
 481              else{
 482                 $args->{accessor} ||= $name;
 483              }
 484         }
 485         elsif($is eq 'bare'){
 486             # do nothing, but don't complain (later) about missing methods
 487         }
 488         else{
 489             $is = 'undef' if !defined $is;
 490             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
 491         }
 492     }
 493
 494     my $tc;
 495     if(exists $args->{isa}){
 496         $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
 497     }
 498
 499     if(exists $args->{does}){
 500         if(defined $tc){ # both isa and does supplied
 501             my $does_ok = do{
 502                 local $@;
 503                 eval{ "$tc"->does($args) };
 504             };
 505             if(!$does_ok){
 506                 $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
 507             }
 508         }
 509         else {
 510             $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
 511         }
 512     }
 513
 514     if($args->{coerce}){
 515         defined($tc)
 516             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
 517
 518         $args->{weak_ref}
 519             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
 520     }
 521
 522     if ($args->{lazy_build}) {
 523         exists($args->{default})
 524             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 525
 526         $args->{lazy}      = 1;
 527         $args->{builder} ||= "_build_${name}";
 528         if ($name =~ /^_/) {
 529             $args->{clearer}   ||= "_clear${name}";
 530             $args->{predicate} ||= "_has${name}";
 531         }
 532         else {
 533             $args->{clearer}   ||= "clear_${name}";
 534             $args->{predicate} ||= "has_${name}";
 535         }
 536     }
 537
 538     if ($args->{auto_deref}) {
 539         defined($tc)
 540             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 541
 542         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 543             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 544     }
 545
 546     if (exists $args->{trigger}) {
 547         ('CODE' eq ref $args->{trigger})
 548             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 549     }
 550
 551     if ($args->{lazy}) {
 552         (exists $args->{default} || defined $args->{builder})
 553             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 554     }
 555
 556     return;
 557 }
 558
 559
 560 package Mouse::Meta::TypeConstraint;
 561
 562 sub name    { $_[0]->{name}    }
 563 sub parent  { $_[0]->{parent}  }
 564 sub message { $_[0]->{message} }
 565
 566 sub type_parameter           { $_[0]->{type_parameter} }
 567 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 568 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 569
 570 sub __is_parameterized { exists $_[0]->{type_parameter} }
 571 sub has_coercion {       exists $_[0]->{_compiled_type_coercion} }
 572
 573
 574 sub compile_type_constraint{
 575     my($self) = @_;
 576
 577     # add parents first
 578     my @checks;
 579     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 580          if($parent->{hand_optimized_type_constraint}){
 581             unshift @checks, $parent->{hand_optimized_type_constraint};
 582             last; # a hand optimized constraint must include all the parents
 583         }
 584         elsif($parent->{constraint}){
 585             unshift @checks, $parent->{constraint};
 586         }
 587     }
 588
 589     # then add child
 590     if($self->{constraint}){
 591         push @checks, $self->{constraint};
 592     }
 593
 594     if($self->{type_constraints}){ # Union
 595         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 596         push @checks, sub{
 597             foreach my $c(@types){
 598                 return 1 if $c->($_[0]);
 599             }
 600             return 0;
 601         };
 602     }
 603
 604     if(@checks == 0){
 605         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 606     }
 607     else{
 608         $self->{compiled_type_constraint} =  sub{
 609             my(@args) = @_;
 610             local $_ = $args[0];
 611             foreach my $c(@checks){
 612                 return undef if !$c->(@args);
 613             }
 614             return 1;
 615         };
 616     }
 617     return;
 618 }
 619
 620 sub check {
 621     my $self = shift;
 622     return $self->_compiled_type_constraint->(@_);
 623 }
 624
 625
 626 package Mouse::Object;
 627
 628 sub BUILDARGS {
 629     my $class = shift;
 630
 631     if (scalar @_ == 1) {
 632         (ref($_[0]) eq 'HASH')
 633             || $class->meta->throw_error("Single parameters to new() must be a HASH ref");
 634
 635         return {%{$_[0]}};
 636     }
 637     else {
 638         return {@_};
 639     }
 640 }
 641
 642 sub new {
 643     my $class = shift;
 644
 645     $class->meta->throw_error('Cannot call new() on an instance') if ref $class;
 646
 647     my $args = $class->BUILDARGS(@_);
 648
 649     my $meta = Mouse::Meta::Class->initialize($class);
 650     my $self = $meta->new_object($args);
 651
 652     # BUILDALL
 653     if( $self->can('BUILD') ) {
 654         for my $class (reverse $meta->linearized_isa) {
 655             my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 656                 || next;
 657
 658             $self->$build($args);
 659         }
 660     }
 661
 662     return $self;
 663 }
 664
 665 sub DESTROY {
 666     my $self = shift;
 667
 668     return unless $self->can('DEMOLISH'); # short circuit
 669
 670     local $?;
 671
 672     my $e = do{
 673         local $@;
 674         eval{
 675             # DEMOLISHALL
 676
 677             # We cannot count on being able to retrieve a previously made
 678             # metaclass, _or_ being able to make a new one during global
 679             # destruction. However, we should still be able to use mro at
 680             # that time (at least tests suggest so ;)
 681
 682             foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
 683                 my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
 684                     || next;
 685
 686                 $self->$demolish($Mouse::Util::in_global_destruction);
 687             }
 688         };
 689         $@;
 690     };
 691
 692     no warnings 'misc';
 693     die $e if $e; # rethrow
 694 }
 695
 696 sub BUILDALL {
 697     my $self = shift;
 698
 699     # short circuit
 700     return unless $self->can('BUILD');
 701
 702     for my $class (reverse $self->meta->linearized_isa) {
 703         my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 704             || next;
 705
 706         $self->$build(@_);
 707     }
 708     return;
 709 }
 710
 711 sub DEMOLISHALL;
 712 *DEMOLISHALL = \&DESTROY;
 713
 714 1;
 715 __END__
 716
 717 =head1 NAME
 718
 719 Mouse::PurePerl - A Mouse guts in pure Perl
 720
 721 =head1 VERSION
 722
 723 This document describes Mouse version 0.52
 724
 725 =head1 SEE ALSO
 726
 727 L<Mouse::XS>
 728
 729 =cut