lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2 # The pure Perl backend for Mouse
   3 package Mouse::Util;
   4 use strict;
   5 use warnings;
   6 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl twice
   7
   8 use B ();
   9
  10 require Mouse::Util;
  11
  12
  13 # taken from Class/MOP.pm
  14 sub is_valid_class_name {
  15     my $class = shift;
  16
  17     return 0 if ref($class);
  18     return 0 unless defined($class);
  19
  20     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
  21
  22     return 0;
  23 }
  24
  25 sub is_class_loaded {
  26     my $class = shift;
  27
  28     return 0 if ref($class) || !defined($class) || !length($class);
  29
  30     # walk the symbol table tree to avoid autovififying
  31     # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::
  32
  33     my $pack = \%::;
  34     foreach my $part (split('::', $class)) {
  35         $part .= '::';
  36         return 0 if !exists $pack->{$part};
  37
  38         my $entry = \$pack->{$part};
  39         return 0 if ref($entry) ne 'GLOB';
  40         $pack = *{$entry}{HASH};
  41     }
  42
  43     return 0 if !%{$pack};
  44
  45     # check for $VERSION or @ISA
  46     return 1 if exists $pack->{VERSION}
  47              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  48     return 1 if exists $pack->{ISA}
  49              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  50
  51     # check for any method
  52     foreach my $name( keys %{$pack} ) {
  53         my $entry = \$pack->{$name};
  54         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  55     }
  56
  57     # fail
  58     return 0;
  59 }
  60
  61
  62 # taken from Sub::Identify
  63 sub get_code_info {
  64     my ($coderef) = @_;
  65     ref($coderef) or return;
  66
  67     my $cv = B::svref_2object($coderef);
  68     $cv->isa('B::CV') or return;
  69
  70     my $gv = $cv->GV;
  71     $gv->isa('B::GV') or return;
  72
  73     return ($gv->STASH->NAME, $gv->NAME);
  74 }
  75
  76 sub get_code_package{
  77     my($coderef) = @_;
  78
  79     my $cv = B::svref_2object($coderef);
  80     $cv->isa('B::CV') or return '';
  81
  82     my $gv = $cv->GV;
  83     $gv->isa('B::GV') or return '';
  84
  85     return $gv->STASH->NAME;
  86 }
  87
  88 sub get_code_ref{
  89     my($package, $name) = @_;
  90     no strict 'refs';
  91     no warnings 'once';
  92     use warnings FATAL => 'uninitialized';
  93     return *{$package . '::' . $name}{CODE};
  94 }
  95
  96 sub generate_isa_predicate_for {
  97     my($for_class, $name) = @_;
  98
  99     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
 100
 101     if(defined $name){
 102         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 103         return;
 104     }
 105
 106     return $predicate;
 107 }
 108
 109 sub generate_can_predicate_for {
 110     my($methods_ref, $name) = @_;
 111
 112     my @methods = @{$methods_ref};
 113
 114     my $predicate = sub{
 115         my($instance) = @_;
 116         if(Scalar::Util::blessed($instance)){
 117             foreach my $method(@methods){
 118                 if(!$instance->can($method)){
 119                     return 0;
 120                 }
 121             }
 122             return 1;
 123         }
 124         return 0;
 125     };
 126
 127     if(defined $name){
 128         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 129         return;
 130     }
 131
 132     return $predicate;
 133 }
 134
 135 package Mouse::Util::TypeConstraints;
 136
 137 use Scalar::Util qw(blessed looks_like_number openhandle);
 138
 139 sub Any        { 1 }
 140 sub Item       { 1 }
 141
 142 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 143 sub Undef      { !defined($_[0]) }
 144 sub Defined    {  defined($_[0])  }
 145 sub Value      {  defined($_[0]) && !ref($_[0]) }
 146 sub Num        {  looks_like_number($_[0]) }
 147 sub Int        {
 148     my($value) = @_;
 149     looks_like_number($value) && $value =~ /\A [+-]? [0-9]+  \z/xms;
 150 }
 151 sub Str        {
 152     my($value) = @_;
 153     return defined($value) && ref(\$value) eq 'SCALAR';
 154 }
 155
 156 sub Ref        { ref($_[0]) }
 157 sub ScalarRef  {
 158     my($value) = @_;
 159     return ref($value) eq 'SCALAR'
 160 }
 161 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 162 sub HashRef    { ref($_[0]) eq 'HASH'   }
 163 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 164 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 165 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 166
 167 sub FileHandle {
 168     return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 169 }
 170
 171 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 172
 173 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 174 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 175
 176 sub _parameterize_ArrayRef_for {
 177     my($type_parameter) = @_;
 178     my $check = $type_parameter->_compiled_type_constraint;
 179
 180     return sub {
 181         foreach my $value (@{$_}) {
 182             return undef unless $check->($value);
 183         }
 184         return 1;
 185     }
 186 }
 187
 188 sub _parameterize_HashRef_for {
 189     my($type_parameter) = @_;
 190     my $check = $type_parameter->_compiled_type_constraint;
 191
 192     return sub {
 193         foreach my $value(values %{$_}){
 194             return undef unless $check->($value);
 195         }
 196         return 1;
 197     };
 198 }
 199
 200 # 'Maybe' type accepts 'Any', so it requires parameters
 201 sub _parameterize_Maybe_for {
 202     my($type_parameter) = @_;
 203     my $check = $type_parameter->_compiled_type_constraint;
 204
 205     return sub{
 206         return !defined($_) || $check->($_);
 207     };
 208 }
 209
 210 package Mouse::Meta::Module;
 211
 212 sub name          { $_[0]->{package} }
 213
 214 sub _method_map   { $_[0]->{methods} }
 215 sub _attribute_map{ $_[0]->{attributes} }
 216
 217 sub namespace{
 218     my $name = $_[0]->{package};
 219     no strict 'refs';
 220     return \%{ $name . '::' };
 221 }
 222
 223 sub add_method {
 224     my($self, $name, $code) = @_;
 225
 226     if(!defined $name){
 227         $self->throw_error('You must pass a defined name');
 228     }
 229     if(!defined $code){
 230         $self->throw_error('You must pass a defined code');
 231     }
 232
 233     if(ref($code) ne 'CODE'){
 234         $code = \&{$code}; # coerce
 235     }
 236
 237     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 238
 239     Mouse::Util::install_subroutines($self->name,
 240         $name => $code,
 241     );
 242     return;
 243 }
 244
 245 my $generate_class_accessor = sub {
 246     my($name) = @_;
 247     return sub {
 248         my $self = shift;
 249         if(@_) {
 250             return $self->{$name} = shift;
 251         }
 252
 253         foreach my $class($self->linearized_isa) {
 254             my $meta = Mouse::Util::get_metaclass_by_name($class)
 255                 or next;
 256
 257             if(exists $meta->{$name}) {
 258                 return $meta->{$name};
 259             }
 260         }
 261         return undef;
 262     };
 263 };
 264
 265
 266 package Mouse::Meta::Class;
 267
 268 use Mouse::Meta::Method::Constructor;
 269 use Mouse::Meta::Method::Destructor;
 270
 271 sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
 272 sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }
 273
 274 sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
 275 sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }
 276
 277 sub is_anon_class{
 278     return exists $_[0]->{anon_serial_id};
 279 }
 280
 281 sub roles { $_[0]->{roles} }
 282
 283 sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
 284
 285 sub get_all_attributes {
 286     my($self) = @_;
 287     my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
 288     return values %attrs;
 289 }
 290
 291 sub new_object {
 292     my $meta = shift;
 293     my %args = (@_ == 1 ? %{$_[0]} : @_);
 294
 295     my $object = bless {}, $meta->name;
 296
 297     $meta->_initialize_object($object, \%args);
 298     # BUILDALL
 299     if( $object->can('BUILD') ) {
 300         for my $class (reverse $meta->linearized_isa) {
 301             my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 302                 || next;
 303
 304             $object->$build(\%args);
 305         }
 306     }
 307     return $object;
 308 }
 309
 310 sub clone_object {
 311     my $class  = shift;
 312     my $object = shift;
 313     my $args   = $object->Mouse::Object::BUILDARGS(@_);
 314
 315     (blessed($object) && $object->isa($class->name))
 316         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 317
 318     my $cloned = bless { %$object }, ref $object;
 319     $class->_initialize_object($cloned, $args, 1);
 320
 321     return $cloned;
 322 }
 323
 324 sub _initialize_object{
 325     my($self, $object, $args, $is_cloning) = @_;
 326
 327     my @triggers_queue;
 328
 329     my $used = 0;
 330
 331     foreach my $attribute ($self->get_all_attributes) {
 332         my $init_arg = $attribute->init_arg;
 333         my $slot     = $attribute->name;
 334
 335         if (defined($init_arg) && exists($args->{$init_arg})) {
 336             $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
 337
 338             weaken($object->{$slot})
 339                 if ref($object->{$slot}) && $attribute->is_weak_ref;
 340
 341             if ($attribute->has_trigger) {
 342                 push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
 343             }
 344             $used++;
 345         }
 346         else { # no init arg
 347             if ($attribute->has_default || $attribute->has_builder) {
 348                 if (!$attribute->is_lazy && !exists $object->{$slot}) {
 349                     my $default = $attribute->default;
 350                     my $builder = $attribute->builder;
 351                     my $value =   $builder                ? $object->$builder()
 352                                 : ref($default) eq 'CODE' ? $object->$default()
 353                                 :                           $default;
 354
 355                     $object->{$slot} = $attribute->_coerce_and_verify($value, $object);
 356
 357                     weaken($object->{$slot})
 358                         if ref($object->{$slot}) && $attribute->is_weak_ref;
 359                 }
 360             }
 361             elsif(!$is_cloning && $attribute->is_required) {
 362                 $self->throw_error("Attribute (".$attribute->name.") is required");
 363             }
 364         }
 365     }
 366
 367     if($used < keys %{$args} && $self->strict_constructor) {
 368         $self->_report_unknown_args([ $self->get_all_attributes ], $args);
 369     }
 370
 371     if(@triggers_queue){
 372         foreach my $trigger_and_value(@triggers_queue){
 373             my($trigger, $value) = @{$trigger_and_value};
 374             $trigger->($object, $value);
 375         }
 376     }
 377
 378     if($self->is_anon_class){
 379         $object->{__METACLASS__} = $self;
 380     }
 381
 382     return;
 383 }
 384
 385 sub is_immutable {  $_[0]->{is_immutable} }
 386
 387 Mouse::Util::install_subroutines(__PACKAGE__,
 388     strict_constructor => $generate_class_accessor->('strict_constructor'),
 389 );
 390
 391 sub _report_unknown_args {
 392     my($metaclass, $attrs, $args) = @_;
 393
 394     my @unknowns;
 395     my %init_args;
 396     foreach my $attr(@{$attrs}){
 397         my $init_arg = $attr->init_arg;
 398         if(defined $init_arg){
 399             $init_args{$init_arg}++;
 400         }
 401     }
 402
 403     while(my $key = each %{$args}){
 404         if(!exists $init_args{$key}){
 405             push @unknowns, $key;
 406         }
 407     }
 408
 409     $metaclass->throw_error( sprintf
 410         "Unknown attribute passed to the constructor of %s: %s",
 411         $metaclass->name, Mouse::Util::english_list(@unknowns),
 412     );
 413 }
 414
 415 package Mouse::Meta::Role;
 416
 417 sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }
 418
 419 sub is_anon_role{
 420     return exists $_[0]->{anon_serial_id};
 421 }
 422
 423 sub get_roles { $_[0]->{roles} }
 424
 425 sub add_before_method_modifier {
 426     my ($self, $method_name, $method) = @_;
 427
 428     push @{ $self->{before_method_modifiers}{$method_name} ||= [] }, $method;
 429     return;
 430 }
 431 sub add_around_method_modifier {
 432     my ($self, $method_name, $method) = @_;
 433
 434     push @{ $self->{around_method_modifiers}{$method_name} ||= [] }, $method;
 435     return;
 436 }
 437 sub add_after_method_modifier {
 438     my ($self, $method_name, $method) = @_;
 439
 440     push @{ $self->{after_method_modifiers}{$method_name} ||= [] }, $method;
 441     return;
 442 }
 443
 444 sub get_before_method_modifiers {
 445     my ($self, $method_name) = @_;
 446     return @{ $self->{before_method_modifiers}{$method_name} ||= [] }
 447 }
 448 sub get_around_method_modifiers {
 449     my ($self, $method_name) = @_;
 450     return @{ $self->{around_method_modifiers}{$method_name} ||= [] }
 451 }
 452 sub get_after_method_modifiers {
 453     my ($self, $method_name) = @_;
 454     return @{ $self->{after_method_modifiers}{$method_name} ||= [] }
 455 }
 456
 457 sub add_metaclass_accessor { # for meta roles (a.k.a. traits)
 458     my($meta, $name) = @_;
 459     $meta->add_method($name => $generate_class_accessor->($name));
 460     return;
 461 }
 462
 463 package Mouse::Meta::Attribute;
 464
 465 require Mouse::Meta::Method::Accessor;
 466
 467 sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }
 468
 469 # readers
 470
 471 sub name                 { $_[0]->{name}                   }
 472 sub associated_class     { $_[0]->{associated_class}       }
 473
 474 sub accessor             { $_[0]->{accessor}               }
 475 sub reader               { $_[0]->{reader}                 }
 476 sub writer               { $_[0]->{writer}                 }
 477 sub predicate            { $_[0]->{predicate}              }
 478 sub clearer              { $_[0]->{clearer}                }
 479 sub handles              { $_[0]->{handles}                }
 480
 481 sub _is_metadata         { $_[0]->{is}                     }
 482 sub is_required          { $_[0]->{required}               }
 483 sub default              { $_[0]->{default}                }
 484 sub is_lazy              { $_[0]->{lazy}                   }
 485 sub is_lazy_build        { $_[0]->{lazy_build}             }
 486 sub is_weak_ref          { $_[0]->{weak_ref}               }
 487 sub init_arg             { $_[0]->{init_arg}               }
 488 sub type_constraint      { $_[0]->{type_constraint}        }
 489
 490 sub trigger              { $_[0]->{trigger}                }
 491 sub builder              { $_[0]->{builder}                }
 492 sub should_auto_deref    { $_[0]->{auto_deref}             }
 493 sub should_coerce        { $_[0]->{coerce}                 }
 494
 495 sub documentation        { $_[0]->{documentation}          }
 496 sub insertion_order      { $_[0]->{insertion_order}        }
 497
 498 # predicates
 499
 500 sub has_accessor         { exists $_[0]->{accessor}        }
 501 sub has_reader           { exists $_[0]->{reader}          }
 502 sub has_writer           { exists $_[0]->{writer}          }
 503 sub has_predicate        { exists $_[0]->{predicate}       }
 504 sub has_clearer          { exists $_[0]->{clearer}         }
 505 sub has_handles          { exists $_[0]->{handles}         }
 506
 507 sub has_default          { exists $_[0]->{default}         }
 508 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 509 sub has_trigger          { exists $_[0]->{trigger}         }
 510 sub has_builder          { exists $_[0]->{builder}         }
 511
 512 sub has_documentation    { exists $_[0]->{documentation}   }
 513
 514 sub _process_options{
 515     my($class, $name, $args) = @_;
 516
 517     # taken from Class::MOP::Attribute::new
 518
 519     defined($name)
 520         or $class->throw_error('You must provide a name for the attribute');
 521
 522     if(!exists $args->{init_arg}){
 523         $args->{init_arg} = $name;
 524     }
 525
 526     # 'required' requires eigher 'init_arg', 'builder', or 'default'
 527     my $can_be_required = defined( $args->{init_arg} );
 528
 529     if(exists $args->{builder}){
 530         # XXX:
 531         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
 532         # This feature will be changed in a future. (gfx)
 533         $class->throw_error('builder must be a defined scalar value which is a method name')
 534             #if ref $args->{builder} || !defined $args->{builder};
 535             if !defined $args->{builder};
 536
 537         $can_be_required++;
 538     }
 539     elsif(exists $args->{default}){
 540         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
 541             $class->throw_error("References are not allowed as default values, you must "
 542                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
 543         }
 544         $can_be_required++;
 545     }
 546
 547     if( $args->{required} && !$can_be_required ) {
 548         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
 549     }
 550
 551     # taken from Mouse::Meta::Attribute->new and ->_process_args
 552
 553     if(exists $args->{is}){
 554         my $is = $args->{is};
 555
 556         if($is eq 'ro'){
 557             $args->{reader} ||= $name;
 558         }
 559         elsif($is eq 'rw'){
 560             if(exists $args->{writer}){
 561                 $args->{reader} ||= $name;
 562              }
 563              else{
 564                 $args->{accessor} ||= $name;
 565              }
 566         }
 567         elsif($is eq 'bare'){
 568             # do nothing, but don't complain (later) about missing methods
 569         }
 570         else{
 571             $is = 'undef' if !defined $is;
 572             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
 573         }
 574     }
 575
 576     my $tc;
 577     if(exists $args->{isa}){
 578         $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
 579     }
 580
 581     if(exists $args->{does}){
 582         if(defined $tc){ # both isa and does supplied
 583             my $does_ok = do{
 584                 local $@;
 585                 eval{ "$tc"->does($args) };
 586             };
 587             if(!$does_ok){
 588                 $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
 589             }
 590         }
 591         else {
 592             $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
 593         }
 594     }
 595
 596     if($args->{coerce}){
 597         defined($tc)
 598             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
 599
 600         $args->{weak_ref}
 601             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
 602     }
 603
 604     if ($args->{lazy_build}) {
 605         exists($args->{default})
 606             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 607
 608         $args->{lazy}      = 1;
 609         $args->{builder} ||= "_build_${name}";
 610         if ($name =~ /^_/) {
 611             $args->{clearer}   ||= "_clear${name}";
 612             $args->{predicate} ||= "_has${name}";
 613         }
 614         else {
 615             $args->{clearer}   ||= "clear_${name}";
 616             $args->{predicate} ||= "has_${name}";
 617         }
 618     }
 619
 620     if ($args->{auto_deref}) {
 621         defined($tc)
 622             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 623
 624         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 625             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 626     }
 627
 628     if (exists $args->{trigger}) {
 629         ('CODE' eq ref $args->{trigger})
 630             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 631     }
 632
 633     if ($args->{lazy}) {
 634         (exists $args->{default} || defined $args->{builder})
 635             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 636     }
 637
 638     return;
 639 }
 640
 641
 642 package Mouse::Meta::TypeConstraint;
 643
 644 use overload
 645     '""' => '_as_string',
 646     '0+' => '_identity',
 647     '|'  => '_unite',
 648
 649     fallback => 1;
 650
 651 sub name    { $_[0]->{name}    }
 652 sub parent  { $_[0]->{parent}  }
 653 sub message { $_[0]->{message} }
 654
 655 sub type_parameter           { $_[0]->{type_parameter} }
 656 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 657 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 658
 659 sub __is_parameterized { exists $_[0]->{type_parameter} }
 660 sub has_coercion {       exists $_[0]->{_compiled_type_coercion} }
 661
 662
 663 sub compile_type_constraint{
 664     my($self) = @_;
 665
 666     # add parents first
 667     my @checks;
 668     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 669          if($parent->{hand_optimized_type_constraint}){
 670             unshift @checks, $parent->{hand_optimized_type_constraint};
 671             last; # a hand optimized constraint must include all the parents
 672         }
 673         elsif($parent->{constraint}){
 674             unshift @checks, $parent->{constraint};
 675         }
 676     }
 677
 678     # then add child
 679     if($self->{constraint}){
 680         push @checks, $self->{constraint};
 681     }
 682
 683     if($self->{type_constraints}){ # Union
 684         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 685         push @checks, sub{
 686             foreach my $c(@types){
 687                 return 1 if $c->($_[0]);
 688             }
 689             return 0;
 690         };
 691     }
 692
 693     if(@checks == 0){
 694         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 695     }
 696     else{
 697         $self->{compiled_type_constraint} =  sub{
 698             my(@args) = @_;
 699             local $_ = $args[0];
 700             foreach my $c(@checks){
 701                 return undef if !$c->(@args);
 702             }
 703             return 1;
 704         };
 705     }
 706     return;
 707 }
 708
 709 sub check {
 710     my $self = shift;
 711     return $self->_compiled_type_constraint->(@_);
 712 }
 713
 714
 715 package Mouse::Object;
 716
 717 sub BUILDARGS {
 718     my $class = shift;
 719
 720     if (scalar @_ == 1) {
 721         (ref($_[0]) eq 'HASH')
 722             || $class->meta->throw_error("Single parameters to new() must be a HASH ref");
 723
 724         return {%{$_[0]}};
 725     }
 726     else {
 727         return {@_};
 728     }
 729 }
 730
 731 sub new {
 732     my $class = shift;
 733
 734     $class->meta->throw_error('Cannot call new() on an instance') if ref $class;
 735
 736     my $args = $class->BUILDARGS(@_);
 737
 738     my $meta = Mouse::Meta::Class->initialize($class);
 739     return $meta->new_object($args);
 740 }
 741
 742 sub DESTROY {
 743     my $self = shift;
 744
 745     return unless $self->can('DEMOLISH'); # short circuit
 746
 747     local $?;
 748
 749     my $e = do{
 750         local $@;
 751         eval{
 752             # DEMOLISHALL
 753
 754             # We cannot count on being able to retrieve a previously made
 755             # metaclass, _or_ being able to make a new one during global
 756             # destruction. However, we should still be able to use mro at
 757             # that time (at least tests suggest so ;)
 758
 759             foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
 760                 my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
 761                     || next;
 762
 763                 $self->$demolish($Mouse::Util::in_global_destruction);
 764             }
 765         };
 766         $@;
 767     };
 768
 769     no warnings 'misc';
 770     die $e if $e; # rethrow
 771 }
 772
 773 sub BUILDALL {
 774     my $self = shift;
 775
 776     # short circuit
 777     return unless $self->can('BUILD');
 778
 779     for my $class (reverse $self->meta->linearized_isa) {
 780         my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 781             || next;
 782
 783         $self->$build(@_);
 784     }
 785     return;
 786 }
 787
 788 sub DEMOLISHALL;
 789 *DEMOLISHALL = \&DESTROY;
 790
 791 1;
 792 __END__
 793
 794 =head1 NAME
 795
 796 Mouse::PurePerl - A Mouse guts in pure Perl
 797
 798 =head1 VERSION
 799
 800 This document describes Mouse version 0.70
 801
 802 =head1 SEE ALSO
 803
 804 L<Mouse::XS>
 805
 806 =cut