lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2 # The pure Perl backend for Mouse
   3 package Mouse::Util;
   4 use strict;
   5 use warnings;
   6 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl twice
   7
   8 use B ();
   9
  10 require Mouse::Util;
  11
  12
  13 # taken from Class/MOP.pm
  14 sub is_valid_class_name {
  15     my $class = shift;
  16
  17     return 0 if ref($class);
  18     return 0 unless defined($class);
  19
  20     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
  21
  22     return 0;
  23 }
  24
  25 sub is_class_loaded {
  26     my $class = shift;
  27
  28     return 0 if ref($class) || !defined($class) || !length($class);
  29
  30     # walk the symbol table tree to avoid autovififying
  31     # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::
  32
  33     my $pack = \%::;
  34     foreach my $part (split('::', $class)) {
  35         $part .= '::';
  36         return 0 if !exists $pack->{$part};
  37
  38         my $entry = \$pack->{$part};
  39         return 0 if ref($entry) ne 'GLOB';
  40         $pack = *{$entry}{HASH};
  41     }
  42
  43     return 0 if !%{$pack};
  44
  45     # check for $VERSION or @ISA
  46     return 1 if exists $pack->{VERSION}
  47              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  48     return 1 if exists $pack->{ISA}
  49              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  50
  51     # check for any method
  52     foreach my $name( keys %{$pack} ) {
  53         my $entry = \$pack->{$name};
  54         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  55     }
  56
  57     # fail
  58     return 0;
  59 }
  60
  61
  62 # taken from Sub::Identify
  63 sub get_code_info {
  64     my ($coderef) = @_;
  65     ref($coderef) or return;
  66
  67     my $cv = B::svref_2object($coderef);
  68     $cv->isa('B::CV') or return;
  69
  70     my $gv = $cv->GV;
  71     $gv->isa('B::GV') or return;
  72
  73     return ($gv->STASH->NAME, $gv->NAME);
  74 }
  75
  76 sub get_code_package{
  77     my($coderef) = @_;
  78
  79     my $cv = B::svref_2object($coderef);
  80     $cv->isa('B::CV') or return '';
  81
  82     my $gv = $cv->GV;
  83     $gv->isa('B::GV') or return '';
  84
  85     return $gv->STASH->NAME;
  86 }
  87
  88 sub get_code_ref{
  89     my($package, $name) = @_;
  90     no strict 'refs';
  91     no warnings 'once';
  92     use warnings FATAL => 'uninitialized';
  93     return *{$package . '::' . $name}{CODE};
  94 }
  95
  96 sub generate_isa_predicate_for {
  97     my($for_class, $name) = @_;
  98
  99     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
 100
 101     if(defined $name){
 102         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 103         return;
 104     }
 105
 106     return $predicate;
 107 }
 108
 109 sub generate_can_predicate_for {
 110     my($methods_ref, $name) = @_;
 111
 112     my @methods = @{$methods_ref};
 113
 114     my $predicate = sub{
 115         my($instance) = @_;
 116         if(Scalar::Util::blessed($instance)){
 117             foreach my $method(@methods){
 118                 if(!$instance->can($method)){
 119                     return 0;
 120                 }
 121             }
 122             return 1;
 123         }
 124         return 0;
 125     };
 126
 127     if(defined $name){
 128         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 129         return;
 130     }
 131
 132     return $predicate;
 133 }
 134
 135 package Mouse::Util::TypeConstraints;
 136
 137 use Scalar::Util qw(blessed looks_like_number openhandle);
 138
 139 sub Any        { 1 }
 140 sub Item       { 1 }
 141
 142 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 143 sub Undef      { !defined($_[0]) }
 144 sub Defined    {  defined($_[0])  }
 145 sub Value      {  defined($_[0]) && !ref($_[0]) }
 146 sub Num        {  looks_like_number($_[0]) }
 147 sub Int        {
 148     my($value) = @_;
 149     looks_like_number($value) && $value =~ /\A [+-]? [0-9]+  \z/xms;
 150 }
 151 sub Str        {
 152     my($value) = @_;
 153     return defined($value) && ref(\$value) eq 'SCALAR';
 154 }
 155
 156 sub Ref        { ref($_[0]) }
 157 sub ScalarRef  {
 158     my($value) = @_;
 159     return ref($value) eq 'SCALAR' || ref($value) eq 'REF';
 160 }
 161 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 162 sub HashRef    { ref($_[0]) eq 'HASH'   }
 163 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 164 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 165 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 166
 167 sub FileHandle {
 168     return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 169 }
 170
 171 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 172
 173 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 174 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 175
 176 sub _parameterize_ArrayRef_for {
 177     my($type_parameter) = @_;
 178     my $check = $type_parameter->_compiled_type_constraint;
 179
 180     return sub {
 181         foreach my $value (@{$_}) {
 182             return undef unless $check->($value);
 183         }
 184         return 1;
 185     }
 186 }
 187
 188 sub _parameterize_HashRef_for {
 189     my($type_parameter) = @_;
 190     my $check = $type_parameter->_compiled_type_constraint;
 191
 192     return sub {
 193         foreach my $value(values %{$_}){
 194             return undef unless $check->($value);
 195         }
 196         return 1;
 197     };
 198 }
 199
 200 # 'Maybe' type accepts 'Any', so it requires parameters
 201 sub _parameterize_Maybe_for {
 202     my($type_parameter) = @_;
 203     my $check = $type_parameter->_compiled_type_constraint;
 204
 205     return sub{
 206         return !defined($_) || $check->($_);
 207     };
 208 }
 209
 210 package Mouse::Meta::Module;
 211
 212 sub name          { $_[0]->{package} }
 213
 214 sub _method_map   { $_[0]->{methods} }
 215 sub _attribute_map{ $_[0]->{attributes} }
 216
 217 sub namespace{
 218     my $name = $_[0]->{package};
 219     no strict 'refs';
 220     return \%{ $name . '::' };
 221 }
 222
 223 sub add_method {
 224     my($self, $name, $code) = @_;
 225
 226     if(!defined $name){
 227         $self->throw_error('You must pass a defined name');
 228     }
 229     if(!defined $code){
 230         $self->throw_error('You must pass a defined code');
 231     }
 232
 233     if(ref($code) ne 'CODE'){
 234         $code = \&{$code}; # coerce
 235     }
 236
 237     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 238
 239     Mouse::Util::install_subroutines($self->name,
 240         $name => $code,
 241     );
 242     return;
 243 }
 244
 245 my $generate_class_accessor = sub {
 246     my($name) = @_;
 247     return sub {
 248         my $self = shift;
 249         if(@_) {
 250             return $self->{$name} = shift;
 251         }
 252
 253         foreach my $class($self->linearized_isa) {
 254             my $meta = Mouse::Util::get_metaclass_by_name($class)
 255                 or next;
 256
 257             if(exists $meta->{$name}) {
 258                 return $meta->{$name};
 259             }
 260         }
 261         return undef;
 262     };
 263 };
 264
 265
 266 package Mouse::Meta::Class;
 267
 268 use Mouse::Meta::Method::Constructor;
 269 use Mouse::Meta::Method::Destructor;
 270
 271 sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
 272 sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }
 273
 274 sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
 275 sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }
 276
 277 sub is_anon_class{
 278     return exists $_[0]->{anon_serial_id};
 279 }
 280
 281 sub roles { $_[0]->{roles} }
 282
 283 sub linearized_isa { @{ Mouse::Util::get_linear_isa($_[0]->{package}) } }
 284
 285 sub new_object {
 286     my $meta = shift;
 287     my %args = (@_ == 1 ? %{$_[0]} : @_);
 288
 289     my $object = bless {}, $meta->name;
 290
 291     $meta->_initialize_object($object, \%args, 0);
 292     # BUILDALL
 293     if( $object->can('BUILD') ) {
 294         for my $class (reverse $meta->linearized_isa) {
 295             my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 296                 || next;
 297
 298             $object->$build(\%args);
 299         }
 300     }
 301     return $object;
 302 }
 303
 304 sub clone_object {
 305     my $class  = shift;
 306     my $object = shift;
 307     my $args   = $object->Mouse::Object::BUILDARGS(@_);
 308
 309     (blessed($object) && $object->isa($class->name))
 310         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 311
 312     my $cloned = bless { %$object }, ref $object;
 313     $class->_initialize_object($cloned, $args, 1);
 314     return $cloned;
 315 }
 316
 317 sub _initialize_object{
 318     my($self, $object, $args, $is_cloning) = @_;
 319     # The initializer, which is used everywhere, must be clear
 320     # when an attribute is added. See Mouse::Meta::Class::add_attribute.
 321     my $initializer = $self->{_mouse_cache}{_initialize_object} ||=
 322         Mouse::Util::load_class($self->constructor_class)
 323             ->_generate_initialize_object($self);
 324     goto &{$initializer};
 325 }
 326
 327 sub get_all_attributes {
 328     my($self) = @_;
 329     return @{ $self->{_mouse_cache}{all_attributes}
 330         ||= $self->_calculate_all_attributes };
 331 }
 332
 333 sub is_immutable {  $_[0]->{is_immutable} }
 334
 335 sub strict_constructor;
 336 *strict_constructor = $generate_class_accessor->('strict_constructor');
 337
 338 sub _report_unknown_args {
 339     my($metaclass, $attrs, $args) = @_;
 340
 341     my @unknowns;
 342     my %init_args;
 343     foreach my $attr(@{$attrs}){
 344         my $init_arg = $attr->init_arg;
 345         if(defined $init_arg){
 346             $init_args{$init_arg}++;
 347         }
 348     }
 349
 350     while(my $key = each %{$args}){
 351         if(!exists $init_args{$key}){
 352             push @unknowns, $key;
 353         }
 354     }
 355
 356     $metaclass->throw_error( sprintf
 357         "Unknown attribute passed to the constructor of %s: %s",
 358         $metaclass->name, Mouse::Util::english_list(@unknowns),
 359     );
 360 }
 361
 362 package Mouse::Meta::Role;
 363
 364 sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }
 365
 366 sub is_anon_role{
 367     return exists $_[0]->{anon_serial_id};
 368 }
 369
 370 sub get_roles { $_[0]->{roles} }
 371
 372 sub add_before_method_modifier {
 373     my ($self, $method_name, $method) = @_;
 374
 375     push @{ $self->{before_method_modifiers}{$method_name} ||= [] }, $method;
 376     return;
 377 }
 378 sub add_around_method_modifier {
 379     my ($self, $method_name, $method) = @_;
 380
 381     push @{ $self->{around_method_modifiers}{$method_name} ||= [] }, $method;
 382     return;
 383 }
 384 sub add_after_method_modifier {
 385     my ($self, $method_name, $method) = @_;
 386
 387     push @{ $self->{after_method_modifiers}{$method_name} ||= [] }, $method;
 388     return;
 389 }
 390
 391 sub get_before_method_modifiers {
 392     my ($self, $method_name) = @_;
 393     return @{ $self->{before_method_modifiers}{$method_name} ||= [] }
 394 }
 395 sub get_around_method_modifiers {
 396     my ($self, $method_name) = @_;
 397     return @{ $self->{around_method_modifiers}{$method_name} ||= [] }
 398 }
 399 sub get_after_method_modifiers {
 400     my ($self, $method_name) = @_;
 401     return @{ $self->{after_method_modifiers}{$method_name} ||= [] }
 402 }
 403
 404 sub add_metaclass_accessor { # for meta roles (a.k.a. traits)
 405     my($meta, $name) = @_;
 406     $meta->add_method($name => $generate_class_accessor->($name));
 407     return;
 408 }
 409
 410 package Mouse::Meta::Attribute;
 411
 412 require Mouse::Meta::Method::Accessor;
 413
 414 sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }
 415
 416 # readers
 417
 418 sub name                 { $_[0]->{name}                   }
 419 sub associated_class     { $_[0]->{associated_class}       }
 420
 421 sub accessor             { $_[0]->{accessor}               }
 422 sub reader               { $_[0]->{reader}                 }
 423 sub writer               { $_[0]->{writer}                 }
 424 sub predicate            { $_[0]->{predicate}              }
 425 sub clearer              { $_[0]->{clearer}                }
 426 sub handles              { $_[0]->{handles}                }
 427
 428 sub _is_metadata         { $_[0]->{is}                     }
 429 sub is_required          { $_[0]->{required}               }
 430 sub default              { $_[0]->{default}                }
 431 sub is_lazy              { $_[0]->{lazy}                   }
 432 sub is_lazy_build        { $_[0]->{lazy_build}             }
 433 sub is_weak_ref          { $_[0]->{weak_ref}               }
 434 sub init_arg             { $_[0]->{init_arg}               }
 435 sub type_constraint      { $_[0]->{type_constraint}        }
 436
 437 sub trigger              { $_[0]->{trigger}                }
 438 sub builder              { $_[0]->{builder}                }
 439 sub should_auto_deref    { $_[0]->{auto_deref}             }
 440 sub should_coerce        { $_[0]->{coerce}                 }
 441
 442 sub documentation        { $_[0]->{documentation}          }
 443 sub insertion_order      { $_[0]->{insertion_order}        }
 444
 445 # predicates
 446
 447 sub has_accessor         { exists $_[0]->{accessor}        }
 448 sub has_reader           { exists $_[0]->{reader}          }
 449 sub has_writer           { exists $_[0]->{writer}          }
 450 sub has_predicate        { exists $_[0]->{predicate}       }
 451 sub has_clearer          { exists $_[0]->{clearer}         }
 452 sub has_handles          { exists $_[0]->{handles}         }
 453
 454 sub has_default          { exists $_[0]->{default}         }
 455 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 456 sub has_trigger          { exists $_[0]->{trigger}         }
 457 sub has_builder          { exists $_[0]->{builder}         }
 458
 459 sub has_documentation    { exists $_[0]->{documentation}   }
 460
 461 sub _process_options{
 462     my($class, $name, $args) = @_;
 463
 464     # taken from Class::MOP::Attribute::new
 465
 466     defined($name)
 467         or $class->throw_error('You must provide a name for the attribute');
 468
 469     if(!exists $args->{init_arg}){
 470         $args->{init_arg} = $name;
 471     }
 472
 473     # 'required' requires eigher 'init_arg', 'builder', or 'default'
 474     my $can_be_required = defined( $args->{init_arg} );
 475
 476     if(exists $args->{builder}){
 477         # XXX:
 478         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
 479         # This feature will be changed in a future. (gfx)
 480         $class->throw_error('builder must be a defined scalar value which is a method name')
 481             #if ref $args->{builder} || !defined $args->{builder};
 482             if !defined $args->{builder};
 483
 484         $can_be_required++;
 485     }
 486     elsif(exists $args->{default}){
 487         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
 488             $class->throw_error("References are not allowed as default values, you must "
 489                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
 490         }
 491         $can_be_required++;
 492     }
 493
 494     if( $args->{required} && !$can_be_required ) {
 495         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
 496     }
 497
 498     # taken from Mouse::Meta::Attribute->new and ->_process_args
 499
 500     if(exists $args->{is}){
 501         my $is = $args->{is};
 502
 503         if($is eq 'ro'){
 504             $args->{reader} ||= $name;
 505         }
 506         elsif($is eq 'rw'){
 507             if(exists $args->{writer}){
 508                 $args->{reader} ||= $name;
 509              }
 510              else{
 511                 $args->{accessor} ||= $name;
 512              }
 513         }
 514         elsif($is eq 'bare'){
 515             # do nothing, but don't complain (later) about missing methods
 516         }
 517         else{
 518             $is = 'undef' if !defined $is;
 519             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
 520         }
 521     }
 522
 523     my $tc;
 524     if(exists $args->{isa}){
 525         $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
 526     }
 527
 528     if(exists $args->{does}){
 529         if(defined $tc){ # both isa and does supplied
 530             my $does_ok = do{
 531                 local $@;
 532                 eval{ "$tc"->does($args) };
 533             };
 534             if(!$does_ok){
 535                 $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
 536             }
 537         }
 538         else {
 539             $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
 540         }
 541     }
 542
 543     if($args->{coerce}){
 544         defined($tc)
 545             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
 546
 547         $args->{weak_ref}
 548             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
 549     }
 550
 551     if ($args->{lazy_build}) {
 552         exists($args->{default})
 553             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 554
 555         $args->{lazy}      = 1;
 556         $args->{builder} ||= "_build_${name}";
 557         if ($name =~ /^_/) {
 558             $args->{clearer}   ||= "_clear${name}";
 559             $args->{predicate} ||= "_has${name}";
 560         }
 561         else {
 562             $args->{clearer}   ||= "clear_${name}";
 563             $args->{predicate} ||= "has_${name}";
 564         }
 565     }
 566
 567     if ($args->{auto_deref}) {
 568         defined($tc)
 569             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 570
 571         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 572             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 573     }
 574
 575     if (exists $args->{trigger}) {
 576         ('CODE' eq ref $args->{trigger})
 577             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 578     }
 579
 580     if ($args->{lazy}) {
 581         (exists $args->{default} || defined $args->{builder})
 582             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 583     }
 584
 585     return;
 586 }
 587
 588
 589 package Mouse::Meta::TypeConstraint;
 590
 591 use overload
 592     '""' => '_as_string',
 593     '0+' => '_identity',
 594     '|'  => '_unite',
 595
 596     fallback => 1;
 597
 598 sub name    { $_[0]->{name}    }
 599 sub parent  { $_[0]->{parent}  }
 600 sub message { $_[0]->{message} }
 601
 602 sub _identity  { Scalar::Util::refaddr($_[0]) } # overload 0+
 603
 604 sub type_parameter           { $_[0]->{type_parameter} }
 605 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 606 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 607
 608 sub __is_parameterized { exists $_[0]->{type_parameter} }
 609 sub has_coercion {       exists $_[0]->{_compiled_type_coercion} }
 610
 611
 612 sub compile_type_constraint{
 613     my($self) = @_;
 614
 615     # add parents first
 616     my @checks;
 617     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 618          if($parent->{hand_optimized_type_constraint}){
 619             unshift @checks, $parent->{hand_optimized_type_constraint};
 620             last; # a hand optimized constraint must include all the parents
 621         }
 622         elsif($parent->{constraint}){
 623             unshift @checks, $parent->{constraint};
 624         }
 625     }
 626
 627     # then add child
 628     if($self->{constraint}){
 629         push @checks, $self->{constraint};
 630     }
 631
 632     if($self->{type_constraints}){ # Union
 633         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 634         push @checks, sub{
 635             foreach my $c(@types){
 636                 return 1 if $c->($_[0]);
 637             }
 638             return 0;
 639         };
 640     }
 641
 642     if(@checks == 0){
 643         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 644     }
 645     else{
 646         $self->{compiled_type_constraint} =  sub{
 647             my(@args) = @_;
 648             local $_ = $args[0];
 649             foreach my $c(@checks){
 650                 return undef if !$c->(@args);
 651             }
 652             return 1;
 653         };
 654     }
 655     return;
 656 }
 657
 658 sub check {
 659     my $self = shift;
 660     return $self->_compiled_type_constraint->(@_);
 661 }
 662
 663
 664 package Mouse::Object;
 665
 666 sub BUILDARGS {
 667     my $class = shift;
 668
 669     if (scalar @_ == 1) {
 670         (ref($_[0]) eq 'HASH')
 671             || $class->meta->throw_error("Single parameters to new() must be a HASH ref");
 672
 673         return {%{$_[0]}};
 674     }
 675     else {
 676         return {@_};
 677     }
 678 }
 679
 680 sub new {
 681     my $class = shift;
 682     my $args  = $class->BUILDARGS(@_);
 683     return $class->meta->new_object($args);
 684 }
 685
 686 sub DESTROY {
 687     my $self = shift;
 688
 689     return unless $self->can('DEMOLISH'); # short circuit
 690
 691     my $e = do{
 692         local $?;
 693         local $@;
 694         eval{
 695             # DEMOLISHALL
 696
 697             # We cannot count on being able to retrieve a previously made
 698             # metaclass, _or_ being able to make a new one during global
 699             # destruction. However, we should still be able to use mro at
 700             # that time (at least tests suggest so ;)
 701
 702             foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
 703                 my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
 704                     || next;
 705
 706                 $self->$demolish($Mouse::Util::in_global_destruction);
 707             }
 708         };
 709         $@;
 710     };
 711
 712     no warnings 'misc';
 713     die $e if $e; # rethrow
 714 }
 715
 716 sub BUILDALL {
 717     my $self = shift;
 718
 719     # short circuit
 720     return unless $self->can('BUILD');
 721
 722     for my $class (reverse $self->meta->linearized_isa) {
 723         my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 724             || next;
 725
 726         $self->$build(@_);
 727     }
 728     return;
 729 }
 730
 731 sub DEMOLISHALL;
 732 *DEMOLISHALL = \&DESTROY;
 733
 734 1;
 735 __END__
 736
 737 =head1 NAME
 738
 739 Mouse::PurePerl - A Mouse guts in pure Perl
 740
 741 =head1 VERSION
 742
 743 This document describes Mouse version 0.73
 744
 745 =head1 SEE ALSO
 746
 747 L<Mouse::XS>
 748
 749 =cut