lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2
   3 require Mouse::Util;
   4
   5 package Mouse::Util;
   6
   7 use strict;
   8 use warnings;
   9
  10 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
  11
  12 use B ();
  13
  14
  15 # taken from Class/MOP.pm
  16 sub is_valid_class_name {
  17     my $class = shift;
  18
  19     return 0 if ref($class);
  20     return 0 unless defined($class);
  21
  22     return 1 if $class =~ /\A \w+ (?: :: \w+ )* \z/xms;
  23
  24     return 0;
  25 }
  26
  27 sub is_class_loaded {
  28     my $class = shift;
  29
  30     return 0 if ref($class) || !defined($class) || !length($class);
  31
  32     # walk the symbol table tree to avoid autovififying
  33     # \*{${main::}{"Foo::"}{"Bar::"}} == \*main::Foo::Bar::
  34
  35     my $pack = \%::;
  36     foreach my $part (split('::', $class)) {
  37         $part .= '::';
  38         return 0 if !exists $pack->{$part};
  39
  40         my $entry = \$pack->{$part};
  41         return 0 if ref($entry) ne 'GLOB';
  42         $pack = *{$entry}{HASH};
  43     }
  44
  45     return 0 if !%{$pack};
  46
  47     # check for $VERSION or @ISA
  48     return 1 if exists $pack->{VERSION}
  49              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  50     return 1 if exists $pack->{ISA}
  51              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  52
  53     # check for any method
  54     foreach my $name( keys %{$pack} ) {
  55         my $entry = \$pack->{$name};
  56         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  57     }
  58
  59     # fail
  60     return 0;
  61 }
  62
  63
  64 # taken from Sub::Identify
  65 sub get_code_info {
  66     my ($coderef) = @_;
  67     ref($coderef) or return;
  68
  69     my $cv = B::svref_2object($coderef);
  70     $cv->isa('B::CV') or return;
  71
  72     my $gv = $cv->GV;
  73     $gv->isa('B::GV') or return;
  74
  75     return ($gv->STASH->NAME, $gv->NAME);
  76 }
  77
  78 sub get_code_package{
  79     my($coderef) = @_;
  80
  81     my $cv = B::svref_2object($coderef);
  82     $cv->isa('B::CV') or return '';
  83
  84     my $gv = $cv->GV;
  85     $gv->isa('B::GV') or return '';
  86
  87     return $gv->STASH->NAME;
  88 }
  89
  90 sub get_code_ref{
  91     my($package, $name) = @_;
  92     no strict 'refs';
  93     no warnings 'once';
  94     use warnings FATAL => 'uninitialized';
  95     return *{$package . '::' . $name}{CODE};
  96 }
  97
  98 sub generate_isa_predicate_for {
  99     my($for_class, $name) = @_;
 100
 101     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
 102
 103     if(defined $name){
 104         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 105         return;
 106     }
 107
 108     return $predicate;
 109 }
 110
 111 sub generate_can_predicate_for {
 112     my($methods_ref, $name) = @_;
 113
 114     my @methods = @{$methods_ref};
 115
 116     my $predicate = sub{
 117         my($instance) = @_;
 118         if(Scalar::Util::blessed($instance)){
 119             foreach my $method(@methods){
 120                 if(!$instance->can($method)){
 121                     return 0;
 122                 }
 123             }
 124             return 1;
 125         }
 126         return 0;
 127     };
 128
 129     if(defined $name){
 130         Mouse::Util::install_subroutines(scalar caller, $name => $predicate);
 131         return;
 132     }
 133
 134     return $predicate;
 135 }
 136
 137 package Mouse::Util::TypeConstraints;
 138
 139 use Scalar::Util qw(blessed looks_like_number openhandle);
 140
 141 sub Any        { 1 }
 142 sub Item       { 1 }
 143
 144 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 145 sub Undef      { !defined($_[0]) }
 146 sub Defined    {  defined($_[0])  }
 147 sub Value      {  defined($_[0]) && !ref($_[0]) }
 148 sub Num        {  looks_like_number($_[0]) }
 149 sub Int        {
 150     my($value) = @_;
 151     looks_like_number($value) && do{
 152         # work around RT #55048
 153         # This is for more than 32 bit int on 32 bit systems
 154         require POSIX;
 155         POSIX::fmod($value, 1) == 0;
 156     };
 157 }
 158 sub Str        {
 159     my($value) = @_;
 160     return defined($value) && ref(\$value) eq 'SCALAR';
 161 }
 162
 163 sub Ref        { ref($_[0]) }
 164 sub ScalarRef  {
 165     my($value) = @_;
 166     return ref($value) eq 'SCALAR'
 167 }
 168 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 169 sub HashRef    { ref($_[0]) eq 'HASH'   }
 170 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 171 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 172 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 173
 174 sub FileHandle {
 175     return openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 176 }
 177
 178 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 179
 180 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 181 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 182
 183 sub _parameterize_ArrayRef_for {
 184     my($type_parameter) = @_;
 185     my $check = $type_parameter->_compiled_type_constraint;
 186
 187     return sub {
 188         foreach my $value (@{$_}) {
 189             return undef unless $check->($value);
 190         }
 191         return 1;
 192     }
 193 }
 194
 195 sub _parameterize_HashRef_for {
 196     my($type_parameter) = @_;
 197     my $check = $type_parameter->_compiled_type_constraint;
 198
 199     return sub {
 200         foreach my $value(values %{$_}){
 201             return undef unless $check->($value);
 202         }
 203         return 1;
 204     };
 205 }
 206
 207 # 'Maybe' type accepts 'Any', so it requires parameters
 208 sub _parameterize_Maybe_for {
 209     my($type_parameter) = @_;
 210     my $check = $type_parameter->_compiled_type_constraint;
 211
 212     return sub{
 213         return !defined($_) || $check->($_);
 214     };
 215 }
 216
 217 package Mouse::Meta::Module;
 218
 219 sub name          { $_[0]->{package} }
 220
 221 sub _method_map   { $_[0]->{methods} }
 222 sub _attribute_map{ $_[0]->{attributes} }
 223
 224 sub namespace{
 225     my $name = $_[0]->{package};
 226     no strict 'refs';
 227     return \%{ $name . '::' };
 228 }
 229
 230 sub add_method {
 231     my($self, $name, $code) = @_;
 232
 233     if(!defined $name){
 234         $self->throw_error('You must pass a defined name');
 235     }
 236     if(!defined $code){
 237         $self->throw_error('You must pass a defined code');
 238     }
 239
 240     if(ref($code) ne 'CODE'){
 241         $code = \&{$code}; # coerce
 242     }
 243
 244     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 245
 246     Mouse::Util::install_subroutines($self->name,
 247         $name => $code,
 248     );
 249     return;
 250 }
 251
 252 package Mouse::Meta::Class;
 253
 254 use Mouse::Meta::Method::Constructor;
 255 use Mouse::Meta::Method::Destructor;
 256
 257 sub method_metaclass    { $_[0]->{method_metaclass}    || 'Mouse::Meta::Method'    }
 258 sub attribute_metaclass { $_[0]->{attribute_metaclass} || 'Mouse::Meta::Attribute' }
 259
 260 sub constructor_class { $_[0]->{constructor_class} || 'Mouse::Meta::Method::Constructor' }
 261 sub destructor_class  { $_[0]->{destructor_class}  || 'Mouse::Meta::Method::Destructor'  }
 262
 263 sub is_anon_class{
 264     return exists $_[0]->{anon_serial_id};
 265 }
 266
 267 sub roles { $_[0]->{roles} }
 268
 269 sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
 270
 271 sub get_all_attributes {
 272     my($self) = @_;
 273     my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
 274     return values %attrs;
 275 }
 276
 277 sub new_object {
 278     my $self = shift;
 279     my %args = (@_ == 1 ? %{$_[0]} : @_);
 280
 281     my $object = bless {}, $self->name;
 282
 283     $self->_initialize_object($object, \%args);
 284     return $object;
 285 }
 286
 287 sub _initialize_object{
 288     my($self, $object, $args, $ignore_triggers) = @_;
 289
 290     my @triggers_queue;
 291
 292     foreach my $attribute ($self->get_all_attributes) {
 293         my $init_arg = $attribute->init_arg;
 294         my $slot     = $attribute->name;
 295
 296         if (defined($init_arg) && exists($args->{$init_arg})) {
 297             $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
 298
 299             weaken($object->{$slot})
 300                 if ref($object->{$slot}) && $attribute->is_weak_ref;
 301
 302             if ($attribute->has_trigger) {
 303                 push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
 304             }
 305         }
 306         else { # no init arg
 307             if ($attribute->has_default || $attribute->has_builder) {
 308                 if (!$attribute->is_lazy) {
 309                     my $default = $attribute->default;
 310                     my $builder = $attribute->builder;
 311                     my $value =   $builder                ? $object->$builder()
 312                                 : ref($default) eq 'CODE' ? $object->$default()
 313                                 :                           $default;
 314
 315                     $object->{$slot} = $attribute->_coerce_and_verify($value, $object);
 316
 317                     weaken($object->{$slot})
 318                         if ref($object->{$slot}) && $attribute->is_weak_ref;
 319                 }
 320             }
 321             elsif($attribute->is_required) {
 322                 $self->throw_error("Attribute (".$attribute->name.") is required");
 323             }
 324         }
 325     }
 326
 327     if(!$ignore_triggers){
 328         foreach my $trigger_and_value(@triggers_queue){
 329             my($trigger, $value) = @{$trigger_and_value};
 330             $trigger->($object, $value);
 331         }
 332     }
 333
 334     if($self->is_anon_class){
 335         $object->{__METACLASS__} = $self;
 336     }
 337
 338     return;
 339 }
 340
 341 sub is_immutable {  $_[0]->{is_immutable} }
 342
 343 sub __strict_constructor{ $_[0]->{strict_constructor} }
 344
 345 package Mouse::Meta::Role;
 346
 347 sub method_metaclass{ $_[0]->{method_metaclass} || 'Mouse::Meta::Role::Method' }
 348
 349 sub is_anon_role{
 350     return exists $_[0]->{anon_serial_id};
 351 }
 352
 353 sub get_roles { $_[0]->{roles} }
 354
 355 sub add_before_method_modifier {
 356     my ($self, $method_name, $method) = @_;
 357
 358     push @{ $self->{before_method_modifiers}{$method_name} ||= [] }, $method;
 359     return;
 360 }
 361 sub add_around_method_modifier {
 362     my ($self, $method_name, $method) = @_;
 363
 364     push @{ $self->{around_method_modifiers}{$method_name} ||= [] }, $method;
 365     return;
 366 }
 367 sub add_after_method_modifier {
 368     my ($self, $method_name, $method) = @_;
 369
 370     push @{ $self->{after_method_modifiers}{$method_name} ||= [] }, $method;
 371     return;
 372 }
 373
 374 sub get_before_method_modifiers {
 375     my ($self, $method_name) = @_;
 376     return @{ $self->{before_method_modifiers}{$method_name} ||= [] }
 377 }
 378 sub get_around_method_modifiers {
 379     my ($self, $method_name) = @_;
 380     return @{ $self->{around_method_modifiers}{$method_name} ||= [] }
 381 }
 382 sub get_after_method_modifiers {
 383     my ($self, $method_name) = @_;
 384     return @{ $self->{after_method_modifiers}{$method_name} ||= [] }
 385 }
 386
 387 package Mouse::Meta::Attribute;
 388
 389 require Mouse::Meta::Method::Accessor;
 390
 391 sub accessor_metaclass{ $_[0]->{accessor_metaclass} || 'Mouse::Meta::Method::Accessor' }
 392
 393 # readers
 394
 395 sub name                 { $_[0]->{name}                   }
 396 sub associated_class     { $_[0]->{associated_class}       }
 397
 398 sub accessor             { $_[0]->{accessor}               }
 399 sub reader               { $_[0]->{reader}                 }
 400 sub writer               { $_[0]->{writer}                 }
 401 sub predicate            { $_[0]->{predicate}              }
 402 sub clearer              { $_[0]->{clearer}                }
 403 sub handles              { $_[0]->{handles}                }
 404
 405 sub _is_metadata         { $_[0]->{is}                     }
 406 sub is_required          { $_[0]->{required}               }
 407 sub default              { $_[0]->{default}                }
 408 sub is_lazy              { $_[0]->{lazy}                   }
 409 sub is_lazy_build        { $_[0]->{lazy_build}             }
 410 sub is_weak_ref          { $_[0]->{weak_ref}               }
 411 sub init_arg             { $_[0]->{init_arg}               }
 412 sub type_constraint      { $_[0]->{type_constraint}        }
 413
 414 sub trigger              { $_[0]->{trigger}                }
 415 sub builder              { $_[0]->{builder}                }
 416 sub should_auto_deref    { $_[0]->{auto_deref}             }
 417 sub should_coerce        { $_[0]->{coerce}                 }
 418
 419 sub documentation        { $_[0]->{documentation}          }
 420
 421 # predicates
 422
 423 sub has_accessor         { exists $_[0]->{accessor}        }
 424 sub has_reader           { exists $_[0]->{reader}          }
 425 sub has_writer           { exists $_[0]->{writer}          }
 426 sub has_predicate        { exists $_[0]->{predicate}       }
 427 sub has_clearer          { exists $_[0]->{clearer}         }
 428 sub has_handles          { exists $_[0]->{handles}         }
 429
 430 sub has_default          { exists $_[0]->{default}         }
 431 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 432 sub has_trigger          { exists $_[0]->{trigger}         }
 433 sub has_builder          { exists $_[0]->{builder}         }
 434
 435 sub has_documentation    { exists $_[0]->{documentation}   }
 436
 437 sub _process_options{
 438     my($class, $name, $args) = @_;
 439
 440     # taken from Class::MOP::Attribute::new
 441
 442     defined($name)
 443         or $class->throw_error('You must provide a name for the attribute');
 444
 445     if(!exists $args->{init_arg}){
 446         $args->{init_arg} = $name;
 447     }
 448
 449     # 'required' requires eigher 'init_arg', 'builder', or 'default'
 450     my $can_be_required = defined( $args->{init_arg} );
 451
 452     if(exists $args->{builder}){
 453         # XXX:
 454         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
 455         # This feature will be changed in a future. (gfx)
 456         $class->throw_error('builder must be a defined scalar value which is a method name')
 457             #if ref $args->{builder} || !defined $args->{builder};
 458             if !defined $args->{builder};
 459
 460         $can_be_required++;
 461     }
 462     elsif(exists $args->{default}){
 463         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
 464             $class->throw_error("References are not allowed as default values, you must "
 465                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
 466         }
 467         $can_be_required++;
 468     }
 469
 470     if( $args->{required} && !$can_be_required ) {
 471         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
 472     }
 473
 474     # taken from Mouse::Meta::Attribute->new and ->_process_args
 475
 476     if(exists $args->{is}){
 477         my $is = $args->{is};
 478
 479         if($is eq 'ro'){
 480             $args->{reader} ||= $name;
 481         }
 482         elsif($is eq 'rw'){
 483             if(exists $args->{writer}){
 484                 $args->{reader} ||= $name;
 485              }
 486              else{
 487                 $args->{accessor} ||= $name;
 488              }
 489         }
 490         elsif($is eq 'bare'){
 491             # do nothing, but don't complain (later) about missing methods
 492         }
 493         else{
 494             $is = 'undef' if !defined $is;
 495             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
 496         }
 497     }
 498
 499     my $tc;
 500     if(exists $args->{isa}){
 501         $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
 502     }
 503
 504     if(exists $args->{does}){
 505         if(defined $tc){ # both isa and does supplied
 506             my $does_ok = do{
 507                 local $@;
 508                 eval{ "$tc"->does($args) };
 509             };
 510             if(!$does_ok){
 511                 $class->throw_error("Cannot have both an isa option and a does option because '$tc' does not do '$args->{does}' on attribute ($name)");
 512             }
 513         }
 514         else {
 515             $tc = $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
 516         }
 517     }
 518
 519     if($args->{coerce}){
 520         defined($tc)
 521             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
 522
 523         $args->{weak_ref}
 524             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
 525     }
 526
 527     if ($args->{lazy_build}) {
 528         exists($args->{default})
 529             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 530
 531         $args->{lazy}      = 1;
 532         $args->{builder} ||= "_build_${name}";
 533         if ($name =~ /^_/) {
 534             $args->{clearer}   ||= "_clear${name}";
 535             $args->{predicate} ||= "_has${name}";
 536         }
 537         else {
 538             $args->{clearer}   ||= "clear_${name}";
 539             $args->{predicate} ||= "has_${name}";
 540         }
 541     }
 542
 543     if ($args->{auto_deref}) {
 544         defined($tc)
 545             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 546
 547         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 548             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 549     }
 550
 551     if (exists $args->{trigger}) {
 552         ('CODE' eq ref $args->{trigger})
 553             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 554     }
 555
 556     if ($args->{lazy}) {
 557         (exists $args->{default} || defined $args->{builder})
 558             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 559     }
 560
 561     return;
 562 }
 563
 564
 565 package Mouse::Meta::TypeConstraint;
 566
 567 sub name    { $_[0]->{name}    }
 568 sub parent  { $_[0]->{parent}  }
 569 sub message { $_[0]->{message} }
 570
 571 sub type_parameter           { $_[0]->{type_parameter} }
 572 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 573 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 574
 575 sub __is_parameterized { exists $_[0]->{type_parameter} }
 576 sub has_coercion {       exists $_[0]->{_compiled_type_coercion} }
 577
 578
 579 sub compile_type_constraint{
 580     my($self) = @_;
 581
 582     # add parents first
 583     my @checks;
 584     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 585          if($parent->{hand_optimized_type_constraint}){
 586             unshift @checks, $parent->{hand_optimized_type_constraint};
 587             last; # a hand optimized constraint must include all the parents
 588         }
 589         elsif($parent->{constraint}){
 590             unshift @checks, $parent->{constraint};
 591         }
 592     }
 593
 594     # then add child
 595     if($self->{constraint}){
 596         push @checks, $self->{constraint};
 597     }
 598
 599     if($self->{type_constraints}){ # Union
 600         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 601         push @checks, sub{
 602             foreach my $c(@types){
 603                 return 1 if $c->($_[0]);
 604             }
 605             return 0;
 606         };
 607     }
 608
 609     if(@checks == 0){
 610         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 611     }
 612     else{
 613         $self->{compiled_type_constraint} =  sub{
 614             my(@args) = @_;
 615             local $_ = $args[0];
 616             foreach my $c(@checks){
 617                 return undef if !$c->(@args);
 618             }
 619             return 1;
 620         };
 621     }
 622     return;
 623 }
 624
 625 package Mouse::Object;
 626
 627 sub BUILDARGS {
 628     my $class = shift;
 629
 630     if (scalar @_ == 1) {
 631         (ref($_[0]) eq 'HASH')
 632             || $class->meta->throw_error("Single parameters to new() must be a HASH ref");
 633
 634         return {%{$_[0]}};
 635     }
 636     else {
 637         return {@_};
 638     }
 639 }
 640
 641 sub new {
 642     my $class = shift;
 643
 644     $class->meta->throw_error('Cannot call new() on an instance') if ref $class;
 645
 646     my $args = $class->BUILDARGS(@_);
 647
 648     my $meta = Mouse::Meta::Class->initialize($class);
 649     my $self = $meta->new_object($args);
 650
 651     # BUILDALL
 652     if( $self->can('BUILD') ) {
 653         for my $class (reverse $meta->linearized_isa) {
 654             my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 655                 || next;
 656
 657             $self->$build($args);
 658         }
 659     }
 660
 661     return $self;
 662 }
 663
 664 sub DESTROY {
 665     my $self = shift;
 666
 667     return unless $self->can('DEMOLISH'); # short circuit
 668
 669     local $?;
 670
 671     my $e = do{
 672         local $@;
 673         eval{
 674             # DEMOLISHALL
 675
 676             # We cannot count on being able to retrieve a previously made
 677             # metaclass, _or_ being able to make a new one during global
 678             # destruction. However, we should still be able to use mro at
 679             # that time (at least tests suggest so ;)
 680
 681             foreach my $class (@{ Mouse::Util::get_linear_isa(ref $self) }) {
 682                 my $demolish = Mouse::Util::get_code_ref($class, 'DEMOLISH')
 683                     || next;
 684
 685                 $self->$demolish($Mouse::Util::in_global_destruction);
 686             }
 687         };
 688         $@;
 689     };
 690
 691     no warnings 'misc';
 692     die $e if $e; # rethrow
 693 }
 694
 695 sub BUILDALL {
 696     my $self = shift;
 697
 698     # short circuit
 699     return unless $self->can('BUILD');
 700
 701     for my $class (reverse $self->meta->linearized_isa) {
 702         my $build = Mouse::Util::get_code_ref($class, 'BUILD')
 703             || next;
 704
 705         $self->$build(@_);
 706     }
 707     return;
 708 }
 709
 710 sub DEMOLISHALL;
 711 *DEMOLISHALL = \&DESTROY;
 712
 713 1;
 714 __END__
 715
 716 =head1 NAME
 717
 718 Mouse::PurePerl - A Mouse guts in pure Perl
 719
 720 =head1 VERSION
 721
 722 This document describes Mouse version 0.50_08
 723
 724 =head1 SEE ALSO
 725
 726 L<Mouse::XS>
 727
 728 =cut