lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2
   3 require Mouse::Util;
   4
   5 package
   6     Mouse::Util;
   7
   8 use strict;
   9 use warnings;
  10
  11 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
  12
  13 use B ();
  14
  15 sub is_class_loaded {
  16     my $class = shift;
  17
  18     return 0 if ref($class) || !defined($class) || !length($class);
  19
  20     # walk the symbol table tree to avoid autovififying
  21     # \*{${main::}{"Foo::"}} == \*main::Foo::
  22
  23     my $pack = \%::;
  24     foreach my $part (split('::', $class)) {
  25         my $entry = \$pack->{$part . '::'};
  26         return 0 if ref($entry) ne 'GLOB';
  27         $pack = *{$entry}{HASH} or return 0;
  28     }
  29
  30     # check for $VERSION or @ISA
  31     return 1 if exists $pack->{VERSION}
  32              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  33     return 1 if exists $pack->{ISA}
  34              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  35
  36     # check for any method
  37     foreach my $name( keys %{$pack} ) {
  38         my $entry = \$pack->{$name};
  39         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  40     }
  41
  42     # fail
  43     return 0;
  44 }
  45
  46
  47 # taken from Sub::Identify
  48 sub get_code_info {
  49     my ($coderef) = @_;
  50     ref($coderef) or return;
  51
  52     my $cv = B::svref_2object($coderef);
  53     $cv->isa('B::CV') or return;
  54
  55     my $gv = $cv->GV;
  56     $gv->isa('B::GV') or return;
  57
  58     return ($gv->STASH->NAME, $gv->NAME);
  59 }
  60
  61 sub get_code_package{
  62     my($coderef) = @_;
  63
  64     my $cv = B::svref_2object($coderef);
  65     $cv->isa('B::CV') or return '';
  66
  67     my $gv = $cv->GV;
  68     $gv->isa('B::GV') or return '';
  69
  70     return $gv->STASH->NAME;
  71 }
  72
  73 sub get_code_ref{
  74     my($package, $name) = @_;
  75     no strict 'refs';
  76     no warnings 'once';
  77     use warnings FATAL => 'uninitialized';
  78     return *{$package . '::' . $name}{CODE};
  79 }
  80
  81 sub generate_isa_predicate_for {
  82     my($for_class, $name) = @_;
  83
  84     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
  85
  86     if(defined $name){
  87         no strict 'refs';
  88         *{ caller() . '::' . $name } = $predicate;
  89         return;
  90     }
  91
  92     return $predicate;
  93 }
  94
  95
  96 package
  97     Mouse::Util::TypeConstraints;
  98
  99 use Scalar::Util qw(blessed looks_like_number openhandle);
 100
 101 sub Any        { 1 }
 102 sub Item       { 1 }
 103
 104 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 105 sub Undef      { !defined($_[0]) }
 106 sub Defined    {  defined($_[0])  }
 107 sub Value      {  defined($_[0]) && !ref($_[0]) }
 108 sub Num        { !ref($_[0]) && looks_like_number($_[0]) }
 109 sub Int        {  defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
 110 sub Str        {  defined($_[0]) && !ref($_[0]) }
 111
 112 sub Ref        { ref($_[0]) }
 113 sub ScalarRef  { ref($_[0]) eq 'SCALAR' }
 114 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 115 sub HashRef    { ref($_[0]) eq 'HASH'   }
 116 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 117 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 118 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 119
 120 sub FileHandle {
 121     openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 122 }
 123
 124 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 125
 126 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 127 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 128
 129 sub _parameterize_ArrayRef_for {
 130     my($type_parameter) = @_;
 131     my $check = $type_parameter->_compiled_type_constraint;
 132
 133     return sub {
 134         foreach my $value (@{$_}) {
 135             return undef unless $check->($value);
 136         }
 137         return 1;
 138     }
 139 }
 140
 141 sub _parameterize_HashRef_for {
 142     my($type_parameter) = @_;
 143     my $check = $type_parameter->_compiled_type_constraint;
 144
 145     return sub {
 146         foreach my $value(values %{$_}){
 147             return undef unless $check->($value);
 148         }
 149         return 1;
 150     };
 151 }
 152
 153 # 'Maybe' type accepts 'Any', so it requires parameters
 154 sub _parameterize_Maybe_for {
 155     my($type_parameter) = @_;
 156     my $check = $type_parameter->_compiled_type_constraint;
 157
 158     return sub{
 159         return !defined($_) || $check->($_);
 160     };
 161 };
 162
 163
 164
 165 package
 166     Mouse::Meta::Module;
 167
 168 sub name          { $_[0]->{package} }
 169
 170 sub _method_map   { $_[0]->{methods} }
 171 sub _attribute_map{ $_[0]->{attributes} }
 172
 173 sub namespace{
 174     my $name = $_[0]->{package};
 175     no strict 'refs';
 176     return \%{ $name . '::' };
 177 }
 178
 179 sub add_method {
 180     my($self, $name, $code) = @_;
 181
 182     if(!defined $name){
 183         $self->throw_error('You must pass a defined name');
 184     }
 185     if(!defined $code){
 186         $self->throw_error('You must pass a defined code');
 187     }
 188
 189     if(ref($code) ne 'CODE'){
 190         $code = \&{$code}; # coerce
 191     }
 192
 193     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 194
 195     my $pkg = $self->name;
 196     no strict 'refs';
 197     no warnings 'redefine', 'once';
 198     *{ $pkg . '::' . $name } = $code;
 199     return;
 200 }
 201
 202
 203 package
 204     Mouse::Meta::Class;
 205
 206 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
 207
 208 sub is_anon_class{
 209     return exists $_[0]->{anon_serial_id};
 210 }
 211
 212 sub roles { $_[0]->{roles} }
 213
 214 sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
 215
 216 sub get_all_attributes {
 217     my($self) = @_;
 218     my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
 219     return values %attrs;
 220 }
 221
 222 sub _initialize_object{
 223     my($self, $object, $args, $ignore_triggers) = @_;
 224
 225     my @triggers_queue;
 226
 227     foreach my $attribute ($self->get_all_attributes) {
 228         my $init_arg = $attribute->init_arg;
 229         my $slot     = $attribute->name;
 230
 231         if (defined($init_arg) && exists($args->{$init_arg})) {
 232             $object->{$slot} = $attribute->_coerce_and_verify($args->{$init_arg}, $object);
 233
 234             weaken($object->{$slot})
 235                 if ref($object->{$slot}) && $attribute->is_weak_ref;
 236
 237             if ($attribute->has_trigger) {
 238                 push @triggers_queue, [ $attribute->trigger, $object->{$slot} ];
 239             }
 240         }
 241         else { # no init arg
 242             if ($attribute->has_default || $attribute->has_builder) {
 243                 if (!$attribute->is_lazy) {
 244                     my $default = $attribute->default;
 245                     my $builder = $attribute->builder;
 246                     my $value =   $builder                ? $object->$builder()
 247                                 : ref($default) eq 'CODE' ? $object->$default()
 248                                 :                           $default;
 249
 250                     $object->{$slot} = $attribute->_coerce_and_verify($value, $object);
 251
 252                     weaken($object->{$slot})
 253                         if ref($object->{$slot}) && $attribute->is_weak_ref;
 254                 }
 255             }
 256             elsif($attribute->is_required) {
 257                 $self->throw_error("Attribute (".$attribute->name.") is required");
 258             }
 259         }
 260     }
 261
 262     if(!$ignore_triggers){
 263         foreach my $trigger_and_value(@triggers_queue){
 264             my($trigger, $value) = @{$trigger_and_value};
 265             $trigger->($object, $value);
 266         }
 267     }
 268
 269     if($self->is_anon_class){
 270         $object->{__METACLASS__} = $self;
 271     }
 272
 273     return;
 274 }
 275
 276
 277 package
 278     Mouse::Meta::Role;
 279
 280 sub is_anon_role{
 281     return exists $_[0]->{anon_serial_id};
 282 }
 283
 284 sub get_roles { $_[0]->{roles} }
 285
 286 package
 287     Mouse::Meta::Attribute;
 288
 289 use Mouse::Meta::Method::Accessor;
 290
 291 # readers
 292
 293 sub name                 { $_[0]->{name}                   }
 294 sub associated_class     { $_[0]->{associated_class}       }
 295
 296 sub accessor             { $_[0]->{accessor}               }
 297 sub reader               { $_[0]->{reader}                 }
 298 sub writer               { $_[0]->{writer}                 }
 299 sub predicate            { $_[0]->{predicate}              }
 300 sub clearer              { $_[0]->{clearer}                }
 301 sub handles              { $_[0]->{handles}                }
 302
 303 sub _is_metadata         { $_[0]->{is}                     }
 304 sub is_required          { $_[0]->{required}               }
 305 sub default              { $_[0]->{default}                }
 306 sub is_lazy              { $_[0]->{lazy}                   }
 307 sub is_lazy_build        { $_[0]->{lazy_build}             }
 308 sub is_weak_ref          { $_[0]->{weak_ref}               }
 309 sub init_arg             { $_[0]->{init_arg}               }
 310 sub type_constraint      { $_[0]->{type_constraint}        }
 311
 312 sub trigger              { $_[0]->{trigger}                }
 313 sub builder              { $_[0]->{builder}                }
 314 sub should_auto_deref    { $_[0]->{auto_deref}             }
 315 sub should_coerce        { $_[0]->{coerce}                 }
 316
 317 sub documentation        { $_[0]->{documentation}          }
 318
 319 # predicates
 320
 321 sub has_accessor         { exists $_[0]->{accessor}        }
 322 sub has_reader           { exists $_[0]->{reader}          }
 323 sub has_writer           { exists $_[0]->{writer}          }
 324 sub has_predicate        { exists $_[0]->{predicate}       }
 325 sub has_clearer          { exists $_[0]->{clearer}         }
 326 sub has_handles          { exists $_[0]->{handles}         }
 327
 328 sub has_default          { exists $_[0]->{default}         }
 329 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 330 sub has_trigger          { exists $_[0]->{trigger}         }
 331 sub has_builder          { exists $_[0]->{builder}         }
 332
 333 sub has_documentation    { exists $_[0]->{documentation}   }
 334
 335 sub accessor_metaclass(){ 'Mouse::Meta::Method::Accessor' }
 336
 337 package
 338     Mouse::Meta::TypeConstraint;
 339
 340 sub name    { $_[0]->{name}    }
 341 sub parent  { $_[0]->{parent}  }
 342 sub message { $_[0]->{message} }
 343
 344 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 345
 346 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 347
 348 sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }
 349
 350
 351 sub compile_type_constraint{
 352     my($self) = @_;
 353
 354     # add parents first
 355     my @checks;
 356     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 357          if($parent->{hand_optimized_type_constraint}){
 358             unshift @checks, $parent->{hand_optimized_type_constraint};
 359             last; # a hand optimized constraint must include all the parents
 360         }
 361         elsif($parent->{constraint}){
 362             unshift @checks, $parent->{constraint};
 363         }
 364     }
 365
 366     # then add child
 367     if($self->{constraint}){
 368         push @checks, $self->{constraint};
 369     }
 370
 371     if($self->{type_constraints}){ # Union
 372         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 373         push @checks, sub{
 374             foreach my $c(@types){
 375                 return 1 if $c->($_[0]);
 376             }
 377             return 0;
 378         };
 379     }
 380
 381     if(@checks == 0){
 382         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 383     }
 384     else{
 385         $self->{compiled_type_constraint} =  sub{
 386             my(@args) = @_;
 387             local $_ = $args[0];
 388             foreach my $c(@checks){
 389                 return undef if !$c->(@args);
 390             }
 391             return 1;
 392         };
 393     }
 394     return;
 395 }
 396
 397 package
 398     Mouse::Object;
 399
 400
 401 sub BUILDARGS {
 402     my $class = shift;
 403
 404     if (scalar @_ == 1) {
 405         (ref($_[0]) eq 'HASH')
 406             || $class->meta->throw_error("Single parameters to new() must be a HASH ref");
 407
 408         return {%{$_[0]}};
 409     }
 410     else {
 411         return {@_};
 412     }
 413 }
 414
 415 1;
 416 __END__
 417
 418 =head1 NAME
 419
 420 Mouse::PurePerl - A Mouse guts in pure Perl
 421
 422 =head1 VERSION
 423
 424 This document describes Mouse version 0.40_05
 425
 426 =head1 SEE ALSO
 427
 428 L<Mouse::XS>
 429
 430 =cut