lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2
   3 require Mouse::Util;
   4
   5 package
   6     Mouse::Util;
   7
   8 use strict;
   9 use warnings;
  10
  11 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
  12
  13 use B ();
  14
  15 sub is_class_loaded {
  16     my $class = shift;
  17
  18     return 0 if ref($class) || !defined($class) || !length($class);
  19
  20     # walk the symbol table tree to avoid autovififying
  21     # \*{${main::}{"Foo::"}} == \*main::Foo::
  22
  23     my $pack = \%::;
  24     foreach my $part (split('::', $class)) {
  25         my $entry = \$pack->{$part . '::'};
  26         return 0 if ref($entry) ne 'GLOB';
  27         $pack = *{$entry}{HASH} or return 0;
  28     }
  29
  30     # check for $VERSION or @ISA
  31     return 1 if exists $pack->{VERSION}
  32              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  33     return 1 if exists $pack->{ISA}
  34              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  35
  36     # check for any method
  37     foreach my $name( keys %{$pack} ) {
  38         my $entry = \$pack->{$name};
  39         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  40     }
  41
  42     # fail
  43     return 0;
  44 }
  45
  46
  47 # taken from Sub::Identify
  48 sub get_code_info {
  49     my ($coderef) = @_;
  50     ref($coderef) or return;
  51
  52     my $cv = B::svref_2object($coderef);
  53     $cv->isa('B::CV') or return;
  54
  55     my $gv = $cv->GV;
  56     $gv->isa('B::GV') or return;
  57
  58     return ($gv->STASH->NAME, $gv->NAME);
  59 }
  60
  61 sub get_code_package{
  62     my($coderef) = @_;
  63
  64     my $cv = B::svref_2object($coderef);
  65     $cv->isa('B::CV') or return '';
  66
  67     my $gv = $cv->GV;
  68     $gv->isa('B::GV') or return '';
  69
  70     return $gv->STASH->NAME;
  71 }
  72
  73 sub get_code_ref{
  74     my($package, $name) = @_;
  75     no strict 'refs';
  76     no warnings 'once';
  77     use warnings FATAL => 'uninitialized';
  78     return *{$package . '::' . $name}{CODE};
  79 }
  80
  81 sub generate_isa_predicate_for {
  82     my($for_class, $name) = @_;
  83
  84     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
  85
  86     if(defined $name){
  87         no strict 'refs';
  88         *{ caller() . '::' . $name } = $predicate;
  89         return;
  90     }
  91
  92     return $predicate;
  93 }
  94
  95
  96 package
  97     Mouse::Util::TypeConstraints;
  98
  99 use Scalar::Util qw(blessed looks_like_number openhandle);
 100
 101 sub Any        { 1 }
 102 sub Item       { 1 }
 103
 104 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 105 sub Undef      { !defined($_[0]) }
 106 sub Defined    {  defined($_[0])  }
 107 sub Value      {  defined($_[0]) && !ref($_[0]) }
 108 sub Num        { !ref($_[0]) && looks_like_number($_[0]) }
 109 sub Int        {  defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
 110 sub Str        {  defined($_[0]) && !ref($_[0]) }
 111
 112 sub Ref        { ref($_[0]) }
 113 sub ScalarRef  { ref($_[0]) eq 'SCALAR' }
 114 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 115 sub HashRef    { ref($_[0]) eq 'HASH'   }
 116 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 117 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 118 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 119
 120 sub FileHandle {
 121     openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 122 }
 123
 124 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 125
 126 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 127 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 128
 129 sub _parameterize_ArrayRef_for {
 130     my($type_parameter) = @_;
 131     my $check = $type_parameter->_compiled_type_constraint;
 132
 133     return sub {
 134         foreach my $value (@{$_}) {
 135             return undef unless $check->($value);
 136         }
 137         return 1;
 138     }
 139 }
 140
 141 sub _parameterize_HashRef_for {
 142     my($type_parameter) = @_;
 143     my $check = $type_parameter->_compiled_type_constraint;
 144
 145     return sub {
 146         foreach my $value(values %{$_}){
 147             return undef unless $check->($value);
 148         }
 149         return 1;
 150     };
 151 }
 152
 153 # 'Maybe' type accepts 'Any', so it requires parameters
 154 sub _parameterize_Maybe_for {
 155     my($type_parameter) = @_;
 156     my $check = $type_parameter->_compiled_type_constraint;
 157
 158     return sub{
 159         return !defined($_) || $check->($_);
 160     };
 161 };
 162
 163
 164
 165 package
 166     Mouse::Meta::Module;
 167
 168 sub name          { $_[0]->{package} }
 169
 170 sub _method_map   { $_[0]->{methods} }
 171 sub _attribute_map{ $_[0]->{attributes} }
 172
 173 sub namespace{
 174     my $name = $_[0]->{package};
 175     no strict 'refs';
 176     return \%{ $name . '::' };
 177 }
 178
 179 sub add_method {
 180     my($self, $name, $code) = @_;
 181
 182     if(!defined $name){
 183         $self->throw_error('You must pass a defined name');
 184     }
 185     if(!defined $code){
 186         $self->throw_error('You must pass a defined code');
 187     }
 188
 189     if(ref($code) ne 'CODE'){
 190         $code = \&{$code}; # coerce
 191     }
 192
 193     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 194
 195     my $pkg = $self->name;
 196     no strict 'refs';
 197     no warnings 'redefine', 'once';
 198     *{ $pkg . '::' . $name } = $code;
 199     return;
 200 }
 201
 202
 203 package
 204     Mouse::Meta::Class;
 205
 206 sub is_anon_class{
 207     return exists $_[0]->{anon_serial_id};
 208 }
 209
 210 sub roles { $_[0]->{roles} }
 211
 212 sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
 213
 214 sub get_all_attributes {
 215     my($self) = @_;
 216     my %attrs = map { %{ $self->initialize($_)->{attributes} } } reverse $self->linearized_isa;
 217     return values %attrs;
 218 }
 219
 220 package
 221     Mouse::Meta::Role;
 222
 223 sub is_anon_role{
 224     return exists $_[0]->{anon_serial_id};
 225 }
 226
 227 sub get_roles { $_[0]->{roles} }
 228
 229 package
 230     Mouse::Meta::Attribute;
 231
 232 use Mouse::Meta::Method::Accessor;
 233
 234 # readers
 235
 236 sub name                 { $_[0]->{name}                   }
 237 sub associated_class     { $_[0]->{associated_class}       }
 238
 239 sub accessor             { $_[0]->{accessor}               }
 240 sub reader               { $_[0]->{reader}                 }
 241 sub writer               { $_[0]->{writer}                 }
 242 sub predicate            { $_[0]->{predicate}              }
 243 sub clearer              { $_[0]->{clearer}                }
 244 sub handles              { $_[0]->{handles}                }
 245
 246 sub _is_metadata         { $_[0]->{is}                     }
 247 sub is_required          { $_[0]->{required}               }
 248 sub default              { $_[0]->{default}                }
 249 sub is_lazy              { $_[0]->{lazy}                   }
 250 sub is_lazy_build        { $_[0]->{lazy_build}             }
 251 sub is_weak_ref          { $_[0]->{weak_ref}               }
 252 sub init_arg             { $_[0]->{init_arg}               }
 253 sub type_constraint      { $_[0]->{type_constraint}        }
 254
 255 sub trigger              { $_[0]->{trigger}                }
 256 sub builder              { $_[0]->{builder}                }
 257 sub should_auto_deref    { $_[0]->{auto_deref}             }
 258 sub should_coerce        { $_[0]->{coerce}                 }
 259
 260 sub documentation        { $_[0]->{documentation}          }
 261
 262 # predicates
 263
 264 sub has_accessor         { exists $_[0]->{accessor}        }
 265 sub has_reader           { exists $_[0]->{reader}          }
 266 sub has_writer           { exists $_[0]->{writer}          }
 267 sub has_predicate        { exists $_[0]->{predicate}       }
 268 sub has_clearer          { exists $_[0]->{clearer}         }
 269 sub has_handles          { exists $_[0]->{handles}         }
 270
 271 sub has_default          { exists $_[0]->{default}         }
 272 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 273 sub has_trigger          { exists $_[0]->{trigger}         }
 274 sub has_builder          { exists $_[0]->{builder}         }
 275
 276 sub has_documentation    { exists $_[0]->{documentation}   }
 277
 278 sub accessor_metaclass(){ 'Mouse::Meta::Method::Accessor' }
 279
 280 package
 281     Mouse::Meta::TypeConstraint;
 282
 283 sub name    { $_[0]->{name}    }
 284 sub parent  { $_[0]->{parent}  }
 285 sub message { $_[0]->{message} }
 286
 287 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 288
 289 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 290
 291 sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }
 292
 293
 294 sub compile_type_constraint{
 295     my($self) = @_;
 296
 297     # add parents first
 298     my @checks;
 299     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 300          if($parent->{hand_optimized_type_constraint}){
 301             unshift @checks, $parent->{hand_optimized_type_constraint};
 302             last; # a hand optimized constraint must include all the parents
 303         }
 304         elsif($parent->{constraint}){
 305             unshift @checks, $parent->{constraint};
 306         }
 307     }
 308
 309     # then add child
 310     if($self->{constraint}){
 311         push @checks, $self->{constraint};
 312     }
 313
 314     if($self->{type_constraints}){ # Union
 315         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 316         push @checks, sub{
 317             foreach my $c(@types){
 318                 return 1 if $c->($_[0]);
 319             }
 320             return 0;
 321         };
 322     }
 323
 324     if(@checks == 0){
 325         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 326     }
 327     else{
 328         $self->{compiled_type_constraint} =  sub{
 329             my(@args) = @_;
 330             local $_ = $args[0];
 331             foreach my $c(@checks){
 332                 return undef if !$c->(@args);
 333             }
 334             return 1;
 335         };
 336     }
 337     return;
 338 }
 339
 340 package
 341     Mouse::Object;
 342
 343
 344 sub BUILDARGS {
 345     my $class = shift;
 346
 347     if (scalar @_ == 1) {
 348         (ref($_[0]) eq 'HASH')
 349             || $class->meta->throw_error("Single parameters to new() must be a HASH ref");
 350
 351         return {%{$_[0]}};
 352     }
 353     else {
 354         return {@_};
 355     }
 356 }
 357
 358 1;
 359 __END__
 360
 361 =head1 NAME
 362
 363 Mouse::PurePerl - A Mouse guts in pure Perl
 364
 365 =head1 VERSION
 366
 367 This document describes Mouse version 0.40_05
 368
 369 =head1 SEE ALSO
 370
 371 L<Mouse::XS>
 372
 373 =cut