lib/Mouse/PurePerl.pm

   1 package Mouse::PurePerl;
   2
   3 require Mouse::Util;
   4
   5 package
   6     Mouse::Util;
   7
   8 use strict;
   9 use warnings;
  10
  11 use warnings FATAL => 'redefine'; # to avoid to load Mouse::PurePerl
  12
  13 use B ();
  14
  15 sub is_class_loaded {
  16     my $class = shift;
  17
  18     return 0 if ref($class) || !defined($class) || !length($class);
  19
  20     # walk the symbol table tree to avoid autovififying
  21     # \*{${main::}{"Foo::"}} == \*main::Foo::
  22
  23     my $pack = \%::;
  24     foreach my $part (split('::', $class)) {
  25         my $entry = \$pack->{$part . '::'};
  26         return 0 if ref($entry) ne 'GLOB';
  27         $pack = *{$entry}{HASH} or return 0;
  28     }
  29
  30     # check for $VERSION or @ISA
  31     return 1 if exists $pack->{VERSION}
  32              && defined *{$pack->{VERSION}}{SCALAR} && defined ${ $pack->{VERSION} };
  33     return 1 if exists $pack->{ISA}
  34              && defined *{$pack->{ISA}}{ARRAY} && @{ $pack->{ISA} } != 0;
  35
  36     # check for any method
  37     foreach my $name( keys %{$pack} ) {
  38         my $entry = \$pack->{$name};
  39         return 1 if ref($entry) ne 'GLOB' || defined *{$entry}{CODE};
  40     }
  41
  42     # fail
  43     return 0;
  44 }
  45
  46
  47 # taken from Sub::Identify
  48 sub get_code_info {
  49     my ($coderef) = @_;
  50     ref($coderef) or return;
  51
  52     my $cv = B::svref_2object($coderef);
  53     $cv->isa('B::CV') or return;
  54
  55     my $gv = $cv->GV;
  56     $gv->isa('B::GV') or return;
  57
  58     return ($gv->STASH->NAME, $gv->NAME);
  59 }
  60
  61 sub get_code_package{
  62     my($coderef) = @_;
  63
  64     my $cv = B::svref_2object($coderef);
  65     $cv->isa('B::CV') or return '';
  66
  67     my $gv = $cv->GV;
  68     $gv->isa('B::GV') or return '';
  69
  70     return $gv->STASH->NAME;
  71 }
  72
  73 sub get_code_ref{
  74     my($package, $name) = @_;
  75     no strict 'refs';
  76     no warnings 'once';
  77     use warnings FATAL => 'uninitialized';
  78     return *{$package . '::' . $name}{CODE};
  79 }
  80
  81 sub generate_isa_predicate_for {
  82     my($for_class, $name) = @_;
  83
  84     my $predicate = sub{ Scalar::Util::blessed($_[0]) && $_[0]->isa($for_class) };
  85
  86     if(defined $name){
  87         no strict 'refs';
  88         *{ caller() . '::' . $name } = $predicate;
  89         return;
  90     }
  91
  92     return $predicate;
  93 }
  94
  95
  96 package
  97     Mouse::Util::TypeConstraints;
  98
  99 use Scalar::Util qw(blessed looks_like_number openhandle);
 100
 101 sub Any        { 1 }
 102 sub Item       { 1 }
 103
 104 sub Bool       { $_[0] ? $_[0] eq '1' : 1 }
 105 sub Undef      { !defined($_[0]) }
 106 sub Defined    {  defined($_[0])  }
 107 sub Value      {  defined($_[0]) && !ref($_[0]) }
 108 sub Num        { !ref($_[0]) && looks_like_number($_[0]) }
 109 sub Int        {  defined($_[0]) && !ref($_[0]) && $_[0] =~ /^-?[0-9]+$/ }
 110 sub Str        {  defined($_[0]) && !ref($_[0]) }
 111
 112 sub Ref        { ref($_[0]) }
 113 sub ScalarRef  { ref($_[0]) eq 'SCALAR' }
 114 sub ArrayRef   { ref($_[0]) eq 'ARRAY'  }
 115 sub HashRef    { ref($_[0]) eq 'HASH'   }
 116 sub CodeRef    { ref($_[0]) eq 'CODE'   }
 117 sub RegexpRef  { ref($_[0]) eq 'Regexp' }
 118 sub GlobRef    { ref($_[0]) eq 'GLOB'   }
 119
 120 sub FileHandle {
 121     openhandle($_[0])  || (blessed($_[0]) && $_[0]->isa("IO::Handle"))
 122 }
 123
 124 sub Object     { blessed($_[0]) && blessed($_[0]) ne 'Regexp' }
 125
 126 sub ClassName  { Mouse::Util::is_class_loaded($_[0]) }
 127 sub RoleName   { (Mouse::Util::class_of($_[0]) || return 0)->isa('Mouse::Meta::Role') }
 128
 129 sub _parameterize_ArrayRef_for {
 130     my($type_parameter) = @_;
 131     my $check = $type_parameter->_compiled_type_constraint;
 132
 133     return sub {
 134         foreach my $value (@{$_}) {
 135             return undef unless $check->($value);
 136         }
 137         return 1;
 138     }
 139 }
 140
 141 sub _parameterize_HashRef_for {
 142     my($type_parameter) = @_;
 143     my $check = $type_parameter->_compiled_type_constraint;
 144
 145     return sub {
 146         foreach my $value(values %{$_}){
 147             return undef unless $check->($value);
 148         }
 149         return 1;
 150     };
 151 }
 152
 153 # 'Maybe' type accepts 'Any', so it requires parameters
 154 sub _parameterize_Maybe_for {
 155     my($type_parameter) = @_;
 156     my $check = $type_parameter->_compiled_type_constraint;
 157
 158     return sub{
 159         return !defined($_) || $check->($_);
 160     };
 161 };
 162
 163
 164
 165 package
 166     Mouse::Meta::Module;
 167
 168 sub name          { $_[0]->{package} }
 169
 170 sub _method_map   { $_[0]->{methods} }
 171 sub _attribute_map{ $_[0]->{attribute_map} }
 172
 173 sub namespace{
 174     my $name = $_[0]->{package};
 175     no strict 'refs';
 176     return \%{ $name . '::' };
 177 }
 178
 179 sub add_method {
 180     my($self, $name, $code) = @_;
 181
 182     if(!defined $name){
 183         $self->throw_error('You must pass a defined name');
 184     }
 185     if(!defined $code){
 186         $self->throw_error('You must pass a defined code');
 187     }
 188
 189     if(ref($code) ne 'CODE'){
 190         $code = \&{$code}; # coerce
 191     }
 192
 193     $self->{methods}->{$name} = $code; # Moose stores meta object here.
 194
 195     my $pkg = $self->name;
 196     no strict 'refs';
 197     no warnings 'redefine', 'once';
 198     *{ $pkg . '::' . $name } = $code;
 199     return;
 200 }
 201
 202
 203 package
 204     Mouse::Meta::Class;
 205
 206 sub is_anon_class{
 207     return exists $_[0]->{anon_serial_id};
 208 }
 209
 210 sub roles { $_[0]->{roles} }
 211
 212 sub linearized_isa { @{ get_linear_isa($_[0]->{package}) } }
 213
 214 package
 215     Mouse::Meta::Role;
 216
 217 sub is_anon_role{
 218     return exists $_[0]->{anon_serial_id};
 219 }
 220
 221 sub get_roles { $_[0]->{roles} }
 222
 223 package
 224     Mouse::Meta::Attribute;
 225
 226 use Mouse::Meta::Method::Accessor;
 227
 228 # readers
 229
 230 sub name                 { $_[0]->{name}                   }
 231 sub associated_class     { $_[0]->{associated_class}       }
 232
 233 sub accessor             { $_[0]->{accessor}               }
 234 sub reader               { $_[0]->{reader}                 }
 235 sub writer               { $_[0]->{writer}                 }
 236 sub predicate            { $_[0]->{predicate}              }
 237 sub clearer              { $_[0]->{clearer}                }
 238 sub handles              { $_[0]->{handles}                }
 239
 240 sub _is_metadata         { $_[0]->{is}                     }
 241 sub is_required          { $_[0]->{required}               }
 242 sub default              { $_[0]->{default}                }
 243 sub is_lazy              { $_[0]->{lazy}                   }
 244 sub is_lazy_build        { $_[0]->{lazy_build}             }
 245 sub is_weak_ref          { $_[0]->{weak_ref}               }
 246 sub init_arg             { $_[0]->{init_arg}               }
 247 sub type_constraint      { $_[0]->{type_constraint}        }
 248
 249 sub trigger              { $_[0]->{trigger}                }
 250 sub builder              { $_[0]->{builder}                }
 251 sub should_auto_deref    { $_[0]->{auto_deref}             }
 252 sub should_coerce        { $_[0]->{coerce}                 }
 253
 254 sub documentation        { $_[0]->{documentation}          }
 255
 256 # predicates
 257
 258 sub has_accessor         { exists $_[0]->{accessor}        }
 259 sub has_reader           { exists $_[0]->{reader}          }
 260 sub has_writer           { exists $_[0]->{writer}          }
 261 sub has_predicate        { exists $_[0]->{predicate}       }
 262 sub has_clearer          { exists $_[0]->{clearer}         }
 263 sub has_handles          { exists $_[0]->{handles}         }
 264
 265 sub has_default          { exists $_[0]->{default}         }
 266 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 267 sub has_trigger          { exists $_[0]->{trigger}         }
 268 sub has_builder          { exists $_[0]->{builder}         }
 269
 270 sub has_documentation    { exists $_[0]->{documentation}   }
 271
 272 sub accessor_metaclass(){ 'Mouse::Meta::Method::Accessor' }
 273
 274 package
 275     Mouse::Meta::TypeConstraint;
 276
 277 sub name    { $_[0]->{name}    }
 278 sub parent  { $_[0]->{parent}  }
 279 sub message { $_[0]->{message} }
 280
 281 sub _compiled_type_constraint{ $_[0]->{compiled_type_constraint} }
 282
 283 sub _compiled_type_coercion  { $_[0]->{_compiled_type_coercion}  }
 284
 285 sub has_coercion{ exists $_[0]->{_compiled_type_coercion} }
 286
 287
 288 sub compile_type_constraint{
 289     my($self) = @_;
 290
 291     # add parents first
 292     my @checks;
 293     for(my $parent = $self->{parent}; defined $parent; $parent = $parent->{parent}){
 294          if($parent->{hand_optimized_type_constraint}){
 295             unshift @checks, $parent->{hand_optimized_type_constraint};
 296             last; # a hand optimized constraint must include all the parents
 297         }
 298         elsif($parent->{constraint}){
 299             unshift @checks, $parent->{constraint};
 300         }
 301     }
 302
 303     # then add child
 304     if($self->{constraint}){
 305         push @checks, $self->{constraint};
 306     }
 307
 308     if($self->{type_constraints}){ # Union
 309         my @types = map{ $_->{compiled_type_constraint} } @{ $self->{type_constraints} };
 310         push @checks, sub{
 311             foreach my $c(@types){
 312                 return 1 if $c->($_[0]);
 313             }
 314             return 0;
 315         };
 316     }
 317
 318     if(@checks == 0){
 319         $self->{compiled_type_constraint} = \&Mouse::Util::TypeConstraints::Any;
 320     }
 321     else{
 322         $self->{compiled_type_constraint} =  sub{
 323             my(@args) = @_;
 324             local $_ = $args[0];
 325             foreach my $c(@checks){
 326                 return undef if !$c->(@args);
 327             }
 328             return 1;
 329         };
 330     }
 331     return;
 332 }
 333
 334
 335
 336 1;
 337 __END__
 338
 339 =head1 NAME
 340
 341 Mouse::PurePerl - A Mouse guts in pure Perl
 342
 343 =head1 VERSION
 344
 345 This document describes Mouse version 0.40_05
 346
 347 =head1 SEE ALSO
 348
 349 L<Mouse::XS>
 350
 351 =cut