lib/Mouse/Object.pm

   1 package Mouse::Object;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util 'weaken';
   6 use Carp 'confess';
   7
   8 sub new {
   9     my $class = shift;
  10
  11     my $args = $class->BUILDARGS(@_);
  12
  13     my $instance = bless {}, $class;
  14
  15     for my $attribute ($class->meta->compute_all_applicable_attributes) {
  16         my $from = $attribute->init_arg;
  17         my $key  = $attribute->name;
  18
  19         if (defined($from) && exists($args->{$from})) {
  20             $args->{$from} = $attribute->coerce_constraint($args->{$from})
  21                 if $attribute->should_coerce;
  22             $attribute->verify_against_type_constraint($args->{$from});
  23
  24             $instance->{$key} = $args->{$from};
  25
  26             weaken($instance->{$key})
  27                 if ref($instance->{$key}) && $attribute->is_weak_ref;
  28
  29             if ($attribute->has_trigger) {
  30                 $attribute->trigger->($instance, $args->{$from}, $attribute);
  31             }
  32         }
  33         else {
  34             if ($attribute->has_default || $attribute->has_builder) {
  35                 unless ($attribute->is_lazy) {
  36                     my $default = $attribute->default;
  37                     my $builder = $attribute->builder;
  38                     my $value = $attribute->has_builder
  39                               ? $instance->$builder
  40                               : ref($default) eq 'CODE'
  41                                   ? $default->($instance)
  42                                   : $default;
  43
  44                     $value = $attribute->coerce_constraint($value)
  45                         if $attribute->should_coerce;
  46                     $attribute->verify_against_type_constraint($value);
  47
  48                     $instance->{$key} = $value;
  49
  50                     weaken($instance->{$key})
  51                         if ref($instance->{$key}) && $attribute->is_weak_ref;
  52                 }
  53             }
  54             else {
  55                 if ($attribute->is_required) {
  56                     confess "Attribute (".$attribute->name.") is required";
  57                 }
  58             }
  59         }
  60     }
  61
  62     $instance->BUILDALL($args);
  63
  64     return $instance;
  65 }
  66
  67 sub BUILDARGS {
  68     my $class = shift;
  69
  70     if (scalar @_ == 1) {
  71         if (defined $_[0]) {
  72             (ref($_[0]) eq 'HASH')
  73                 || confess "Single parameters to new() must be a HASH ref";
  74             return {%{$_[0]}};
  75         } else {
  76             return {};
  77         }
  78     }
  79     else {
  80         return {@_};
  81     }
  82 }
  83
  84 sub DESTROY { shift->DEMOLISHALL }
  85
  86 sub BUILDALL {
  87     my $self = shift;
  88
  89     # short circuit
  90     return unless $self->can('BUILD');
  91
  92     for my $class (reverse $self->meta->linearized_isa) {
  93         no strict 'refs';
  94         no warnings 'once';
  95         my $code = *{ $class . '::BUILD' }{CODE}
  96             or next;
  97         $code->($self, @_);
  98     }
  99 }
 100
 101 sub DEMOLISHALL {
 102     my $self = shift;
 103
 104     # short circuit
 105     return unless $self->can('DEMOLISH');
 106
 107     no strict 'refs';
 108
 109     for my $class ($self->meta->linearized_isa) {
 110         my $code = *{ $class . '::DEMOLISH' }{CODE}
 111             or next;
 112         $code->($self, @_);
 113     }
 114 }
 115
 116 sub dump {
 117     my $self = shift;
 118     require Data::Dumper;
 119     local $Data::Dumper::Maxdepth = shift if @_;
 120     Data::Dumper::Dumper $self;
 121 }
 122
 123 1;
 124
 125 __END__
 126
 127 =head1 NAME
 128
 129 Mouse::Object - we don't need to steenkin' constructor
 130
 131 =head1 METHODS
 132
 133 =head2 new arguments -> object
 134
 135 Instantiates a new Mouse::Object. This is obviously intended for subclasses.
 136
 137 =head2 BUILDALL \%args
 138
 139 Calls L</BUILD> on each class in the class hierarchy. This is called at the
 140 end of L</new>.
 141
 142 =head2 BUILD \%args
 143
 144 You may put any business logic initialization in BUILD methods. You don't
 145 need to redispatch or return any specific value.
 146
 147 =head2 BUILDARGS
 148
 149 Lets you override the arguments that C<new> takes. Return a hashref of
 150 parameters.
 151
 152 =head2 DEMOLISHALL
 153
 154 Calls L</DEMOLISH> on each class in the class hierarchy. This is called at
 155 L</DESTROY> time.
 156
 157 =head2 DEMOLISH
 158
 159 You may put any business logic deinitialization in DEMOLISH methods. You don't
 160 need to redispatch or return any specific value.
 161
 162
 163 =head2 B<dump ($maxdepth)>
 164
 165 From the Moose POD:
 166
 167     C'mon, how many times have you written the following code while debugging:
 168
 169      use Data::Dumper;
 170      warn Dumper $obj;
 171
 172     It can get seriously annoying, so why not just use this.
 173
 174 The implementation was lifted directly from Moose::Object.
 175
 176 =cut
 177
 178