lib/Mouse/Object.pm

   1 package Mouse::Object;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util 'weaken';
   6 use Carp 'confess';
   7
   8 sub new {
   9     my $class = shift;
  10
  11     my $args = $class->BUILDARGS(@_);
  12
  13     my $instance = bless {}, $class;
  14
  15     for my $attribute ($class->meta->get_all_attributes) {
  16         my $from = $attribute->init_arg;
  17         my $key  = $attribute->name;
  18
  19         if (defined($from) && exists($args->{$from})) {
  20             $args->{$from} = $attribute->coerce_constraint($args->{$from})
  21                 if $attribute->should_coerce;
  22             $attribute->verify_against_type_constraint($args->{$from});
  23
  24             $instance->{$key} = $args->{$from};
  25
  26             weaken($instance->{$key})
  27                 if ref($instance->{$key}) && $attribute->is_weak_ref;
  28
  29             if ($attribute->has_trigger) {
  30                 $attribute->trigger->($instance, $args->{$from});
  31             }
  32         }
  33         else {
  34             if ($attribute->has_default || $attribute->has_builder) {
  35                 unless ($attribute->is_lazy) {
  36                     my $default = $attribute->default;
  37                     my $builder = $attribute->builder;
  38                     my $value = $attribute->has_builder
  39                               ? $instance->$builder
  40                               : ref($default) eq 'CODE'
  41                                   ? $default->($instance)
  42                                   : $default;
  43
  44                     $value = $attribute->coerce_constraint($value)
  45                         if $attribute->should_coerce;
  46                     $attribute->verify_against_type_constraint($value);
  47
  48                     $instance->{$key} = $value;
  49
  50                     weaken($instance->{$key})
  51                         if ref($instance->{$key}) && $attribute->is_weak_ref;
  52                 }
  53             }
  54             else {
  55                 if ($attribute->is_required) {
  56                     confess "Attribute (".$attribute->name.") is required";
  57                 }
  58             }
  59         }
  60     }
  61
  62     $instance->BUILDALL($args);
  63
  64     return $instance;
  65 }
  66
  67 sub BUILDARGS {
  68     my $class = shift;
  69
  70     if (scalar @_ == 1) {
  71         (ref($_[0]) eq 'HASH')
  72             || confess "Single parameters to new() must be a HASH ref";
  73         return {%{$_[0]}};
  74     }
  75     else {
  76         return {@_};
  77     }
  78 }
  79
  80 sub DESTROY { shift->DEMOLISHALL }
  81
  82 sub BUILDALL {
  83     my $self = shift;
  84
  85     # short circuit
  86     return unless $self->can('BUILD');
  87
  88     for my $class (reverse $self->meta->linearized_isa) {
  89         no strict 'refs';
  90         no warnings 'once';
  91         my $code = *{ $class . '::BUILD' }{CODE}
  92             or next;
  93         $code->($self, @_);
  94     }
  95 }
  96
  97 sub DEMOLISHALL {
  98     my $self = shift;
  99
 100     # short circuit
 101     return unless $self->can('DEMOLISH');
 102
 103     no strict 'refs';
 104
 105     my @isa;
 106     if ( my $meta = Mouse::class_of($self) ) {
 107         @isa = $meta->linearized_isa;
 108     } else {
 109         # We cannot count on being able to retrieve a previously made
 110         # metaclass, _or_ being able to make a new one during global
 111         # destruction. However, we should still be able to use mro at
 112         # that time (at least tests suggest so ;)
 113         my $class_name = ref $self;
 114         @isa = @{ Mouse::Util::get_linear_isa($class_name) }
 115     }
 116
 117     foreach my $class (@isa) {
 118         no strict 'refs';
 119         my $demolish = *{"${class}::DEMOLISH"}{CODE};
 120         $self->$demolish
 121             if defined $demolish;
 122     }
 123 }
 124
 125 sub dump {
 126     my $self = shift;
 127     require Data::Dumper;
 128     local $Data::Dumper::Maxdepth = shift if @_;
 129     Data::Dumper::Dumper $self;
 130 }
 131
 132
 133 sub does {
 134     my ($self, $role_name) = @_;
 135     (defined $role_name)
 136         || confess "You must supply a role name to does()";
 137     my $meta = $self->meta;
 138     foreach my $class ($meta->linearized_isa) {
 139         my $m = $meta->initialize($class);
 140         return 1
 141             if $m->can('does_role') && $m->does_role($role_name);
 142     }
 143     return 0;
 144 };
 145
 146 1;
 147
 148 __END__
 149
 150 =head1 NAME
 151
 152 Mouse::Object - we don't need to steenkin' constructor
 153
 154 =head1 METHODS
 155
 156 =head2 new arguments -> object
 157
 158 Instantiates a new Mouse::Object. This is obviously intended for subclasses.
 159
 160 =head2 BUILDALL \%args
 161
 162 Calls L</BUILD> on each class in the class hierarchy. This is called at the
 163 end of L</new>.
 164
 165 =head2 BUILD \%args
 166
 167 You may put any business logic initialization in BUILD methods. You don't
 168 need to redispatch or return any specific value.
 169
 170 =head2 BUILDARGS
 171
 172 Lets you override the arguments that C<new> takes. Return a hashref of
 173 parameters.
 174
 175 =head2 DEMOLISHALL
 176
 177 Calls L</DEMOLISH> on each class in the class hierarchy. This is called at
 178 L</DESTROY> time.
 179
 180 =head2 DEMOLISH
 181
 182 You may put any business logic deinitialization in DEMOLISH methods. You don't
 183 need to redispatch or return any specific value.
 184
 185
 186 =head2 does $role_name
 187
 188 This will check if the invocant's class "does" a given C<$role_name>.
 189 This is similar to "isa" for object, but it checks the roles instead.
 190
 191
 192 =head2 B<dump ($maxdepth)>
 193
 194 From the Moose POD:
 195
 196     C'mon, how many times have you written the following code while debugging:
 197
 198      use Data::Dumper;
 199      warn Dumper $obj;
 200
 201     It can get seriously annoying, so why not just use this.
 202
 203 The implementation was lifted directly from Moose::Object.
 204
 205 =cut
 206
 207