lib/Mouse/Object.pm

   1 package Mouse::Object;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util 'weaken';
   6 use Carp 'confess';
   7
   8 sub new {
   9     my $class = shift;
  10
  11     my $args = $class->BUILDARGS(@_);
  12
  13     my $instance = bless {}, $class;
  14
  15     for my $attribute ($class->meta->get_all_attributes) {
  16         my $from = $attribute->init_arg;
  17         my $key  = $attribute->name;
  18
  19         if (defined($from) && exists($args->{$from})) {
  20             $args->{$from} = $attribute->coerce_constraint($args->{$from})
  21                 if $attribute->should_coerce;
  22             $attribute->verify_against_type_constraint($args->{$from});
  23
  24             $instance->{$key} = $args->{$from};
  25
  26             weaken($instance->{$key})
  27                 if ref($instance->{$key}) && $attribute->is_weak_ref;
  28
  29             if ($attribute->has_trigger) {
  30                 $attribute->trigger->($instance, $args->{$from});
  31             }
  32         }
  33         else {
  34             if ($attribute->has_default || $attribute->has_builder) {
  35                 unless ($attribute->is_lazy) {
  36                     my $default = $attribute->default;
  37                     my $builder = $attribute->builder;
  38                     my $value = $attribute->has_builder
  39                               ? $instance->$builder
  40                               : ref($default) eq 'CODE'
  41                                   ? $default->($instance)
  42                                   : $default;
  43
  44                     $value = $attribute->coerce_constraint($value)
  45                         if $attribute->should_coerce;
  46                     $attribute->verify_against_type_constraint($value);
  47
  48                     $instance->{$key} = $value;
  49
  50                     weaken($instance->{$key})
  51                         if ref($instance->{$key}) && $attribute->is_weak_ref;
  52                 }
  53             }
  54             else {
  55                 if ($attribute->is_required) {
  56                     confess "Attribute (".$attribute->name.") is required";
  57                 }
  58             }
  59         }
  60     }
  61
  62     $instance->BUILDALL($args);
  63
  64     return $instance;
  65 }
  66
  67 sub BUILDARGS {
  68     my $class = shift;
  69
  70     if (scalar @_ == 1) {
  71         (ref($_[0]) eq 'HASH')
  72             || confess "Single parameters to new() must be a HASH ref";
  73         return {%{$_[0]}};
  74     }
  75     else {
  76         return {@_};
  77     }
  78 }
  79
  80 sub DESTROY { shift->DEMOLISHALL }
  81
  82 sub BUILDALL {
  83     my $self = shift;
  84
  85     # short circuit
  86     return unless $self->can('BUILD');
  87
  88     for my $class (reverse $self->meta->linearized_isa) {
  89         no strict 'refs';
  90         no warnings 'once';
  91         my $code = *{ $class . '::BUILD' }{CODE}
  92             or next;
  93         $code->($self, @_);
  94     }
  95     return;
  96 }
  97
  98 sub DEMOLISHALL {
  99     my $self = shift;
 100
 101     # short circuit
 102     return unless $self->can('DEMOLISH');
 103
 104     no strict 'refs';
 105
 106     my @isa;
 107     if ( my $meta = Mouse::Meta::Class::class_of($self) ) {
 108         @isa = $meta->linearized_isa;
 109     } else {
 110         # We cannot count on being able to retrieve a previously made
 111         # metaclass, _or_ being able to make a new one during global
 112         # destruction. However, we should still be able to use mro at
 113         # that time (at least tests suggest so ;)
 114         my $class_name = ref $self;
 115         @isa = @{ Mouse::Util::get_linear_isa($class_name) }
 116     }
 117
 118     foreach my $class (@isa) {
 119         no strict 'refs';
 120         my $demolish = *{"${class}::DEMOLISH"}{CODE};
 121         $self->$demolish
 122             if defined $demolish;
 123     }
 124     return;
 125 }
 126
 127 sub dump {
 128     my $self = shift;
 129     require Data::Dumper;
 130     local $Data::Dumper::Maxdepth = shift if @_;
 131     Data::Dumper::Dumper($self);
 132 }
 133
 134
 135 sub does {
 136     my ($self, $role_name) = @_;
 137     (defined $role_name)
 138         || confess "You must supply a role name to does()";
 139
 140     my $meta = $self->meta;
 141     foreach my $class ($meta->linearized_isa) {
 142         my $m = ref($meta)->initialize($class);
 143         return 1
 144             if $m->can('does_role') && $m->does_role($role_name);
 145     }
 146     return 0;
 147 };
 148
 149 1;
 150
 151 __END__
 152
 153 =head1 NAME
 154
 155 Mouse::Object - we don't need to steenkin' constructor
 156
 157 =head1 METHODS
 158
 159 =head2 new arguments -> object
 160
 161 Instantiates a new Mouse::Object. This is obviously intended for subclasses.
 162
 163 =head2 BUILDALL \%args
 164
 165 Calls L</BUILD> on each class in the class hierarchy. This is called at the
 166 end of L</new>.
 167
 168 =head2 BUILD \%args
 169
 170 You may put any business logic initialization in BUILD methods. You don't
 171 need to redispatch or return any specific value.
 172
 173 =head2 BUILDARGS
 174
 175 Lets you override the arguments that C<new> takes. Return a hashref of
 176 parameters.
 177
 178 =head2 DEMOLISHALL
 179
 180 Calls L</DEMOLISH> on each class in the class hierarchy. This is called at
 181 L</DESTROY> time.
 182
 183 =head2 DEMOLISH
 184
 185 You may put any business logic deinitialization in DEMOLISH methods. You don't
 186 need to redispatch or return any specific value.
 187
 188
 189 =head2 does $role_name
 190
 191 This will check if the invocant's class "does" a given C<$role_name>.
 192 This is similar to "isa" for object, but it checks the roles instead.
 193
 194
 195 =head2 B<dump ($maxdepth)>
 196
 197 From the Moose POD:
 198
 199     C'mon, how many times have you written the following code while debugging:
 200
 201      use Data::Dumper;
 202      warn Dumper $obj;
 203
 204     It can get seriously annoying, so why not just use this.
 205
 206 The implementation was lifted directly from Moose::Object.
 207
 208 =cut
 209
 210