lib/Mouse/Meta/TypeConstraint.pm

   1 package Mouse::Meta::TypeConstraint;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 sub new {
   5     my $class = shift;
   6     my %args  = @_ == 1 ? %{$_[0]} : @_;
   7
   8     $args{name} = '__ANON__' if !defined $args{name};
   9
  10     if($args{parent}) {
  11         %args = (%{$args{parent}}, %args);
  12         # a child type must not inherit 'compiled_type_constraint'
  13         # and 'hand_optimized_type_constraint' from the parent
  14         delete $args{compiled_type_constraint};
  15         delete $args{hand_optimized_type_constraint};
  16     }
  17
  18     my $check;
  19
  20     if($check = delete $args{optimized}) {
  21         $args{hand_optimized_type_constraint} = $check;
  22         $args{compiled_type_constraint}       = $check;
  23     }
  24     elsif(my $param = $args{type_parameter}) {
  25         my $generator = $args{constraint_generator}
  26             || $class->throw_error("The $args{name} constraint cannot be used,"
  27                 . " because $param doesn't subtype from a parameterizable type");
  28         # it must be 'constraint'
  29         $check = $args{constraint} = $generator->($param);
  30     }
  31     else {
  32         $check = $args{constraint};
  33     }
  34
  35     if(defined($check) && ref($check) ne 'CODE'){
  36         $class->throw_error(
  37             "Constraint for $args{name} is not a CODE reference");
  38     }
  39
  40     my $self = bless \%args, $class;
  41     $self->compile_type_constraint()
  42         if !$args{hand_optimized_type_constraint};
  43
  44     if($args{type_constraints}) {
  45         $self->_compile_union_type_coercion();
  46     }
  47     return $self;
  48 }
  49
  50 sub create_child_type {
  51     my $self = shift;
  52     return ref($self)->new(@_, parent => $self);
  53 }
  54
  55 sub name;
  56 sub parent;
  57 sub message;
  58 sub has_coercion;
  59
  60 sub check;
  61
  62 sub type_parameter;
  63 sub __is_parameterized;
  64
  65 sub _compiled_type_constraint;
  66 sub _compiled_type_coercion;
  67
  68 sub compile_type_constraint;
  69
  70
  71 sub _add_type_coercions { # ($self, @pairs)
  72     my $self = shift;
  73
  74     my $coercions = ($self->{coercion_map} ||= []);
  75     my %has       = map{ $_->[0] => undef } @{$coercions};
  76
  77     for(my $i = 0; $i < @_; $i++){
  78         my $from   = $_[  $i];
  79         my $action = $_[++$i];
  80
  81         if(exists $has{$from}){
  82             $self->throw_error("A coercion action already exists for '$from'");
  83         }
  84
  85         my $type = Mouse::Util::TypeConstraints::find_or_parse_type_constraint($from)
  86             or $self->throw_error(
  87                 "Could not find the type constraint ($from) to coerce from");
  88
  89         push @{$coercions}, [ $type => $action ];
  90     }
  91
  92     # compile
  93     if(exists $self->{type_constraints}){ # union type
  94         $self->throw_error(
  95             "Cannot add additional type coercions to Union types");
  96     }
  97     else{
  98         $self->_compile_type_coercion();
  99     }
 100     return;
 101 }
 102
 103 sub _compile_type_coercion {
 104     my($self) = @_;
 105
 106     my @coercions = @{$self->{coercion_map}};
 107
 108     $self->{_compiled_type_coercion} = sub {
 109        my($thing) = @_;
 110        foreach my $pair (@coercions) {
 111             #my ($constraint, $converter) = @$pair;
 112             if ($pair->[0]->check($thing)) {
 113               local $_ = $thing;
 114               return $pair->[1]->($thing);
 115             }
 116        }
 117        return $thing;
 118     };
 119     return;
 120 }
 121
 122 sub _compile_union_type_coercion {
 123     my($self) = @_;
 124
 125     my @coercions;
 126     foreach my $type(@{$self->{type_constraints}}){
 127         if($type->has_coercion){
 128             push @coercions, $type;
 129         }
 130     }
 131     if(@coercions){
 132         $self->{_compiled_type_coercion} = sub {
 133             my($thing) = @_;
 134             foreach my $type(@coercions){
 135                 my $value = $type->coerce($thing);
 136                 return $value if $self->check($value);
 137             }
 138             return $thing;
 139         };
 140     }
 141     return;
 142 }
 143
 144 sub coerce {
 145     my $self = shift;
 146
 147     my $coercion = $self->_compiled_type_coercion;
 148     if(!$coercion){
 149         $self->throw_error("Cannot coerce without a type coercion");
 150     }
 151
 152     return $_[0] if $self->check(@_);
 153
 154     return  $coercion->(@_);
 155 }
 156
 157 sub get_message {
 158     my ($self, $value) = @_;
 159     if ( my $msg = $self->message ) {
 160         local $_ = $value;
 161         return $msg->($value);
 162     }
 163     else {
 164         if(not defined $value) {
 165             $value = 'undef';
 166         }
 167         elsif( ref($value) && defined(&overload::StrVal) ) {
 168             $value = overload::StrVal($value);
 169         }
 170         return "Validation failed for '$self' with value $value";
 171     }
 172 }
 173
 174 sub is_a_type_of{
 175     my($self, $other) = @_;
 176
 177     # ->is_a_type_of('__ANON__') is always false
 178     return 0 if !ref($other) && $other eq '__ANON__';
 179
 180     (my $other_name = $other) =~ s/\s+//g;
 181
 182     return 1 if $self->name eq $other_name;
 183
 184     if(exists $self->{type_constraints}){ # union
 185         foreach my $type(@{$self->{type_constraints}}) {
 186             return 1 if $type->name eq $other_name;
 187         }
 188     }
 189
 190     for(my $p = $self->parent; defined $p; $p = $p->parent) {
 191         return 1 if $p->name eq $other_name;
 192     }
 193
 194     return 0;
 195 }
 196
 197 # See also Moose::Meta::TypeConstraint::Parameterizable
 198 sub parameterize{
 199     my($self, $param, $name) = @_;
 200
 201     if(!ref $param){
 202         require Mouse::Util::TypeConstraints;
 203         $param = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($param);
 204     }
 205
 206     $name ||= sprintf '%s[%s]', $self->name, $param->name;
 207     return Mouse::Meta::TypeConstraint->new(
 208         name           => $name,
 209         parent         => $self,
 210         type_parameter => $param,
 211     );
 212 }
 213
 214 sub assert_valid {
 215     my ($self, $value) = @_;
 216
 217     if(!$self->check($value)){
 218         $self->throw_error($self->get_message($value));
 219     }
 220     return 1;
 221 }
 222
 223 sub _as_string { $_[0]->name                  } # overload ""
 224 sub _identity;                                  # overload 0+
 225
 226 sub _unite { # overload infix:<|>
 227     my($lhs, $rhs) = @_;
 228     require Mouse::Util::TypeConstraints;
 229     return Mouse::Util::TypeConstraints::find_or_parse_type_constraint(
 230        " $lhs | $rhs",
 231     );
 232 }
 233
 234 1;
 235 __END__
 236
 237 =head1 NAME
 238
 239 Mouse::Meta::TypeConstraint - The Mouse Type Constraint metaclass
 240
 241 =head1 VERSION
 242
 243 This document describes Mouse version 0.73
 244
 245 =head1 DESCRIPTION
 246
 247 This class represents a type constraint, including built-in
 248 type constraints, union type constraints, parameterizable/
 249 parameterized type constraints, as well as custom type
 250 constraints
 251
 252 =head1 METHODS
 253
 254 =over
 255
 256 =item C<< Mouse::Meta::TypeConstraint->new(%options) >>
 257
 258 =item C<< $constraint->name >>
 259
 260 =item C<< $constraint->parent >>
 261
 262 =item C<< $constraint->constraint >>
 263
 264 =item C<< $constraint->has_coercion >>
 265
 266 =item C<< $constraint->message >>
 267
 268 =item C<< $constraint->is_a_subtype_of($name or $object) >>
 269
 270 =item C<< $constraint->coerce($value) >>
 271
 272 =item C<< $constraint->check($value) >>
 273
 274 =item C<< $constraint->assert_valid($value) >>
 275
 276 =item C<< $constraint->get_message($value) >>
 277
 278 =item C<< $constraint->create_child_type(%options) >>
 279
 280 =back
 281
 282 =head1 SEE ALSO
 283
 284 L<Moose::Meta::TypeConstraint>
 285
 286 =cut
 287