lib/Mouse/Meta/TypeConstraint.pm

   1 package Mouse::Meta::TypeConstraint;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 sub new {
   5     my $class = shift;
   6     my %args  = @_ == 1 ? %{$_[0]} : @_;
   7
   8     $args{name} = '__ANON__' if !defined $args{name};
   9
  10     if(defined $args{parent}) {
  11         %args = (%{$args{parent}}, %args);
  12         # a child type must not inherit 'compiled_type_constraint'
  13         # and 'hand_optimized_type_constraint' from the parent
  14         delete $args{compiled_type_constraint};
  15         delete $args{hand_optimized_type_constraint};
  16     }
  17
  18     my $check;
  19
  20     if($check = delete $args{optimized}) {
  21         $args{hand_optimized_type_constraint} = $check;
  22         $args{compiled_type_constraint}       = $check;
  23     }
  24     elsif(my $param = $args{type_parameter}) {
  25         my $generator = $args{constraint_generator}
  26             || $class->throw_error("The $args{name} constraint cannot be used,"
  27                 . " because $param doesn't subtype from a parameterizable type");
  28         # it must be 'constraint'
  29         $check = $args{constraint} = $generator->($param);
  30     }
  31     else {
  32         $check = $args{constraint};
  33     }
  34
  35     if(defined($check) && ref($check) ne 'CODE'){
  36         $class->throw_error(
  37             "Constraint for $args{name} is not a CODE reference");
  38     }
  39
  40     my $self = bless \%args, $class;
  41     $self->compile_type_constraint()
  42         if !$args{hand_optimized_type_constraint};
  43
  44     if($args{type_constraints}) {
  45         $self->_compile_union_type_coercion();
  46     }
  47     return $self;
  48 }
  49
  50 sub create_child_type {
  51     my $self = shift;
  52     return ref($self)->new(@_, parent => $self);
  53 }
  54
  55 sub name;
  56 sub parent;
  57 sub message;
  58 sub has_coercion;
  59
  60 sub check;
  61
  62 sub type_parameter;
  63 sub __is_parameterized;
  64
  65 sub _compiled_type_constraint;
  66 sub _compiled_type_coercion;
  67
  68 sub compile_type_constraint;
  69
  70
  71 sub _add_type_coercions { # ($self, @pairs)
  72     my $self = shift;
  73
  74     if(exists $self->{type_constraints}){ # union type
  75         $self->throw_error(
  76             "Cannot add additional type coercions to Union types '$self'");
  77     }
  78
  79     my $coercions = ($self->{coercion_map} ||= []);
  80     my %has       = map{ $_->[0] => undef } @{$coercions};
  81
  82     for(my $i = 0; $i < @_; $i++){
  83         my $from   = $_[  $i];
  84         my $action = $_[++$i];
  85
  86         if(exists $has{$from}){
  87             $self->throw_error("A coercion action already exists for '$from'");
  88         }
  89
  90         my $type = Mouse::Util::TypeConstraints::find_or_parse_type_constraint($from)
  91             or $self->throw_error(
  92                 "Could not find the type constraint ($from) to coerce from");
  93
  94         push @{$coercions}, [ $type => $action ];
  95     }
  96
  97     $self->_compile_type_coercion();
  98     return;
  99 }
 100
 101 sub _compile_type_coercion {
 102     my($self) = @_;
 103
 104     my @coercions = @{$self->{coercion_map}};
 105
 106     $self->{_compiled_type_coercion} = sub {
 107        my($thing) = @_;
 108        foreach my $pair (@coercions) {
 109             #my ($constraint, $converter) = @$pair;
 110             if ($pair->[0]->check($thing)) {
 111               local $_ = $thing;
 112               return $pair->[1]->($thing);
 113             }
 114        }
 115        return $thing;
 116     };
 117     return;
 118 }
 119
 120 sub _compile_union_type_coercion {
 121     my($self) = @_;
 122
 123     my @coercions;
 124     foreach my $type(@{$self->{type_constraints}}){
 125         if($type->has_coercion){
 126             push @coercions, $type;
 127         }
 128     }
 129     if(@coercions){
 130         $self->{_compiled_type_coercion} = sub {
 131             my($thing) = @_;
 132             foreach my $type(@coercions){
 133                 my $value = $type->coerce($thing);
 134                 return $value if $self->check($value);
 135             }
 136             return $thing;
 137         };
 138     }
 139     return;
 140 }
 141
 142 sub coerce {
 143     my $self = shift;
 144     return $_[0] if $self->check(@_);
 145
 146     my $coercion = $self->{_compiled_type_coercion}
 147         or $self->throw_error("Cannot coerce without a type coercion");
 148     return  $coercion->(@_);
 149 }
 150
 151 sub get_message {
 152     my ($self, $value) = @_;
 153     if ( my $msg = $self->message ) {
 154         local $_ = $value;
 155         return $msg->($value);
 156     }
 157     else {
 158         if(not defined $value) {
 159             $value = 'undef';
 160         }
 161         elsif( ref($value) && defined(&overload::StrVal) ) {
 162             $value = overload::StrVal($value);
 163         }
 164         return "Validation failed for '$self' with value $value";
 165     }
 166 }
 167
 168 sub is_a_type_of {
 169     my($self, $other) = @_;
 170
 171     # ->is_a_type_of('__ANON__') is always false
 172     return 0 if !ref($other) && $other eq '__ANON__';
 173
 174     (my $other_name = $other) =~ s/\s+//g;
 175
 176     return 1 if $self->name eq $other_name;
 177
 178     if(exists $self->{type_constraints}){ # union
 179         foreach my $type(@{$self->{type_constraints}}) {
 180             return 1 if $type->name eq $other_name;
 181         }
 182     }
 183
 184     for(my $p = $self->parent; defined $p; $p = $p->parent) {
 185         return 1 if $p->name eq $other_name;
 186     }
 187
 188     return 0;
 189 }
 190
 191 # See also Moose::Meta::TypeConstraint::Parameterizable
 192 sub parameterize{
 193     my($self, $param, $name) = @_;
 194
 195     if(!ref $param){
 196         require Mouse::Util::TypeConstraints;
 197         $param = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($param);
 198     }
 199
 200     $name ||= sprintf '%s[%s]', $self->name, $param->name;
 201     return Mouse::Meta::TypeConstraint->new(
 202         name           => $name,
 203         parent         => $self,
 204         type_parameter => $param,
 205     );
 206 }
 207
 208 sub assert_valid {
 209     my ($self, $value) = @_;
 210
 211     if(!$self->check($value)){
 212         $self->throw_error($self->get_message($value));
 213     }
 214     return 1;
 215 }
 216
 217 sub _as_string { $_[0]->name                  } # overload ""
 218 sub _identity;                                  # overload 0+
 219
 220 sub _unite { # overload infix:<|>
 221     my($lhs, $rhs) = @_;
 222     require Mouse::Util::TypeConstraints;
 223     return Mouse::Util::TypeConstraints::find_or_parse_type_constraint(
 224        " $lhs | $rhs",
 225     );
 226 }
 227
 228 1;
 229 __END__
 230
 231 =head1 NAME
 232
 233 Mouse::Meta::TypeConstraint - The Mouse Type Constraint metaclass
 234
 235 =head1 VERSION
 236
 237 This document describes Mouse version 0.76
 238
 239 =head1 DESCRIPTION
 240
 241 This class represents a type constraint, including built-in
 242 type constraints, union type constraints, parameterizable/
 243 parameterized type constraints, as well as custom type
 244 constraints
 245
 246 =head1 METHODS
 247
 248 =over
 249
 250 =item C<< Mouse::Meta::TypeConstraint->new(%options) >>
 251
 252 =item C<< $constraint->name >>
 253
 254 =item C<< $constraint->parent >>
 255
 256 =item C<< $constraint->constraint >>
 257
 258 =item C<< $constraint->has_coercion >>
 259
 260 =item C<< $constraint->message >>
 261
 262 =item C<< $constraint->is_a_subtype_of($name or $object) >>
 263
 264 =item C<< $constraint->coerce($value) >>
 265
 266 =item C<< $constraint->check($value) >>
 267
 268 =item C<< $constraint->assert_valid($value) >>
 269
 270 =item C<< $constraint->get_message($value) >>
 271
 272 =item C<< $constraint->create_child_type(%options) >>
 273
 274 =back
 275
 276 =head1 SEE ALSO
 277
 278 L<Moose::Meta::TypeConstraint>
 279
 280 =cut
 281