lib/Mouse/Meta/Role.pm

   1 package Mouse::Meta::Role;
   2 use Mouse::Util qw(:meta not_supported english_list); # enables strict and warnings
   3
   4 use Mouse::Meta::Module;
   5 our @ISA = qw(Mouse::Meta::Module);
   6
   7 sub method_metaclass(){ 'Mouse::Meta::Role::Method' } # required for get_method()
   8
   9 sub _construct_meta {
  10     my $class = shift;
  11
  12     my %args  = @_;
  13
  14     $args{methods}          ||= {};
  15     $args{attributes}       ||= {};
  16     $args{required_methods} ||= [];
  17     $args{roles}            ||= [];
  18
  19     my $self = bless \%args, ref($class) || $class;
  20     if($class ne __PACKAGE__){
  21         $self->meta->_initialize_object($self, \%args);
  22     }
  23
  24     return $self;
  25 }
  26
  27 sub create_anon_role{
  28     my $self = shift;
  29     return $self->create(undef, @_);
  30 }
  31
  32 sub is_anon_role{
  33     return exists $_[0]->{anon_serial_id};
  34 }
  35
  36 sub get_roles { $_[0]->{roles} }
  37
  38 sub calculate_all_roles {
  39     my $self = shift;
  40     my %seen;
  41     return grep { !$seen{ $_->name }++ }
  42            ($self, map  { $_->calculate_all_roles } @{ $self->get_roles });
  43 }
  44
  45 sub get_required_method_list{
  46     return @{ $_[0]->{required_methods} };
  47 }
  48
  49 sub add_required_methods {
  50     my($self, @methods) = @_;
  51     my %required = map{ $_ => 1 } @{$self->{required_methods}};
  52     push @{$self->{required_methods}}, grep{ !$required{$_}++ && !$self->has_method($_) } @methods;
  53     return;
  54 }
  55
  56 sub requires_method {
  57     my($self, $name) = @_;
  58     return scalar( grep{ $_ eq $name } @{ $self->{required_methods} } ) != 0;
  59 }
  60
  61 sub add_attribute {
  62     my $self = shift;
  63     my $name = shift;
  64
  65     $self->{attributes}->{$name} = (@_ == 1) ? $_[0] : { @_ };
  66     return;
  67 }
  68
  69 sub _check_required_methods{
  70     my($role, $applicant, $args) = @_;
  71
  72     if($args->{_to} eq 'role'){
  73         $applicant->add_required_methods($role->get_required_method_list);
  74     }
  75     else{ # to class or instance
  76         my $applicant_class_name = $applicant->name;
  77
  78         my @missing;
  79         foreach my $method_name(@{$role->{required_methods}}){
  80             next if exists $args->{aliased_methods}{$method_name};
  81             next if exists $role->{methods}{$method_name};
  82             next if $applicant_class_name->can($method_name);
  83
  84             push @missing, $method_name;
  85         }
  86         if(@missing){
  87             $role->throw_error(sprintf "'%s' requires the method%s %s to be implemented by '%s'",
  88                 $role->name,
  89                 (@missing == 1 ? '' : 's'), # method or methods
  90                 english_list(map{ sprintf q{'%s'}, $_ } @missing),
  91                 $applicant_class_name);
  92         }
  93     }
  94
  95     return;
  96 }
  97
  98 sub _apply_methods{
  99     my($role, $applicant, $args) = @_;
 100
 101     my $alias    = $args->{-alias};
 102     my $excludes = $args->{-excludes};
 103
 104     foreach my $method_name($role->get_method_list){
 105         next if $method_name eq 'meta';
 106
 107         my $code = $role->get_method_body($method_name);
 108
 109         if(!exists $excludes->{$method_name}){
 110             if(!$applicant->has_method($method_name)){
 111                 # The third argument $role is used in Role::Composite
 112                 $applicant->add_method($method_name => $code, $role);
 113             }
 114         }
 115
 116         if(exists $alias->{$method_name}){
 117             my $dstname = $alias->{$method_name};
 118
 119             my $dstcode = $applicant->get_method_body($dstname);
 120
 121             if(defined($dstcode) && $dstcode != $code){
 122                 $role->throw_error("Cannot create a method alias if a local method of the same name exists");
 123             }
 124             else{
 125                 $applicant->add_method($dstname => $code, $role);
 126             }
 127         }
 128     }
 129
 130     return;
 131 }
 132
 133 sub _apply_attributes{
 134     my($role, $applicant, $args) = @_;
 135
 136     for my $attr_name ($role->get_attribute_list) {
 137         next if $applicant->has_attribute($attr_name);
 138
 139         $applicant->add_attribute($attr_name => $role->get_attribute($attr_name));
 140     }
 141     return;
 142 }
 143
 144 sub _apply_modifiers{
 145     my($role, $applicant, $args) = @_;
 146
 147     if(my $modifiers = $role->{override_method_modifiers}){
 148         foreach my $method_name (keys %{$modifiers}){
 149             $applicant->add_override_method_modifier($method_name => $modifiers->{$method_name});
 150         }
 151     }
 152
 153     for my $modifier_type (qw/before around after/) {
 154         my $modifiers = $role->{"${modifier_type}_method_modifiers"}
 155             or next;
 156
 157         my $add_modifier = "add_${modifier_type}_method_modifier";
 158
 159         foreach my $method_name (keys %{$modifiers}){
 160             foreach my $code(@{ $modifiers->{$method_name} }){
 161                 next if $applicant->{"_applied_$modifier_type"}{$method_name, $code}++; # skip applied modifiers
 162                 $applicant->$add_modifier($method_name => $code);
 163             }
 164         }
 165     }
 166     return;
 167 }
 168
 169 sub _append_roles{
 170     my($role, $applicant, $args) = @_;
 171
 172     my $roles = ($args->{_to} eq 'role') ? $applicant->get_roles : $applicant->roles;
 173
 174     foreach my $r($role, @{$role->get_roles}){
 175         if(!$applicant->does_role($r->name)){
 176             push @{$roles}, $r;
 177         }
 178     }
 179     return;
 180 }
 181
 182 # Moose uses Application::ToInstance, Application::ToClass, Application::ToRole
 183 sub apply {
 184     my $self      = shift;
 185     my $applicant = shift;
 186
 187     my %args = (@_ == 1) ? %{ $_[0] } : @_;
 188
 189     my $instance;
 190
 191     if($applicant->isa('Mouse::Meta::Class')){  # Application::ToClass
 192         $args{_to} = 'class';
 193     }
 194     elsif($applicant->isa('Mouse::Meta::Role')){ # Application::ToRole
 195         $args{_to} = 'role';
 196     }
 197     else{                                       # Appplication::ToInstance
 198         $args{_to} = 'instance';
 199         $instance = $applicant;
 200
 201         $applicant = (Mouse::Util::class_of($instance) || 'Mouse::Meta::Class')->create_anon_class(
 202             superclasses => [ref $instance],
 203             cache        => 1,
 204         );
 205     }
 206
 207     if($args{alias} && !exists $args{-alias}){
 208         $args{-alias} = $args{alias};
 209     }
 210     if($args{excludes} && !exists $args{-excludes}){
 211         $args{-excludes} = $args{excludes};
 212     }
 213
 214     $args{aliased_methods} = {};
 215     if(my $alias = $args{-alias}){
 216         @{$args{aliased_methods}}{ values %{$alias} } = ();
 217     }
 218
 219     if(my $excludes = $args{-excludes}){
 220         $args{-excludes} = {}; # replace with a hash ref
 221         if(ref $excludes){
 222             %{$args{-excludes}} = (map{ $_ => undef } @{$excludes});
 223         }
 224         else{
 225             $args{-excludes}{$excludes} = undef;
 226         }
 227     }
 228
 229     $self->_check_required_methods($applicant, \%args);
 230     $self->_apply_attributes($applicant, \%args);
 231     $self->_apply_methods($applicant, \%args);
 232     $self->_apply_modifiers($applicant, \%args);
 233     $self->_append_roles($applicant, \%args);
 234
 235
 236     if(defined $instance){ # Application::ToInstance
 237         # rebless instance
 238         bless $instance, $applicant->name;
 239         $applicant->_initialize_object($instance, $instance);
 240     }
 241
 242     return;
 243 }
 244
 245
 246 sub combine {
 247     my($role_class, @role_specs) = @_;
 248
 249     require 'Mouse/Meta/Role/Composite.pm'; # we don't want to create its namespace
 250
 251     my $composite = Mouse::Meta::Role::Composite->create_anon_role();
 252
 253     foreach my $role_spec (@role_specs) {
 254         my($role_name, $args) = @{$role_spec};
 255         $role_name->meta->apply($composite, %{$args});
 256     }
 257     return $composite;
 258 }
 259
 260 for my $modifier_type (qw/before after around/) {
 261
 262     my $modifier = "${modifier_type}_method_modifiers";
 263
 264     my $add_method_modifier =  sub {
 265         my ($self, $method_name, $method) = @_;
 266
 267         push @{ $self->{$modifier}->{$method_name} ||= [] }, $method;
 268         return;
 269     };
 270
 271     my $get_method_modifiers = sub {
 272         my ($self, $method_name) = @_;
 273         return @{ $self->{$modifier}->{$method_name} ||= [] }
 274     };
 275
 276     no strict 'refs';
 277     *{ 'add_' . $modifier_type . '_method_modifier'  } = $add_method_modifier;
 278     *{ 'get_' . $modifier_type . '_method_modifiers' } = $get_method_modifiers;
 279
 280     # has_${modifier_type}_method_modifiers is moved into t::lib::Test::Mouse
 281 }
 282
 283 sub add_override_method_modifier{
 284     my($self, $method_name, $method) = @_;
 285
 286     if($self->has_method($method_name)){
 287         # This error happens in the override keyword or during role composition,
 288         # so I added a message, "A local method of ...", only for compatibility (gfx)
 289         $self->throw_error("Cannot add an override of method '$method_name' "
 290                    . "because there is a local version of '$method_name'"
 291                    . "(A local method of the same name as been found)");
 292     }
 293
 294     $self->{override_method_modifiers}->{$method_name} = $method;
 295 }
 296
 297 sub get_override_method_modifier {
 298     my ($self, $method_name) = @_;
 299     return $self->{override_method_modifiers}->{$method_name};
 300 }
 301
 302 sub does_role {
 303     my ($self, $role_name) = @_;
 304
 305     (defined $role_name)
 306         || $self->throw_error("You must supply a role name to look for");
 307
 308     # if we are it,.. then return true
 309     return 1 if $role_name eq $self->name;
 310     # otherwise.. check our children
 311     for my $role (@{ $self->get_roles }) {
 312         return 1 if $role->does_role($role_name);
 313     }
 314     return 0;
 315 }
 316
 317 1;
 318 __END__
 319
 320 =head1 NAME
 321
 322 Mouse::Meta::Role - The Mouse Role metaclass
 323
 324 =head1 VERSION
 325
 326 This document describes Mouse version 0.39
 327
 328 =head1 SEE ALSO
 329
 330 L<Moose::Meta::Role>
 331
 332 =cut