lib/Mouse/Meta/Role.pm

   1 package Mouse::Meta::Role;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Mouse::Meta::Module;
   5 our @ISA = qw(Mouse::Meta::Module);
   6
   7 sub method_metaclass;
   8
   9 sub _construct_meta {
  10     my $class = shift;
  11
  12     my %args  = @_;
  13
  14     $args{methods}          = {};
  15     $args{attributes}       = {};
  16     $args{required_methods} = [];
  17     $args{roles}            = [];
  18
  19     my $self = bless \%args, ref($class) || $class;
  20     if($class ne __PACKAGE__){
  21         $self->meta->_initialize_object($self, \%args);
  22     }
  23
  24     return $self;
  25 }
  26
  27 sub create_anon_role{
  28     my $self = shift;
  29     return $self->create(undef, @_);
  30 }
  31
  32 sub is_anon_role;
  33
  34 sub get_roles;
  35
  36 sub calculate_all_roles {
  37     my $self = shift;
  38     my %seen;
  39     return grep { !$seen{ $_->name }++ }
  40            ($self, map  { $_->calculate_all_roles } @{ $self->get_roles });
  41 }
  42
  43 sub get_required_method_list{
  44     return @{ $_[0]->{required_methods} };
  45 }
  46
  47 sub add_required_methods {
  48     my($self, @methods) = @_;
  49     my %required = map{ $_ => 1 } @{$self->{required_methods}};
  50     push @{$self->{required_methods}}, grep{ !$required{$_}++ && !$self->has_method($_) } @methods;
  51     return;
  52 }
  53
  54 sub requires_method {
  55     my($self, $name) = @_;
  56     return scalar( grep{ $_ eq $name } @{ $self->{required_methods} } ) != 0;
  57 }
  58
  59 sub add_attribute {
  60     my $self = shift;
  61     my $name = shift;
  62
  63     $self->{attributes}->{$name} = (@_ == 1) ? $_[0] : { @_ };
  64     return;
  65 }
  66
  67 sub _check_required_methods{
  68     my($role, $consumer, $args) = @_;
  69
  70     if($args->{_to} eq 'role'){
  71         $consumer->add_required_methods($role->get_required_method_list);
  72     }
  73     else{ # to class or instance
  74         my $consumer_class_name = $consumer->name;
  75
  76         my @missing;
  77         foreach my $method_name(@{$role->{required_methods}}){
  78             next if exists $args->{aliased_methods}{$method_name};
  79             next if exists $role->{methods}{$method_name};
  80             next if $consumer_class_name->can($method_name);
  81
  82             push @missing, $method_name;
  83         }
  84         if(@missing){
  85             $role->throw_error(sprintf "'%s' requires the method%s %s to be implemented by '%s'",
  86                 $role->name,
  87                 (@missing == 1 ? '' : 's'), # method or methods
  88                 Mouse::Util::quoted_english_list(@missing),
  89                 $consumer_class_name);
  90         }
  91     }
  92
  93     return;
  94 }
  95
  96 sub _apply_methods{
  97     my($role, $consumer, $args) = @_;
  98
  99     my $alias    = $args->{-alias};
 100     my $excludes = $args->{-excludes};
 101
 102     foreach my $method_name($role->get_method_list){
 103         next if $method_name eq 'meta';
 104
 105         my $code = $role->get_method_body($method_name);
 106
 107         if(!exists $excludes->{$method_name}){
 108             if(!$consumer->has_method($method_name)){
 109                 # The third argument $role is used in Role::Composite
 110                 $consumer->add_method($method_name => $code, $role);
 111             }
 112         }
 113
 114         if(exists $alias->{$method_name}){
 115             my $dstname = $alias->{$method_name};
 116
 117             my $dstcode = $consumer->get_method_body($dstname);
 118
 119             if(defined($dstcode) && $dstcode != $code){
 120                 $role->throw_error("Cannot create a method alias if a local method of the same name exists");
 121             }
 122             else{
 123                 $consumer->add_method($dstname => $code, $role);
 124             }
 125         }
 126     }
 127
 128     return;
 129 }
 130
 131 sub _apply_attributes{
 132     #my($role, $consumer, $args) = @_;
 133     my($role, $consumer) = @_;
 134
 135     for my $attr_name ($role->get_attribute_list) {
 136         next if $consumer->has_attribute($attr_name);
 137
 138         $consumer->add_attribute($attr_name => $role->get_attribute($attr_name));
 139     }
 140     return;
 141 }
 142
 143 sub _apply_modifiers{
 144     #my($role, $consumer, $args) = @_;
 145     my($role, $consumer) = @_;
 146
 147
 148     if(my $modifiers = $role->{override_method_modifiers}){
 149         foreach my $method_name (keys %{$modifiers}){
 150             $consumer->add_override_method_modifier($method_name => $modifiers->{$method_name});
 151         }
 152     }
 153
 154     for my $modifier_type (qw/before around after/) {
 155         my $table = $role->{"${modifier_type}_method_modifiers"}
 156             or next;
 157
 158         my $add_modifier = "add_${modifier_type}_method_modifier";
 159
 160         while(my($method_name, $modifiers) = each %{$table}){
 161             foreach my $code(@{ $modifiers }){
 162                 next if $consumer->{"_applied_$modifier_type"}{$method_name, $code}++; # skip applied modifiers
 163                 $consumer->$add_modifier($method_name => $code);
 164             }
 165         }
 166     }
 167     return;
 168 }
 169
 170 sub _append_roles{
 171     #my($role, $consumer, $args) = @_;
 172     my($role, $consumer) = @_;
 173
 174     my $roles = $consumer->{roles};
 175
 176     foreach my $r($role, @{$role->get_roles}){
 177         if(!$consumer->does_role($r)){
 178             push @{$roles}, $r;
 179         }
 180     }
 181     return;
 182 }
 183
 184 # Moose uses Application::ToInstance, Application::ToClass, Application::ToRole
 185 sub apply {
 186     my $self     = shift;
 187     my $consumer = shift;
 188
 189     my %args = (@_ == 1) ? %{ $_[0] } : @_;
 190
 191     my $instance;
 192
 193     if(Mouse::Util::is_a_metaclass($consumer)){  # Application::ToClass
 194         $args{_to} = 'class';
 195     }
 196     elsif(Mouse::Util::is_a_metarole($consumer)){ # Application::ToRole
 197         $args{_to} = 'role';
 198     }
 199     else{                                       # Appplication::ToInstance
 200         $args{_to} = 'instance';
 201         $instance  = $consumer;
 202
 203         $consumer = (Mouse::Util::class_of($instance) || 'Mouse::Meta::Class')
 204             ->create_anon_class(
 205                 superclasses => [ref $instance],
 206                 cache        => 1,
 207             );
 208     }
 209
 210     if($args{alias} && !exists $args{-alias}){
 211         $args{-alias} = $args{alias};
 212     }
 213     if($args{excludes} && !exists $args{-excludes}){
 214         $args{-excludes} = $args{excludes};
 215     }
 216
 217     $args{aliased_methods} = {};
 218     if(my $alias = $args{-alias}){
 219         @{$args{aliased_methods}}{ values %{$alias} } = ();
 220     }
 221
 222     if(my $excludes = $args{-excludes}){
 223         $args{-excludes} = {}; # replace with a hash ref
 224         if(ref $excludes){
 225             %{$args{-excludes}} = (map{ $_ => undef } @{$excludes});
 226         }
 227         else{
 228             $args{-excludes}{$excludes} = undef;
 229         }
 230     }
 231
 232     $self->_check_required_methods($consumer, \%args);
 233     $self->_apply_attributes($consumer, \%args);
 234     $self->_apply_methods($consumer, \%args);
 235     $self->_apply_modifiers($consumer, \%args);
 236     $self->_append_roles($consumer, \%args);
 237
 238
 239     if(defined $instance){ # Application::ToInstance
 240         # rebless instance
 241         bless $instance, $consumer->name;
 242         $consumer->_initialize_object($instance, $instance, 1);
 243     }
 244
 245     return;
 246 }
 247
 248
 249 sub combine {
 250     my($self, @role_specs) = @_;
 251
 252     require 'Mouse/Meta/Role/Composite.pm'; # we don't want to create its namespace
 253
 254     my $composite = Mouse::Meta::Role::Composite->create_anon_role();
 255
 256     foreach my $role_spec (@role_specs) {
 257         my($role_name, $args) = @{$role_spec};
 258         $role_name->meta->apply($composite, %{$args});
 259     }
 260     return $composite;
 261 }
 262
 263 sub add_before_method_modifier;
 264 sub add_around_method_modifier;
 265 sub add_after_method_modifier;
 266
 267 sub get_before_method_modifiers;
 268 sub get_around_method_modifiers;
 269 sub get_after_method_modifiers;
 270
 271 sub add_override_method_modifier{
 272     my($self, $method_name, $method) = @_;
 273
 274     if($self->has_method($method_name)){
 275         # This error happens in the override keyword or during role composition,
 276         # so I added a message, "A local method of ...", only for compatibility (gfx)
 277         $self->throw_error("Cannot add an override of method '$method_name' "
 278                    . "because there is a local version of '$method_name'"
 279                    . "(A local method of the same name as been found)");
 280     }
 281
 282     $self->{override_method_modifiers}->{$method_name} = $method;
 283 }
 284
 285 sub get_override_method_modifier {
 286     my ($self, $method_name) = @_;
 287     return $self->{override_method_modifiers}->{$method_name};
 288 }
 289
 290 sub does_role {
 291     my ($self, $role_name) = @_;
 292
 293     (defined $role_name)
 294         || $self->throw_error("You must supply a role name to look for");
 295
 296     $role_name = $role_name->name if ref $role_name;
 297
 298     # if we are it,.. then return true
 299     return 1 if $role_name eq $self->name;
 300     # otherwise.. check our children
 301     for my $role (@{ $self->get_roles }) {
 302         return 1 if $role->does_role($role_name);
 303     }
 304     return 0;
 305 }
 306
 307 1;
 308 __END__
 309
 310 =head1 NAME
 311
 312 Mouse::Meta::Role - The Mouse Role metaclass
 313
 314 =head1 VERSION
 315
 316 This document describes Mouse version 0.70
 317
 318 =head1 DESCRIPTION
 319
 320 This class is a meta object protocol for Mouse roles,
 321 which is a subset of Moose::Meta:::Role.
 322
 323 =head1 SEE ALSO
 324
 325 L<Moose::Meta::Role>
 326
 327 =cut