lib/Mouse/Meta/Role.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Role;
   3 use strict;
   4 use warnings;
   5 use Carp 'confess';
   6
   7 do {
   8     my %METACLASS_CACHE;
   9
  10     # because Mouse doesn't introspect existing classes, we're forced to
  11     # only pay attention to other Mouse classes
  12     sub _metaclass_cache {
  13         my $class = shift;
  14         my $name  = shift;
  15         return $METACLASS_CACHE{$name};
  16     }
  17
  18     sub initialize {
  19         my $class = shift;
  20         my $name  = shift;
  21         $METACLASS_CACHE{$name} = $class->new(name => $name)
  22             if !exists($METACLASS_CACHE{$name});
  23         return $METACLASS_CACHE{$name};
  24     }
  25 };
  26
  27 sub new {
  28     my $class = shift;
  29     my %args  = @_;
  30
  31     $args{attributes}       ||= {};
  32     $args{required_methods} ||= [];
  33     $args{roles}            ||= [];
  34
  35     bless \%args, $class;
  36 }
  37
  38 sub name { $_[0]->{name} }
  39
  40 sub add_required_methods {
  41     my $self = shift;
  42     my @methods = @_;
  43     push @{$self->{required_methods}}, @methods;
  44 }
  45
  46 sub add_attribute {
  47     my $self = shift;
  48     my $name = shift;
  49     my $spec = shift;
  50     $self->{attributes}->{$name} = $spec;
  51 }
  52
  53 sub has_attribute { exists $_[0]->{attributes}->{$_[1]}  }
  54 sub get_attribute_list { keys %{ $_[0]->{attributes} } }
  55 sub get_attribute { $_[0]->{attributes}->{$_[1]} }
  56
  57 # copied from Class::Inspector
  58 sub get_method_list {
  59     my $self = shift;
  60     my $name = $self->name;
  61
  62     no strict 'refs';
  63     # Get all the CODE symbol table entries
  64     my @functions = grep !/^meta$/,
  65       grep { /\A[^\W\d]\w*\z/o }
  66       grep { defined &{"${name}::$_"} }
  67       keys %{"${name}::"};
  68     wantarray ? @functions : \@functions;
  69 }
  70
  71 sub apply {
  72     my $self  = shift;
  73     my $selfname = $self->name;
  74     my $class = shift;
  75     my $classname = $class->name;
  76     my %args  = @_;
  77
  78     if ($class->isa('Mouse::Meta::Class')) {
  79         for my $name (@{$self->{required_methods}}) {
  80             unless ($classname->can($name)) {
  81                 confess "'$selfname' requires the method '$name' to be implemented by '$classname'";
  82             }
  83         }
  84     }
  85
  86     {
  87         no strict 'refs';
  88         for my $name ($self->get_method_list) {
  89             next if $name eq 'has' || $name eq 'requires' || $name eq 'meta' || $name eq 'with' || $name eq 'around' || $name eq 'before' || $name eq 'after' || $name eq 'blessed' || $name eq 'extends' || $name eq 'confess' || $name eq 'excludes';
  90             my $dstname = $args{alias} ? ($args{alias}->{$name}||$name) : $name;
  91             if ($classname->can($dstname)) {
  92                 # XXX what's Moose's behavior?
  93                 next;
  94             }
  95             *{"${classname}::${dstname}"} = *{"${selfname}::${name}"};
  96         }
  97     }
  98
  99     if ($class->isa('Mouse::Meta::Class')) {
 100         # apply role to class
 101         for my $name ($self->get_attribute_list) {
 102             next if $class->has_attribute($name);
 103             my $spec = $self->get_attribute($name);
 104             Mouse::Meta::Attribute->create($class, $name, %$spec);
 105         }
 106     } else {
 107         # apply role to role
 108         # XXX Room for speed improvement
 109         for my $name ($self->get_attribute_list) {
 110             next if $class->has_attribute($name);
 111             my $spec = $self->get_attribute($name);
 112             $class->add_attribute($name, $spec);
 113         }
 114     }
 115
 116     # XXX Room for speed improvement in role to role
 117     for my $modifier_type (qw/before after around/) {
 118         my $add_method = "add_${modifier_type}_method_modifier";
 119         my $modified = $self->{"${modifier_type}_method_modifiers"};
 120
 121         for my $method_name (keys %$modified) {
 122             for my $code (@{ $modified->{$method_name} }) {
 123                 $class->$add_method($method_name => $code);
 124             }
 125         }
 126     }
 127
 128     # append roles
 129     push @{ $class->roles }, $self, @{ $self->roles };
 130 }
 131
 132 for my $modifier_type (qw/before after around/) {
 133     no strict 'refs';
 134     *{ __PACKAGE__ . '::' . "add_${modifier_type}_method_modifier" } = sub {
 135         my ($self, $method_name, $method) = @_;
 136
 137         push @{ $self->{"${modifier_type}_method_modifiers"}->{$method_name} },
 138             $method;
 139     };
 140
 141     *{ __PACKAGE__ . '::' . "get_${modifier_type}_method_modifiers" } = sub {
 142         my ($self, $method_name, $method) = @_;
 143         @{ $self->{"${modifier_type}_method_modifiers"}->{$method_name} || [] }
 144     };
 145 }
 146
 147 sub roles { $_[0]->{roles} }
 148
 149 1;
 150