lib/Mouse/Meta/Role.pm

   1 package Mouse::Meta::Role;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Util qw(not_supported english_list);
   6 use Mouse::Meta::Module;
   7
   8 use base qw(Mouse::Meta::Module);
   9
  10 sub method_metaclass(){ 'Mouse::Meta::Role::Method' } # required for get_method()
  11
  12 sub _construct_meta {
  13     my $class = shift;
  14
  15     my %args  = @_;
  16
  17     $args{methods}          ||= {};
  18     $args{attributes}       ||= {};
  19     $args{required_methods} ||= [];
  20     $args{roles}            ||= [];
  21
  22 #    return Mouse::Meta::Class->initialize($class)->new_object(%args)
  23 #        if $class ne __PACKAGE__;
  24
  25     return bless \%args, ref($class) || $class;
  26 }
  27
  28 sub create_anon_role{
  29     my $self = shift;
  30     return $self->create(undef, @_);
  31 }
  32
  33 sub is_anon_role{
  34     return exists $_[0]->{anon_serial_id};
  35 }
  36
  37 sub get_roles { $_[0]->{roles} }
  38
  39 sub get_required_method_list{
  40     return @{ $_[0]->{required_methods} };
  41 }
  42
  43 sub add_required_methods {
  44     my $self = shift;
  45     my @methods = @_;
  46     push @{$self->{required_methods}}, @methods;
  47 }
  48
  49 sub requires_method {
  50     my($self, $name) = @_;
  51     return scalar( grep{ $_ eq $name } @{ $self->{required_methods} } ) != 0;
  52 }
  53
  54 sub add_attribute {
  55     my $self = shift;
  56     my $name = shift;
  57
  58     $self->{attributes}->{$name} = (@_ == 1) ? $_[0] : { @_ };
  59 }
  60
  61 sub _canonicalize_apply_args{
  62     my($self, $applicant, %args) = @_;
  63
  64     if($applicant->isa('Mouse::Meta::Class')){
  65         $args{_to} = 'class';
  66     }
  67     elsif($applicant->isa('Mouse::Meta::Role')){
  68         $args{_to} = 'role';
  69     }
  70     else{
  71         $args{_to} = 'instance';
  72
  73         not_supported 'Application::ToInstance';
  74     }
  75
  76     if($args{alias} && !exists $args{-alias}){
  77         $args{-alias} = $args{alias};
  78     }
  79     if($args{excludes} && !exists $args{-excludes}){
  80         $args{-excludes} = $args{excludes};
  81     }
  82
  83     if(my $excludes = $args{-excludes}){
  84         $args{-excludes} = {}; # replace with a hash ref
  85         if(ref $excludes){
  86             %{$args{-excludes}} = (map{ $_ => undef } @{$excludes});
  87         }
  88         else{
  89             $args{-excludes}{$excludes} = undef;
  90         }
  91     }
  92
  93     return \%args;
  94 }
  95
  96 sub _check_required_methods{
  97     my($role, $class, $args, @other_roles) = @_;
  98
  99     if($args->{_to} eq 'class'){
 100         my $class_name = $class->name;
 101         my $role_name  = $role->name;
 102         my @missing;
 103         foreach my $method_name(@{$role->{required_methods}}){
 104             if(!$class_name->can($method_name)){
 105                 my $has_method      = 0;
 106
 107                 foreach my $another_role_spec(@other_roles){
 108                     my $another_role_name = $another_role_spec->[0];
 109                     if($role_name ne $another_role_name && $another_role_name->can($method_name)){
 110                         $has_method = 1;
 111                         last;
 112                     }
 113                 }
 114
 115                 push @missing, $method_name if !$has_method;
 116             }
 117         }
 118         if(@missing){
 119             $class->throw_error("'$role_name' requires the "
 120                 . (@missing == 1 ? 'method' : 'methods')
 121                 . " "
 122                 . english_list(map{ sprintf q{'%s'}, $_ } @missing)
 123                 . " to be implemented by '$class_name'");
 124         }
 125     }
 126     elsif($args->{_to} eq 'role'){
 127         # apply role($role) to role($class)
 128         foreach my $method_name($role->get_required_method_list){
 129             next if $class->has_method($method_name); # already has it
 130             $class->add_required_methods($method_name);
 131         }
 132     }
 133
 134     return;
 135 }
 136
 137 sub _apply_methods{
 138     my($role, $class, $args) = @_;
 139
 140     my $role_name  = $role->name;
 141     my $class_name = $class->name;
 142
 143     my $alias    = $args->{-alias};
 144     my $excludes = $args->{-excludes};
 145
 146     foreach my $method_name($role->get_method_list){
 147         next if $method_name eq 'meta';
 148
 149         my $code = $role_name->can($method_name);
 150
 151         if(!exists $excludes->{$method_name}){
 152             if(!$class->has_method($method_name)){
 153                 $class->add_method($method_name => $code);
 154             }
 155         }
 156
 157         if($alias && $alias->{$method_name}){
 158             my $dstname = $alias->{$method_name};
 159
 160             my $dstcode = do{ no strict 'refs'; *{$class_name . '::' . $dstname}{CODE} };
 161
 162             if(defined($dstcode) && $dstcode != $code){
 163                 $class->throw_error("Cannot create a method alias if a local method of the same name exists");
 164             }
 165             else{
 166                 $class->add_method($dstname => $code);
 167             }
 168         }
 169     }
 170
 171     return;
 172 }
 173
 174 sub _apply_attributes{
 175     my($role, $class, $args) = @_;
 176
 177     if ($args->{_to} eq 'class') {
 178         # apply role to class
 179         for my $attr_name ($role->get_attribute_list) {
 180             next if $class->has_attribute($attr_name);
 181
 182             my $spec = $role->get_attribute($attr_name);
 183
 184             $class->add_attribute($attr_name => %{$spec});
 185         }
 186     }
 187     elsif($args->{_to} eq 'role'){
 188         # apply role to role
 189         for my $attr_name ($role->get_attribute_list) {
 190             next if $class->has_attribute($attr_name);
 191
 192             my $spec = $role->get_attribute($attr_name);
 193             $class->add_attribute($attr_name => $spec);
 194         }
 195     }
 196
 197     return;
 198 }
 199
 200 sub _apply_modifiers{
 201     my($role, $class, $args) = @_;
 202
 203     for my $modifier_type (qw/override before around after/) {
 204         my $add_modifier = "add_${modifier_type}_method_modifier";
 205         my $modifiers    = $role->{"${modifier_type}_method_modifiers"};
 206
 207         while(my($method_name, $modifier_codes) = each %{$modifiers}){
 208             foreach my $code(ref($modifier_codes) eq 'ARRAY' ? @{$modifier_codes} : $modifier_codes){
 209                 $class->$add_modifier($method_name => $code);
 210             }
 211         }
 212     }
 213     return;
 214 }
 215
 216 sub _append_roles{
 217     my($role, $class, $args) = @_;
 218
 219     my $roles = ($args->{_to} eq 'class') ? $class->roles : $class->get_roles;
 220
 221     foreach my $r($role, @{$role->get_roles}){
 222         if(!$class->does_role($r->name)){
 223             push @{$roles}, $r;
 224         }
 225     }
 226     return;
 227 }
 228
 229 # Moose uses Application::ToInstance, Application::ToClass, Application::ToRole
 230 sub apply {
 231     my $self      = shift;
 232     my $applicant = shift;
 233
 234     my $args = $self->_canonicalize_apply_args($applicant, @_);
 235
 236     $self->_check_required_methods($applicant, $args);
 237     $self->_apply_methods($applicant, $args);
 238     $self->_apply_attributes($applicant, $args);
 239     $self->_apply_modifiers($applicant, $args);
 240     $self->_append_roles($applicant, $args);
 241     return;
 242 }
 243
 244 sub combine_apply {
 245     my(undef, $class, @roles) = @_;
 246
 247     if($class->isa('Mouse::Object')){
 248         not_supported 'Application::ToInstance';
 249     }
 250
 251     # check conflicting
 252     my %method_provided;
 253     my @method_conflicts;
 254     my %attr_provided;
 255     my %override_provided;
 256
 257     foreach my $role_spec (@roles) {
 258         my $role      = $role_spec->[0]->meta;
 259         my $role_name = $role->name;
 260
 261         # methods
 262         foreach my $method_name($role->get_method_list){
 263             next if $class->has_method($method_name); # manually resolved
 264
 265             my $code = do{ no strict 'refs'; \&{ $role_name . '::' . $method_name } };
 266
 267             my $c = $method_provided{$method_name};
 268
 269             if($c && $c->[0] != $code){
 270                 push @{$c}, $role;
 271                 push @method_conflicts, $c;
 272             }
 273             else{
 274                 $method_provided{$method_name} = [$code, $method_name, $role];
 275             }
 276         }
 277
 278         # attributes
 279         foreach my $attr_name($role->get_attribute_list){
 280             my $attr = $role->get_attribute($attr_name);
 281             my $c    = $attr_provided{$attr_name};
 282             if($c && $c != $attr){
 283                 $class->throw_error("We have encountered an attribute conflict with '$attr_name' "
 284                                    . "during composition. This is fatal error and cannot be disambiguated.")
 285             }
 286             else{
 287                 $attr_provided{$attr_name} = $attr;
 288             }
 289         }
 290
 291         # override modifiers
 292         foreach my $method_name($role->get_method_modifier_list('override')){
 293             my $override = $role->get_override_method_modifier($method_name);
 294             my $c        = $override_provided{$method_name};
 295             if($c && $c != $override){
 296                 $class->throw_error( "We have encountered an 'override' method conflict with '$method_name' during "
 297                                    . "composition (Two 'override' methods of the same name encountered). "
 298                                    . "This is fatal error.")
 299             }
 300             else{
 301                 $override_provided{$method_name} = $override;
 302             }
 303         }
 304     }
 305     if(@method_conflicts){
 306         my $error;
 307
 308         if(@method_conflicts == 1){
 309             my($code, $method_name, @roles) = @{$method_conflicts[0]};
 310             $class->throw_error(
 311                 sprintf q{Due to a method name conflict in roles %s, the method '%s' must be implemented or excluded by '%s'},
 312                     english_list(map{ sprintf q{'%s'}, $_->name } @roles), $method_name, $class->name
 313             );
 314         }
 315         else{
 316             @method_conflicts = sort { $a->[0] cmp $b->[0] } @method_conflicts; # to avoid hash-ordering bugs
 317             my $methods = english_list(map{ sprintf q{'%s'}, $_->[1] } @method_conflicts);
 318             my $roles   = english_list(
 319                 map{ sprintf q{'%s'}, $_->name }
 320                 map{ my($code, $method_name, @roles) = @{$_}; @roles } @method_conflicts
 321             );
 322
 323             $class->throw_error(
 324                 sprintf q{Due to method name conflicts in roles %s, the methods %s must be implemented or excluded by '%s'},
 325                     $roles, $methods, $class->name
 326             );
 327         }
 328     }
 329
 330     foreach my $role_spec (@roles) {
 331         my($role_name, $args) = @{$role_spec};
 332
 333         my $role = $role_name->meta;
 334
 335         $args = $role->_canonicalize_apply_args($class, %{$args});
 336
 337         $role->_check_required_methods($class, $args, @roles);
 338         $role->_apply_methods($class, $args);
 339         $role->_apply_attributes($class, $args);
 340         $role->_apply_modifiers($class, $args);
 341         $role->_append_roles($class, $args);
 342     }
 343     return;
 344 }
 345
 346 for my $modifier_type (qw/before after around/) {
 347
 348     my $modifier = "${modifier_type}_method_modifiers";
 349     my $add_method_modifier =  sub {
 350         my ($self, $method_name, $method) = @_;
 351
 352         push @{ $self->{$modifier}->{$method_name} ||= [] }, $method;
 353         return;
 354     };
 355     my $has_method_modifiers = sub{
 356         my($self, $method_name) = @_;
 357         my $m = $self->{$modifier}->{$method_name};
 358         return $m && @{$m} != 0;
 359     };
 360     my $get_method_modifiers = sub {
 361         my ($self, $method_name) = @_;
 362         return @{ $self->{$modifier}->{$method_name} ||= [] }
 363     };
 364
 365     no strict 'refs';
 366     *{ 'add_' . $modifier_type . '_method_modifier'  } = $add_method_modifier;
 367     *{ 'has_' . $modifier_type . '_method_modifiers' } = $has_method_modifiers;
 368     *{ 'get_' . $modifier_type . '_method_modifiers' } = $get_method_modifiers;
 369 }
 370
 371 sub add_override_method_modifier{
 372     my($self, $method_name, $method) = @_;
 373
 374     if($self->has_method($method_name)){
 375         # This error happens in the override keyword or during role composition,
 376         # so I added a message, "A local method of ...", only for compatibility (gfx)
 377         $self->throw_error("Cannot add an override of method '$method_name' "
 378                    . "because there is a local version of '$method_name'"
 379                    . "(A local method of the same name as been found)");
 380     }
 381
 382     $self->{override_method_modifiers}->{$method_name} = $method;
 383 }
 384
 385 sub has_override_method_modifier {
 386     my ($self, $method_name) = @_;
 387     return exists $self->{override_method_modifiers}->{$method_name};
 388 }
 389
 390 sub get_override_method_modifier {
 391     my ($self, $method_name) = @_;
 392     return $self->{override_method_modifiers}->{$method_name};
 393 }
 394
 395 sub get_method_modifier_list {
 396     my($self, $modifier_type) = @_;
 397
 398     return keys %{ $self->{$modifier_type . '_method_modifiers'} };
 399 }
 400
 401 # This is currently not passing all the Moose tests.
 402 sub does_role {
 403     my ($self, $role_name) = @_;
 404
 405     (defined $role_name)
 406         || $self->throw_error("You must supply a role name to look for");
 407
 408     # if we are it,.. then return true
 409     return 1 if $role_name eq $self->name;
 410     # otherwise.. check our children
 411     for my $role (@{ $self->get_roles }) {
 412         return 1 if $role->does_role($role_name);
 413     }
 414     return 0;
 415 }
 416
 417
 418 1;
 419