lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package get_code_ref load_class not_supported/; # enables strict and warnings
   3
   4 use Carp         ();
   5 use Scalar::Util ();
   6
   7 my %METAS;
   8
   9 # XXX: work around a warning "useless use of a constant in void context" in 5.6.2
  10 if(&Mouse::Util::MOUSE_XS){
  11     # register meta storage for performance
  12     Mouse::Util::__register_metaclass_storage(\%METAS, 0);
  13
  14     # ensure thread safety
  15     *CLONE = sub { Mouse::Util::__register_metaclass_storage(\%METAS, 1) };
  16 }
  17
  18 sub _metaclass_cache { # DEPRECATED
  19     my($class, $name) = @_;
  20     return $METAS{$name};
  21 }
  22
  23 sub initialize {
  24     my($class, $package_name, @args) = @_;
  25
  26     ($package_name && !ref($package_name))
  27         || $class->throw_error("You must pass a package name and it cannot be blessed");
  28
  29     return $METAS{$package_name}
  30         ||= $class->_construct_meta(package => $package_name, @args);
  31 }
  32
  33 sub reinitialize {
  34     my($class, $package_name, @args) = @_;
  35
  36     $package_name = $package_name->name if ref $package_name;
  37
  38     ($package_name && !ref($package_name))
  39         || $class->throw_error("You must pass a package name and it cannot be blessed");
  40
  41     delete $METAS{$package_name};
  42     return $class->initialize($package_name, @args);
  43 }
  44
  45 sub _class_of{
  46     my($class_or_instance) = @_;
  47     return undef unless defined $class_or_instance;
  48     return $METAS{ ref($class_or_instance) || $class_or_instance };
  49 }
  50
  51 # Means of accessing all the metaclasses that have
  52 # been initialized thus far
  53 #sub _get_all_metaclasses         {        %METAS         }
  54 sub _get_all_metaclass_instances { values %METAS         }
  55 sub _get_all_metaclass_names     { keys   %METAS         }
  56 sub _get_metaclass_by_name       { $METAS{$_[0]}         }
  57 #sub _store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  58 #sub _weaken_metaclass            { weaken($METAS{$_[0]}) }
  59 #sub _does_metaclass_exist        { defined $METAS{$_[0]} }
  60 #sub _remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  61
  62 sub name;
  63
  64 sub namespace;
  65
  66 # The followings are Class::MOP specific methods
  67
  68 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  69 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  70 #sub identifier {
  71 #    my $self = shift;
  72 #    return join '-' => (
  73 #       $self->name,
  74 #        ($self->version   || ()),
  75 #        ($self->authority || ()),
  76 #    );
  77 #}
  78
  79 # add_attribute is an abstract method
  80
  81 sub get_attribute_map { # DEPRECATED
  82     Carp::cluck('get_attribute_map() has been deprecated');
  83     return $_[0]->{attributes};
  84 }
  85
  86 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  87 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  88 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  89
  90 sub get_attribute_list{ keys   %{$_[0]->{attributes}} }
  91
  92
  93 # XXX: for backward compatibility
  94 my %foreign = map{ $_ => undef } qw(
  95     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
  96     Carp Scalar::Util List::Util
  97 );
  98 sub _code_is_mine{
  99 #    my($self, $code) = @_;
 100
 101     return !exists $foreign{ get_code_package($_[1]) };
 102 }
 103
 104 sub add_method;
 105
 106 sub has_method {
 107     my($self, $method_name) = @_;
 108
 109     defined($method_name)
 110         or $self->throw_error('You must define a method name');
 111
 112     return defined($self->{methods}{$method_name}) || do{
 113         my $code = get_code_ref($self->{package}, $method_name);
 114         $code && $self->_code_is_mine($code);
 115     };
 116 }
 117
 118 sub get_method_body {
 119     my($self, $method_name) = @_;
 120
 121     defined($method_name)
 122         or $self->throw_error('You must define a method name');
 123
 124     return $self->{methods}{$method_name} ||= do{
 125         my $code = get_code_ref($self->{package}, $method_name);
 126         $code && $self->_code_is_mine($code) ? $code : undef;
 127     };
 128 }
 129
 130 sub get_method{
 131     my($self, $method_name) = @_;
 132
 133     if(my $code = $self->get_method_body($method_name)){
 134         my $method_metaclass = $self->method_metaclass;
 135         load_class($method_metaclass);
 136
 137         return $method_metaclass->wrap(
 138             body                 => $code,
 139             name                 => $method_name,
 140             package              => $self->name,
 141             associated_metaclass => $self,
 142         );
 143     }
 144
 145     return undef;
 146 }
 147
 148 sub get_method_list {
 149     my($self) = @_;
 150
 151     return grep { $self->has_method($_) } keys %{ $self->namespace };
 152 }
 153
 154 {
 155     my $ANON_SERIAL = 0;
 156
 157     my %IMMORTALS;
 158
 159     sub create {
 160         my($self, $package_name, %options) = @_;
 161
 162         my $class = ref($self) || $self;
 163         $self->throw_error('You must pass a package name') if @_ < 2;
 164
 165         my $superclasses;
 166         if(exists $options{superclasses}){
 167             if(Mouse::Util::is_a_metarole($self)){
 168                 delete $options{superclasses};
 169             }
 170             else{
 171                 $superclasses = delete $options{superclasses};
 172                 (ref $superclasses eq 'ARRAY')
 173                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 174             }
 175         }
 176
 177         my $attributes = delete $options{attributes};
 178         if(defined $attributes){
 179             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 180                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 181         }
 182         my $methods = delete $options{methods};
 183         if(defined $methods){
 184             (ref $methods eq 'HASH')
 185                 || $self->throw_error("You must pass a HASH ref of methods");
 186         }
 187         my $roles = delete $options{roles};
 188         if(defined $roles){
 189             (ref $roles eq 'ARRAY')
 190                 || $self->throw_error("You must pass an ARRAY ref of roles");
 191         }
 192         my $mortal;
 193         my $cache_key;
 194
 195         if(!defined $package_name){ # anonymous
 196             $mortal = !$options{cache};
 197
 198             # anonymous but immortal
 199             if(!$mortal){
 200                     # something like Super::Class|Super::Class::2=Role|Role::1
 201                     $cache_key = join '=' => (
 202                         join('|',      @{$superclasses || []}),
 203                         join('|', sort @{$roles        || []}),
 204                     );
 205                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 206             }
 207             $options{anon_serial_id} = ++$ANON_SERIAL;
 208             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 209         }
 210
 211         # instantiate a module
 212         {
 213             no strict 'refs';
 214             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 215             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 216         }
 217
 218         my $meta = $self->initialize( $package_name, %options);
 219
 220         Scalar::Util::weaken $METAS{$package_name}
 221             if $mortal;
 222
 223         $meta->add_method(meta => sub{
 224             $self->initialize(ref($_[0]) || $_[0]);
 225         });
 226
 227         $meta->superclasses(@{$superclasses})
 228             if defined $superclasses;
 229
 230         # NOTE:
 231         # process attributes first, so that they can
 232         # install accessors, but locally defined methods
 233         # can then overwrite them. It is maybe a little odd, but
 234         # I think this should be the order of things.
 235         if (defined $attributes) {
 236             if(ref($attributes) eq 'ARRAY'){
 237                 # array of Mouse::Meta::Attribute
 238                 foreach my $attr (@{$attributes}) {
 239                     $meta->add_attribute($attr);
 240                 }
 241             }
 242             else{
 243                 # hash map of name and attribute spec pairs
 244                 while(my($name, $attr) = each %{$attributes}){
 245                     $meta->add_attribute($name => $attr);
 246                 }
 247             }
 248         }
 249         if (defined $methods) {
 250             while(my($method_name, $method_body) = each %{$methods}){
 251                 $meta->add_method($method_name, $method_body);
 252             }
 253         }
 254         if (defined $roles){
 255             Mouse::Util::apply_all_roles($package_name, @{$roles});
 256         }
 257
 258         if($cache_key){
 259             $IMMORTALS{$cache_key} = $meta;
 260         }
 261
 262         return $meta;
 263     }
 264
 265     sub DESTROY{
 266         my($self) = @_;
 267
 268         my $serial_id = $self->{anon_serial_id};
 269
 270         return if !$serial_id;
 271
 272         # @ISA is a magical variable, so we clear it manually.
 273         @{$self->{superclasses}} = () if exists $self->{superclasses};
 274
 275         # Then, clear the symbol table hash
 276         %{$self->namespace} = ();
 277
 278         my $name = $self->name;
 279         delete $METAS{$name};
 280
 281         $name =~ s/ $serial_id \z//xms;
 282
 283         no strict 'refs';
 284         delete ${$name}{ $serial_id . '::' };
 285
 286         return;
 287     }
 288 }
 289
 290 sub throw_error{
 291     my($class, $message, %args) = @_;
 292
 293     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 294     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 295
 296     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 297         Carp::croak($message);
 298     }
 299     else{
 300         Carp::confess($message);
 301     }
 302 }
 303
 304 1;
 305
 306 __END__
 307
 308 =head1 NAME
 309
 310 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 311
 312 =head1 VERSION
 313
 314 This document describes Mouse version 0.40_07
 315
 316 =head1 SEE ALSO
 317
 318 L<Class::MOP::Class>
 319
 320 L<Class::MOP::Module>
 321
 322 L<Class::MOP::Package>
 323
 324 =cut
 325