lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package get_code_ref load_class not_supported/; # enables strict and warnings
   3
   4 use Mouse::Util::TypeConstraints ();
   5
   6 use Carp         ();
   7 use Scalar::Util ();
   8
   9 my %METAS;
  10
  11 sub _metaclass_cache { # DEPRECATED
  12     my($class, $name) = @_;
  13     return $METAS{$name};
  14 }
  15
  16 sub initialize {
  17     my($class, $package_name, @args) = @_;
  18
  19     ($package_name && !ref($package_name))
  20         || $class->throw_error("You must pass a package name and it cannot be blessed");
  21
  22     return $METAS{$package_name}
  23         ||= $class->_construct_meta(package => $package_name, @args);
  24 }
  25
  26 sub class_of{
  27     my($class_or_instance) = @_;
  28     return undef unless defined $class_or_instance;
  29     return $METAS{ ref($class_or_instance) || $class_or_instance };
  30 }
  31
  32 # Means of accessing all the metaclasses that have
  33 # been initialized thus far
  34 #sub get_all_metaclasses         {        %METAS         }
  35 sub get_all_metaclass_instances { values %METAS         }
  36 sub get_all_metaclass_names     { keys   %METAS         }
  37 sub get_metaclass_by_name       { $METAS{$_[0]}         }
  38 #sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  39 #sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  40 #sub does_metaclass_exist        { defined $METAS{$_[0]} }
  41 #sub remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  42
  43 sub name;
  44
  45 sub namespace;
  46
  47 # The followings are Class::MOP specific methods
  48
  49 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  50 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  51 #sub identifier {
  52 #    my $self = shift;
  53 #    return join '-' => (
  54 #       $self->name,
  55 #        ($self->version   || ()),
  56 #        ($self->authority || ()),
  57 #    );
  58 #}
  59
  60 # add_attribute is an abstract method
  61
  62 sub get_attribute_map { # DEPRECATED
  63     Carp::cluck('get_attribute_map() has been deprecated');
  64     return $_[0]->{attributes};
  65 }
  66
  67 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  68 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  69 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  70 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  71
  72 # XXX: for backward compatibility
  73 my %foreign = map{ $_ => undef } qw(
  74     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
  75     Carp Scalar::Util
  76 );
  77 sub _code_is_mine{
  78     my($self, $code) = @_;
  79
  80     my $package = get_code_package($code);
  81
  82     return !exists $foreign{$package};
  83 }
  84
  85 sub add_method;
  86
  87 sub has_method {
  88     my($self, $method_name) = @_;
  89
  90     defined($method_name)
  91         or $self->throw_error('You must define a method name');
  92
  93     return 1 if $self->{methods}{$method_name};
  94
  95     my $code = get_code_ref($self->{package}, $method_name);
  96
  97     return $code && $self->_code_is_mine($code);
  98 }
  99
 100 sub get_method_body{
 101     my($self, $method_name) = @_;
 102
 103     defined($method_name)
 104         or $self->throw_error('You must define a method name');
 105
 106     return $self->{methods}{$method_name} ||= do{
 107         my $code = get_code_ref($self->{package}, $method_name);
 108         ($code && $self->_code_is_mine($code)) ? $code : undef;
 109     };
 110 }
 111
 112 sub get_method{
 113     my($self, $method_name) = @_;
 114
 115     if($self->has_method($method_name)){
 116         my $method_metaclass = $self->method_metaclass;
 117         load_class($method_metaclass);
 118
 119         return $method_metaclass->wrap(
 120             body                 => $self->get_method_body($method_name),
 121             name                 => $method_name,
 122             package              => $self->name,
 123             associated_metaclass => $self,
 124         );
 125     }
 126
 127     return undef;
 128 }
 129
 130 sub get_method_list {
 131     my($self) = @_;
 132
 133     return grep { $self->has_method($_) } keys %{ $self->namespace };
 134 }
 135
 136 {
 137     my $ANON_SERIAL = 0;
 138
 139     my %IMMORTALS;
 140
 141     sub create {
 142         my($self, $package_name, %options) = @_;
 143
 144         my $class = ref($self) || $self;
 145         $self->throw_error('You must pass a package name') if @_ < 2;
 146
 147         my $superclasses;
 148         if(exists $options{superclasses}){
 149             if(Mouse::Util::TypeConstraints::_is_a_metarole($self)){
 150                 delete $options{superclasses};
 151             }
 152             else{
 153                 $superclasses = delete $options{superclasses};
 154                 (ref $superclasses eq 'ARRAY')
 155                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 156             }
 157         }
 158
 159         my $attributes = delete $options{attributes};
 160         if(defined $attributes){
 161             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 162                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 163         }
 164         my $methods = delete $options{methods};
 165         if(defined $methods){
 166             (ref $methods eq 'HASH')
 167                 || $self->throw_error("You must pass a HASH ref of methods");
 168         }
 169         my $roles = delete $options{roles};
 170         if(defined $roles){
 171             (ref $roles eq 'ARRAY')
 172                 || $self->throw_error("You must pass an ARRAY ref of roles");
 173         }
 174         my $mortal;
 175         my $cache_key;
 176
 177         if(!defined $package_name){ # anonymous
 178             $mortal = !$options{cache};
 179
 180             # anonymous but immortal
 181             if(!$mortal){
 182                     # something like Super::Class|Super::Class::2=Role|Role::1
 183                     $cache_key = join '=' => (
 184                         join('|',      @{$superclasses || []}),
 185                         join('|', sort @{$roles        || []}),
 186                     );
 187                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 188             }
 189             $options{anon_serial_id} = ++$ANON_SERIAL;
 190             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 191         }
 192
 193         # instantiate a module
 194         {
 195             no strict 'refs';
 196             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 197             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 198         }
 199
 200         my $meta = $self->initialize( $package_name, %options);
 201
 202         Scalar::Util::weaken $METAS{$package_name}
 203             if $mortal;
 204
 205         $meta->add_method(meta => sub{
 206             $self->initialize(ref($_[0]) || $_[0]);
 207         });
 208
 209         $meta->superclasses(@{$superclasses})
 210             if defined $superclasses;
 211
 212         # NOTE:
 213         # process attributes first, so that they can
 214         # install accessors, but locally defined methods
 215         # can then overwrite them. It is maybe a little odd, but
 216         # I think this should be the order of things.
 217         if (defined $attributes) {
 218             if(ref($attributes) eq 'ARRAY'){
 219                 # array of Mouse::Meta::Attribute
 220                 foreach my $attr (@{$attributes}) {
 221                     $meta->add_attribute($attr);
 222                 }
 223             }
 224             else{
 225                 # hash map of name and attribute spec pairs
 226                 while(my($name, $attr) = each %{$attributes}){
 227                     $meta->add_attribute($name => $attr);
 228                 }
 229             }
 230         }
 231         if (defined $methods) {
 232             while(my($method_name, $method_body) = each %{$methods}){
 233                 $meta->add_method($method_name, $method_body);
 234             }
 235         }
 236         if (defined $roles){
 237             Mouse::Util::apply_all_roles($package_name, @{$roles});
 238         }
 239
 240         if($cache_key){
 241             $IMMORTALS{$cache_key} = $meta;
 242         }
 243
 244         return $meta;
 245     }
 246
 247     sub DESTROY{
 248         my($self) = @_;
 249
 250         my $serial_id = $self->{anon_serial_id};
 251
 252         return if !$serial_id;
 253
 254         # @ISA is a magical variable, so we clear it manually.
 255         @{$self->{superclasses}} = () if exists $self->{superclasses};
 256
 257         # Then, clear the symbol table hash
 258         %{$self->namespace} = ();
 259
 260         my $name = $self->name;
 261         delete $METAS{$name};
 262
 263         $name =~ s/ $serial_id \z//xms;
 264
 265         no strict 'refs';
 266         delete ${$name}{ $serial_id . '::' };
 267
 268         return;
 269     }
 270 }
 271
 272 sub throw_error{
 273     my($class, $message, %args) = @_;
 274
 275     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 276     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 277
 278     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 279         Carp::croak($message);
 280     }
 281     else{
 282         Carp::confess($message);
 283     }
 284 }
 285
 286 1;
 287
 288 __END__
 289
 290 =head1 NAME
 291
 292 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 293
 294 =head1 VERSION
 295
 296 This document describes Mouse version 0.40_01
 297
 298 =head1 SEE ALSO
 299
 300 L<Class::MOP::Class>
 301
 302 L<Class::MOP::Module>
 303
 304 L<Class::MOP::Package>
 305
 306 =cut
 307