lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package load_class not_supported/; # enables strict and warnings
   3
   4 use Carp ();
   5 use Scalar::Util qw/blessed weaken/;
   6
   7 my %METAS;
   8
   9 sub _metaclass_cache { # DEPRECATED
  10     my($class, $name) = @_;
  11     return $METAS{$name};
  12 }
  13
  14 sub initialize {
  15     my($class, $package_name, @args) = @_;
  16
  17     ($package_name && !ref($package_name))
  18         || $class->throw_error("You must pass a package name and it cannot be blessed");
  19
  20     return $METAS{$package_name}
  21         ||= $class->_construct_meta(package => $package_name, @args);
  22 }
  23
  24 sub class_of{
  25     my($class_or_instance) = @_;
  26     return undef unless defined $class_or_instance;
  27     return $METAS{ ref($class_or_instance) || $class_or_instance };
  28 }
  29
  30 # Means of accessing all the metaclasses that have
  31 # been initialized thus far
  32 #sub get_all_metaclasses         {        %METAS         }
  33 sub get_all_metaclass_instances { values %METAS         }
  34 sub get_all_metaclass_names     { keys   %METAS         }
  35 sub get_metaclass_by_name       { $METAS{$_[0]}         }
  36 #sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  37 #sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  38 #sub does_metaclass_exist        { defined $METAS{$_[0]} }
  39 #sub remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  40
  41
  42
  43 sub name { $_[0]->{package} }
  44
  45 # The followings are Class::MOP specific methods
  46
  47 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  48 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  49 #sub identifier {
  50 #    my $self = shift;
  51 #    return join '-' => (
  52 #       $self->name,
  53 #        ($self->version   || ()),
  54 #        ($self->authority || ()),
  55 #    );
  56 #}
  57
  58 # add_attribute is an abstract method
  59
  60 sub get_attribute_map { # DEPRECATED
  61     Carp::cluck('get_attribute_map() has been deprecated');
  62     return $_[0]->{attributes};
  63 }
  64
  65 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  66 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  67 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  68 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  69
  70 sub namespace{
  71     my $name = $_[0]->{package};
  72     no strict 'refs';
  73     return \%{ $name . '::' };
  74 }
  75
  76 sub add_method {
  77     my($self, $name, $code) = @_;
  78
  79     if(!defined $name){
  80         $self->throw_error('You must pass a defined name');
  81     }
  82     if(!defined $code){
  83         $self->throw_error('You must pass a defined code');
  84     }
  85
  86     if(ref($code) ne 'CODE'){
  87         $code = \&{$code}; # coerce
  88     }
  89
  90     $self->{methods}->{$name} = $code; # Moose stores meta object here.
  91
  92     my $pkg = $self->name;
  93     no strict 'refs';
  94     no warnings 'redefine';
  95     *{ $pkg . '::' . $name } = $code;
  96 }
  97
  98 # XXX: for backward compatibility
  99 my %foreign = map{ $_ => undef } qw(
 100     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
 101     Carp Scalar::Util
 102 );
 103 sub _code_is_mine{
 104     my($self, $code) = @_;
 105
 106     my $package = get_code_package($code);
 107
 108     return !exists $foreign{$package};
 109 }
 110
 111 sub has_method {
 112     my($self, $method_name) = @_;
 113
 114     defined($method_name)
 115         or $self->throw_error('You must define a method name');
 116
 117     return 1 if $self->{methods}{$method_name};
 118
 119     my $code = do{
 120         no strict 'refs';
 121         *{ $self->{package} . '::' . $method_name }{CODE};
 122     };
 123
 124     return $code && $self->_code_is_mine($code);
 125 }
 126
 127 sub get_method_body{
 128     my($self, $method_name) = @_;
 129
 130     defined($method_name)
 131         or $self->throw_error('You must define a method name');
 132
 133     return $self->{methods}{$method_name} ||= do{
 134         my $code = do{ no strict 'refs'; *{$self->{package} . '::' . $method_name}{CODE} };
 135
 136         ($code && $self->_code_is_mine($code)) ? $code : undef;
 137     };
 138 }
 139
 140 sub get_method{
 141     my($self, $method_name) = @_;
 142
 143     if($self->has_method($method_name)){
 144         my $method_metaclass = $self->method_metaclass;
 145         load_class($method_metaclass);
 146
 147         my $package = $self->name;
 148         return $method_metaclass->new(
 149             body    => $package->can($method_name),
 150             name    => $method_name,
 151             package => $package,
 152         );
 153     }
 154
 155     return undef;
 156 }
 157
 158 sub get_method_list {
 159     my($self) = @_;
 160
 161     return grep { $self->has_method($_) } keys %{ $self->namespace };
 162 }
 163
 164 {
 165     my $ANON_SERIAL = 0;
 166
 167     my %IMMORTALS;
 168
 169     sub create {
 170         my($self, $package_name, %options) = @_;
 171
 172         my $class = ref($self) || $self;
 173         $self->throw_error('You must pass a package name') if @_ < 2;
 174
 175         my $superclasses;
 176         if(exists $options{superclasses}){
 177             if($self->isa('Mouse::Meta::Role')){
 178                 delete $options{superclasses};
 179             }
 180             else{
 181                 $superclasses = delete $options{superclasses};
 182                 (ref $superclasses eq 'ARRAY')
 183                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 184             }
 185         }
 186
 187         my $attributes = delete $options{attributes};
 188         if(defined $attributes){
 189             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 190                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 191         }
 192         my $methods = delete $options{methods};
 193         if(defined $methods){
 194             (ref $methods eq 'HASH')
 195                 || $self->throw_error("You must pass a HASH ref of methods");
 196         }
 197         my $roles = delete $options{roles};
 198         if(defined $roles){
 199             (ref $roles eq 'ARRAY')
 200                 || $self->throw_error("You must pass an ARRAY ref of roles");
 201         }
 202         my $mortal;
 203         my $cache_key;
 204
 205         if(!defined $package_name){ # anonymous
 206             $mortal = !$options{cache};
 207
 208             # anonymous but immortal
 209             if(!$mortal){
 210                     # something like Super::Class|Super::Class::2=Role|Role::1
 211                     $cache_key = join '=' => (
 212                         join('|',      @{$superclasses || []}),
 213                         join('|', sort @{$roles        || []}),
 214                     );
 215                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 216             }
 217             $options{anon_serial_id} = ++$ANON_SERIAL;
 218             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 219         }
 220
 221         # instantiate a module
 222         {
 223             no strict 'refs';
 224             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 225             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 226         }
 227
 228         my $meta = $self->initialize( $package_name, %options);
 229
 230         weaken $METAS{$package_name}
 231             if $mortal;
 232
 233         $meta->add_method(meta => sub{
 234             $self->initialize(ref($_[0]) || $_[0]);
 235         });
 236
 237         $meta->superclasses(@{$superclasses})
 238             if defined $superclasses;
 239
 240         # NOTE:
 241         # process attributes first, so that they can
 242         # install accessors, but locally defined methods
 243         # can then overwrite them. It is maybe a little odd, but
 244         # I think this should be the order of things.
 245         if (defined $attributes) {
 246             if(ref($attributes) eq 'ARRAY'){
 247                 # array of Mouse::Meta::Attribute
 248                 foreach my $attr (@{$attributes}) {
 249                     $meta->add_attribute($attr);
 250                 }
 251             }
 252             else{
 253                 # hash map of name and attribute spec pairs
 254                 while(my($name, $attr) = each %{$attributes}){
 255                     $meta->add_attribute($name => $attr);
 256                 }
 257             }
 258         }
 259         if (defined $methods) {
 260             while(my($method_name, $method_body) = each %{$methods}){
 261                 $meta->add_method($method_name, $method_body);
 262             }
 263         }
 264         if (defined $roles){
 265             Mouse::Util::apply_all_roles($package_name, @{$roles});
 266         }
 267
 268         if($cache_key){
 269             $IMMORTALS{$cache_key} = $meta;
 270         }
 271
 272         return $meta;
 273     }
 274
 275     sub DESTROY{
 276         my($self) = @_;
 277
 278         my $serial_id = $self->{anon_serial_id};
 279
 280         return if !$serial_id;
 281
 282         # @ISA is a magical variable, so we clear it manually.
 283         @{$self->{superclasses}} = () if exists $self->{superclasses};
 284
 285         # Then, clear the symbol table hash
 286         %{$self->namespace} = ();
 287
 288         my $name = $self->name;
 289         delete $METAS{$name};
 290
 291         $name =~ s/ $serial_id \z//xms;
 292
 293         no strict 'refs';
 294         delete ${$name}{ $serial_id . '::' };
 295
 296         return;
 297     }
 298 }
 299
 300 sub throw_error{
 301     my($class, $message, %args) = @_;
 302
 303     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 304     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 305
 306     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 307         Carp::croak($message);
 308     }
 309     else{
 310         Carp::confess($message);
 311     }
 312 }
 313
 314 1;
 315
 316 __END__
 317
 318 =head1 NAME
 319
 320 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 321
 322 =head1 SEE ALSO
 323
 324 L<Class::MOP::Class>
 325
 326 L<Class::MOP::Module>
 327
 328 L<Class::MOP::Package>
 329
 330 =cut
 331