lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package get_code_ref load_class not_supported/; # enables strict and warnings
   3
   4 use Carp         ();
   5 use Scalar::Util ();
   6
   7 my %METAS;
   8
   9 if(Mouse::Util::MOUSE_XS){
  10     # register meta storage for performance
  11     Mouse::Util::__register_metaclass_storage(\%METAS, 0);
  12
  13     # ensure thread safety
  14     *CLONE = sub { Mouse::Util::__register_metaclass_storage(\%METAS, 1) };
  15 }
  16
  17 sub _metaclass_cache { # DEPRECATED
  18     my($class, $name) = @_;
  19     return $METAS{$name};
  20 }
  21
  22 sub initialize {
  23     my($class, $package_name, @args) = @_;
  24
  25     ($package_name && !ref($package_name))
  26         || $class->throw_error("You must pass a package name and it cannot be blessed");
  27
  28     return $METAS{$package_name}
  29         ||= $class->_construct_meta(package => $package_name, @args);
  30 }
  31
  32 sub reinitialize {
  33     my($class, $package_name, @args) = @_;
  34
  35     $package_name = $package_name->name if ref $package_name;
  36
  37     ($package_name && !ref($package_name))
  38         || $class->throw_error("You must pass a package name and it cannot be blessed");
  39
  40     delete $METAS{$package_name};
  41     return $class->initialize($package_name, @args);
  42 }
  43
  44 sub _class_of{
  45     my($class_or_instance) = @_;
  46     return undef unless defined $class_or_instance;
  47     return $METAS{ ref($class_or_instance) || $class_or_instance };
  48 }
  49
  50 # Means of accessing all the metaclasses that have
  51 # been initialized thus far
  52 #sub _get_all_metaclasses         {        %METAS         }
  53 sub _get_all_metaclass_instances { values %METAS         }
  54 sub _get_all_metaclass_names     { keys   %METAS         }
  55 sub _get_metaclass_by_name       { $METAS{$_[0]}         }
  56 #sub _store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  57 #sub _weaken_metaclass            { weaken($METAS{$_[0]}) }
  58 #sub _does_metaclass_exist        { defined $METAS{$_[0]} }
  59 #sub _remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  60
  61 sub name;
  62
  63 sub namespace;
  64
  65 # The followings are Class::MOP specific methods
  66
  67 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  68 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  69 #sub identifier {
  70 #    my $self = shift;
  71 #    return join '-' => (
  72 #       $self->name,
  73 #        ($self->version   || ()),
  74 #        ($self->authority || ()),
  75 #    );
  76 #}
  77
  78 # add_attribute is an abstract method
  79
  80 sub get_attribute_map { # DEPRECATED
  81     Carp::cluck('get_attribute_map() has been deprecated');
  82     return $_[0]->{attributes};
  83 }
  84
  85 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  86 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  87 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  88
  89 sub get_attribute_list{ keys   %{$_[0]->{attributes}} }
  90
  91 # XXX: for backward compatibility
  92 my %foreign = map{ $_ => undef } qw(
  93     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
  94     Carp Scalar::Util List::Util
  95 );
  96 sub _code_is_mine{
  97 #    my($self, $code) = @_;
  98
  99     return !exists $foreign{ get_code_package($_[1]) };
 100 }
 101
 102 sub add_method;
 103
 104 sub has_method {
 105     my($self, $method_name) = @_;
 106
 107     defined($method_name)
 108         or $self->throw_error('You must define a method name');
 109
 110     return defined($self->{methods}{$method_name}) || do{
 111         my $code = get_code_ref($self->{package}, $method_name);
 112         $code && $self->_code_is_mine($code);
 113     };
 114 }
 115
 116 sub get_method_body {
 117     my($self, $method_name) = @_;
 118
 119     defined($method_name)
 120         or $self->throw_error('You must define a method name');
 121
 122     return $self->{methods}{$method_name} ||= do{
 123         my $code = get_code_ref($self->{package}, $method_name);
 124         $code && $self->_code_is_mine($code) ? $code : undef;
 125     };
 126 }
 127
 128 sub get_method{
 129     my($self, $method_name) = @_;
 130
 131     if(my $code = $self->get_method_body($method_name)){
 132         my $method_metaclass = $self->method_metaclass;
 133         load_class($method_metaclass);
 134
 135         return $method_metaclass->wrap(
 136             body                 => $code,
 137             name                 => $method_name,
 138             package              => $self->name,
 139             associated_metaclass => $self,
 140         );
 141     }
 142
 143     return undef;
 144 }
 145
 146 sub get_method_list {
 147     my($self) = @_;
 148
 149     return grep { $self->has_method($_) } keys %{ $self->namespace };
 150 }
 151
 152 {
 153     my $ANON_SERIAL = 0;
 154
 155     my %IMMORTALS;
 156
 157     sub create {
 158         my($self, $package_name, %options) = @_;
 159
 160         my $class = ref($self) || $self;
 161         $self->throw_error('You must pass a package name') if @_ < 2;
 162
 163         my $superclasses;
 164         if(exists $options{superclasses}){
 165             if(Mouse::Util::is_a_metarole($self)){
 166                 delete $options{superclasses};
 167             }
 168             else{
 169                 $superclasses = delete $options{superclasses};
 170                 (ref $superclasses eq 'ARRAY')
 171                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 172             }
 173         }
 174
 175         my $attributes = delete $options{attributes};
 176         if(defined $attributes){
 177             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 178                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 179         }
 180         my $methods = delete $options{methods};
 181         if(defined $methods){
 182             (ref $methods eq 'HASH')
 183                 || $self->throw_error("You must pass a HASH ref of methods");
 184         }
 185         my $roles = delete $options{roles};
 186         if(defined $roles){
 187             (ref $roles eq 'ARRAY')
 188                 || $self->throw_error("You must pass an ARRAY ref of roles");
 189         }
 190         my $mortal;
 191         my $cache_key;
 192
 193         if(!defined $package_name){ # anonymous
 194             $mortal = !$options{cache};
 195
 196             # anonymous but immortal
 197             if(!$mortal){
 198                     # something like Super::Class|Super::Class::2=Role|Role::1
 199                     $cache_key = join '=' => (
 200                         join('|',      @{$superclasses || []}),
 201                         join('|', sort @{$roles        || []}),
 202                     );
 203                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 204             }
 205             $options{anon_serial_id} = ++$ANON_SERIAL;
 206             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 207         }
 208
 209         # instantiate a module
 210         {
 211             no strict 'refs';
 212             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 213             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 214         }
 215
 216         my $meta = $self->initialize( $package_name, %options);
 217
 218         Scalar::Util::weaken $METAS{$package_name}
 219             if $mortal;
 220
 221         $meta->add_method(meta => sub{
 222             $self->initialize(ref($_[0]) || $_[0]);
 223         });
 224
 225         $meta->superclasses(@{$superclasses})
 226             if defined $superclasses;
 227
 228         # NOTE:
 229         # process attributes first, so that they can
 230         # install accessors, but locally defined methods
 231         # can then overwrite them. It is maybe a little odd, but
 232         # I think this should be the order of things.
 233         if (defined $attributes) {
 234             if(ref($attributes) eq 'ARRAY'){
 235                 # array of Mouse::Meta::Attribute
 236                 foreach my $attr (@{$attributes}) {
 237                     $meta->add_attribute($attr);
 238                 }
 239             }
 240             else{
 241                 # hash map of name and attribute spec pairs
 242                 while(my($name, $attr) = each %{$attributes}){
 243                     $meta->add_attribute($name => $attr);
 244                 }
 245             }
 246         }
 247         if (defined $methods) {
 248             while(my($method_name, $method_body) = each %{$methods}){
 249                 $meta->add_method($method_name, $method_body);
 250             }
 251         }
 252         if (defined $roles){
 253             Mouse::Util::apply_all_roles($package_name, @{$roles});
 254         }
 255
 256         if($cache_key){
 257             $IMMORTALS{$cache_key} = $meta;
 258         }
 259
 260         return $meta;
 261     }
 262
 263     sub DESTROY{
 264         my($self) = @_;
 265
 266         return if $Mouse::Util::in_global_destruction;
 267
 268         my $serial_id = $self->{anon_serial_id};
 269
 270         return if !$serial_id;
 271
 272         # @ISA is a magical variable, so we clear it manually.
 273         @{$self->{superclasses}} = () if exists $self->{superclasses};
 274
 275         # Then, clear the symbol table hash
 276         %{$self->namespace} = ();
 277
 278         my $name = $self->name;
 279         delete $METAS{$name};
 280
 281         $name =~ s/ $serial_id \z//xms;
 282
 283         no strict 'refs';
 284         delete ${$name}{ $serial_id . '::' };
 285
 286         return;
 287     }
 288 }
 289
 290 sub throw_error{
 291     my($class, $message, %args) = @_;
 292
 293     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 294     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 295
 296     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 297         Carp::croak($message);
 298     }
 299     else{
 300         Carp::confess($message);
 301     }
 302 }
 303
 304 1;
 305 __END__
 306
 307 =head1 NAME
 308
 309 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 310
 311 =head1 VERSION
 312
 313 This document describes Mouse version 0.4501
 314
 315 =head1 SEE ALSO
 316
 317 L<Class::MOP::Class>
 318
 319 L<Class::MOP::Module>
 320
 321 L<Class::MOP::Package>
 322
 323 =cut
 324