lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package get_code_ref load_class not_supported/; # enables strict and warnings
   3
   4 use Mouse::Util::TypeConstraints ();
   5
   6 use Carp ();
   7 use Scalar::Util qw/blessed weaken/;
   8
   9 my %METAS;
  10
  11 sub _metaclass_cache { # DEPRECATED
  12     my($class, $name) = @_;
  13     return $METAS{$name};
  14 }
  15
  16 sub initialize {
  17     my($class, $package_name, @args) = @_;
  18
  19     ($package_name && !ref($package_name))
  20         || $class->throw_error("You must pass a package name and it cannot be blessed");
  21
  22     return $METAS{$package_name}
  23         ||= $class->_construct_meta(package => $package_name, @args);
  24 }
  25
  26 sub class_of{
  27     my($class_or_instance) = @_;
  28     return undef unless defined $class_or_instance;
  29     return $METAS{ ref($class_or_instance) || $class_or_instance };
  30 }
  31
  32 # Means of accessing all the metaclasses that have
  33 # been initialized thus far
  34 #sub get_all_metaclasses         {        %METAS         }
  35 sub get_all_metaclass_instances { values %METAS         }
  36 sub get_all_metaclass_names     { keys   %METAS         }
  37 sub get_metaclass_by_name       { $METAS{$_[0]}         }
  38 #sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  39 #sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  40 #sub does_metaclass_exist        { defined $METAS{$_[0]} }
  41 #sub remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  42
  43 sub name;
  44
  45 sub namespace;
  46
  47 # The followings are Class::MOP specific methods
  48
  49 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  50 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  51 #sub identifier {
  52 #    my $self = shift;
  53 #    return join '-' => (
  54 #       $self->name,
  55 #        ($self->version   || ()),
  56 #        ($self->authority || ()),
  57 #    );
  58 #}
  59
  60 # add_attribute is an abstract method
  61
  62 sub get_attribute_map { # DEPRECATED
  63     Carp::cluck('get_attribute_map() has been deprecated');
  64     return $_[0]->{attributes};
  65 }
  66
  67 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  68 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  69 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  70 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  71
  72 sub add_method {
  73     my($self, $name, $code) = @_;
  74
  75     if(!defined $name){
  76         $self->throw_error('You must pass a defined name');
  77     }
  78     if(!defined $code){
  79         $self->throw_error('You must pass a defined code');
  80     }
  81
  82     if(ref($code) ne 'CODE'){
  83         $code = \&{$code}; # coerce
  84     }
  85
  86     $self->{methods}->{$name} = $code; # Moose stores meta object here.
  87
  88     my $pkg = $self->name;
  89     no strict 'refs';
  90     no warnings 'redefine', 'once';
  91     *{ $pkg . '::' . $name } = $code;
  92 }
  93
  94 # XXX: for backward compatibility
  95 my %foreign = map{ $_ => undef } qw(
  96     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
  97     Carp Scalar::Util
  98 );
  99 sub _code_is_mine{
 100     my($self, $code) = @_;
 101
 102     my $package = get_code_package($code);
 103
 104     return !exists $foreign{$package};
 105 }
 106
 107 sub has_method {
 108     my($self, $method_name) = @_;
 109
 110     defined($method_name)
 111         or $self->throw_error('You must define a method name');
 112
 113     return 1 if $self->{methods}{$method_name};
 114
 115     my $code = get_code_ref($self->{package}, $method_name);
 116
 117     return $code && $self->_code_is_mine($code);
 118 }
 119
 120 sub get_method_body{
 121     my($self, $method_name) = @_;
 122
 123     defined($method_name)
 124         or $self->throw_error('You must define a method name');
 125
 126     return $self->{methods}{$method_name} ||= do{
 127         my $code = get_code_ref($self->{package}, $method_name);
 128         ($code && $self->_code_is_mine($code)) ? $code : undef;
 129     };
 130 }
 131
 132 sub get_method{
 133     my($self, $method_name) = @_;
 134
 135     if($self->has_method($method_name)){
 136         my $method_metaclass = $self->method_metaclass;
 137         load_class($method_metaclass);
 138
 139         return $method_metaclass->wrap(
 140             body                 => $self->get_method_body($method_name),
 141             name                 => $method_name,
 142             package              => $self->name,
 143             associated_metaclass => $self,
 144         );
 145     }
 146
 147     return undef;
 148 }
 149
 150 sub get_method_list {
 151     my($self) = @_;
 152
 153     return grep { $self->has_method($_) } keys %{ $self->namespace };
 154 }
 155
 156 {
 157     my $ANON_SERIAL = 0;
 158
 159     my %IMMORTALS;
 160
 161     sub create {
 162         my($self, $package_name, %options) = @_;
 163
 164         my $class = ref($self) || $self;
 165         $self->throw_error('You must pass a package name') if @_ < 2;
 166
 167         my $superclasses;
 168         if(exists $options{superclasses}){
 169             if(Mouse::Util::TypeConstraints::_is_a_metarole($self)){
 170                 delete $options{superclasses};
 171             }
 172             else{
 173                 $superclasses = delete $options{superclasses};
 174                 (ref $superclasses eq 'ARRAY')
 175                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 176             }
 177         }
 178
 179         my $attributes = delete $options{attributes};
 180         if(defined $attributes){
 181             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 182                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 183         }
 184         my $methods = delete $options{methods};
 185         if(defined $methods){
 186             (ref $methods eq 'HASH')
 187                 || $self->throw_error("You must pass a HASH ref of methods");
 188         }
 189         my $roles = delete $options{roles};
 190         if(defined $roles){
 191             (ref $roles eq 'ARRAY')
 192                 || $self->throw_error("You must pass an ARRAY ref of roles");
 193         }
 194         my $mortal;
 195         my $cache_key;
 196
 197         if(!defined $package_name){ # anonymous
 198             $mortal = !$options{cache};
 199
 200             # anonymous but immortal
 201             if(!$mortal){
 202                     # something like Super::Class|Super::Class::2=Role|Role::1
 203                     $cache_key = join '=' => (
 204                         join('|',      @{$superclasses || []}),
 205                         join('|', sort @{$roles        || []}),
 206                     );
 207                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 208             }
 209             $options{anon_serial_id} = ++$ANON_SERIAL;
 210             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 211         }
 212
 213         # instantiate a module
 214         {
 215             no strict 'refs';
 216             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 217             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 218         }
 219
 220         my $meta = $self->initialize( $package_name, %options);
 221
 222         weaken $METAS{$package_name}
 223             if $mortal;
 224
 225         $meta->add_method(meta => sub{
 226             $self->initialize(ref($_[0]) || $_[0]);
 227         });
 228
 229         $meta->superclasses(@{$superclasses})
 230             if defined $superclasses;
 231
 232         # NOTE:
 233         # process attributes first, so that they can
 234         # install accessors, but locally defined methods
 235         # can then overwrite them. It is maybe a little odd, but
 236         # I think this should be the order of things.
 237         if (defined $attributes) {
 238             if(ref($attributes) eq 'ARRAY'){
 239                 # array of Mouse::Meta::Attribute
 240                 foreach my $attr (@{$attributes}) {
 241                     $meta->add_attribute($attr);
 242                 }
 243             }
 244             else{
 245                 # hash map of name and attribute spec pairs
 246                 while(my($name, $attr) = each %{$attributes}){
 247                     $meta->add_attribute($name => $attr);
 248                 }
 249             }
 250         }
 251         if (defined $methods) {
 252             while(my($method_name, $method_body) = each %{$methods}){
 253                 $meta->add_method($method_name, $method_body);
 254             }
 255         }
 256         if (defined $roles){
 257             Mouse::Util::apply_all_roles($package_name, @{$roles});
 258         }
 259
 260         if($cache_key){
 261             $IMMORTALS{$cache_key} = $meta;
 262         }
 263
 264         return $meta;
 265     }
 266
 267     sub DESTROY{
 268         my($self) = @_;
 269
 270         my $serial_id = $self->{anon_serial_id};
 271
 272         return if !$serial_id;
 273
 274         # @ISA is a magical variable, so we clear it manually.
 275         @{$self->{superclasses}} = () if exists $self->{superclasses};
 276
 277         # Then, clear the symbol table hash
 278         %{$self->namespace} = ();
 279
 280         my $name = $self->name;
 281         delete $METAS{$name};
 282
 283         $name =~ s/ $serial_id \z//xms;
 284
 285         no strict 'refs';
 286         delete ${$name}{ $serial_id . '::' };
 287
 288         return;
 289     }
 290 }
 291
 292 sub throw_error{
 293     my($class, $message, %args) = @_;
 294
 295     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 296     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 297
 298     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 299         Carp::croak($message);
 300     }
 301     else{
 302         Carp::confess($message);
 303     }
 304 }
 305
 306 1;
 307
 308 __END__
 309
 310 =head1 NAME
 311
 312 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 313
 314 =head1 VERSION
 315
 316 This document describes Mouse version 0.40_01
 317
 318 =head1 SEE ALSO
 319
 320 L<Class::MOP::Class>
 321
 322 L<Class::MOP::Module>
 323
 324 L<Class::MOP::Package>
 325
 326 =cut
 327