lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package load_class not_supported/; # enables strict and warnings
   3
   4 use Carp ();
   5 use Scalar::Util qw/blessed weaken/;
   6
   7 my %METAS;
   8
   9 sub _metaclass_cache { # DEPRECATED
  10     my($class, $name) = @_;
  11     return $METAS{$name};
  12 }
  13
  14 sub initialize {
  15     my($class, $package_name, @args) = @_;
  16
  17     ($package_name && !ref($package_name))
  18         || $class->throw_error("You must pass a package name and it cannot be blessed");
  19
  20     return $METAS{$package_name}
  21         ||= $class->_construct_meta(package => $package_name, @args);
  22 }
  23
  24 sub class_of{
  25     my($class_or_instance) = @_;
  26     return undef unless defined $class_or_instance;
  27     return $METAS{ ref($class_or_instance) || $class_or_instance };
  28 }
  29
  30 # Means of accessing all the metaclasses that have
  31 # been initialized thus far
  32 #sub get_all_metaclasses         {        %METAS         }
  33 sub get_all_metaclass_instances { values %METAS         }
  34 sub get_all_metaclass_names     { keys   %METAS         }
  35 sub get_metaclass_by_name       { $METAS{$_[0]}         }
  36 #sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  37 #sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  38 #sub does_metaclass_exist        { defined $METAS{$_[0]} }
  39 #sub remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  40
  41
  42
  43 sub name { $_[0]->{package} }
  44
  45 # The followings are Class::MOP specific methods
  46
  47 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  48 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  49 #sub identifier {
  50 #    my $self = shift;
  51 #    return join '-' => (
  52 #       $self->name,
  53 #        ($self->version   || ()),
  54 #        ($self->authority || ()),
  55 #    );
  56 #}
  57
  58 # add_attribute is an abstract method
  59
  60 sub get_attribute_map { # DEPRECATED
  61     Carp::cluck('get_attribute_map() has been deprecated');
  62     return $_[0]->{attributes};
  63 }
  64
  65 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  66 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  67 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  68 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  69
  70 sub namespace{
  71     my $name = $_[0]->{package};
  72     no strict 'refs';
  73     return \%{ $name . '::' };
  74 }
  75
  76 sub add_method {
  77     my($self, $name, $code) = @_;
  78
  79     if(!defined $name){
  80         $self->throw_error('You must pass a defined name');
  81     }
  82     if(!defined $code){
  83         $self->throw_error('You must pass a defined code');
  84     }
  85
  86     if(ref($code) ne 'CODE'){
  87         $code = \&{$code}; # coerce
  88     }
  89
  90     $self->{methods}->{$name} = $code; # Moose stores meta object here.
  91
  92     my $pkg = $self->name;
  93     no strict 'refs';
  94     no warnings 'redefine', 'once';
  95     *{ $pkg . '::' . $name } = $code;
  96 }
  97
  98 # XXX: for backward compatibility
  99 my %foreign = map{ $_ => undef } qw(
 100     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
 101     Carp Scalar::Util
 102 );
 103 sub _code_is_mine{
 104     my($self, $code) = @_;
 105
 106     my $package = get_code_package($code);
 107
 108     return !exists $foreign{$package};
 109 }
 110
 111 sub has_method {
 112     my($self, $method_name) = @_;
 113
 114     defined($method_name)
 115         or $self->throw_error('You must define a method name');
 116
 117     return 1 if $self->{methods}{$method_name};
 118
 119     my $code = do{
 120         no strict 'refs';
 121         no warnings 'once';
 122         *{ $self->{package} . '::' . $method_name }{CODE};
 123     };
 124
 125     return $code && $self->_code_is_mine($code);
 126 }
 127
 128 sub get_method_body{
 129     my($self, $method_name) = @_;
 130
 131     defined($method_name)
 132         or $self->throw_error('You must define a method name');
 133
 134     return $self->{methods}{$method_name} ||= do{
 135         my $code = do{
 136             no strict 'refs';
 137             no warnings 'once';
 138             *{$self->{package} . '::' . $method_name}{CODE};
 139         };
 140
 141         ($code && $self->_code_is_mine($code)) ? $code : undef;
 142     };
 143 }
 144
 145 sub get_method{
 146     my($self, $method_name) = @_;
 147
 148     if($self->has_method($method_name)){
 149         my $method_metaclass = $self->method_metaclass;
 150         load_class($method_metaclass);
 151
 152         return $method_metaclass->wrap(
 153             body                 => $self->get_method_body($method_name),
 154             name                 => $method_name,
 155             package              => $self->name,
 156             associated_metaclass => $self,
 157         );
 158     }
 159
 160     return undef;
 161 }
 162
 163 sub get_method_list {
 164     my($self) = @_;
 165
 166     return grep { $self->has_method($_) } keys %{ $self->namespace };
 167 }
 168
 169 {
 170     my $ANON_SERIAL = 0;
 171
 172     my %IMMORTALS;
 173
 174     sub create {
 175         my($self, $package_name, %options) = @_;
 176
 177         my $class = ref($self) || $self;
 178         $self->throw_error('You must pass a package name') if @_ < 2;
 179
 180         my $superclasses;
 181         if(exists $options{superclasses}){
 182             if($self->isa('Mouse::Meta::Role')){
 183                 delete $options{superclasses};
 184             }
 185             else{
 186                 $superclasses = delete $options{superclasses};
 187                 (ref $superclasses eq 'ARRAY')
 188                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 189             }
 190         }
 191
 192         my $attributes = delete $options{attributes};
 193         if(defined $attributes){
 194             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 195                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 196         }
 197         my $methods = delete $options{methods};
 198         if(defined $methods){
 199             (ref $methods eq 'HASH')
 200                 || $self->throw_error("You must pass a HASH ref of methods");
 201         }
 202         my $roles = delete $options{roles};
 203         if(defined $roles){
 204             (ref $roles eq 'ARRAY')
 205                 || $self->throw_error("You must pass an ARRAY ref of roles");
 206         }
 207         my $mortal;
 208         my $cache_key;
 209
 210         if(!defined $package_name){ # anonymous
 211             $mortal = !$options{cache};
 212
 213             # anonymous but immortal
 214             if(!$mortal){
 215                     # something like Super::Class|Super::Class::2=Role|Role::1
 216                     $cache_key = join '=' => (
 217                         join('|',      @{$superclasses || []}),
 218                         join('|', sort @{$roles        || []}),
 219                     );
 220                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 221             }
 222             $options{anon_serial_id} = ++$ANON_SERIAL;
 223             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 224         }
 225
 226         # instantiate a module
 227         {
 228             no strict 'refs';
 229             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 230             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 231         }
 232
 233         my $meta = $self->initialize( $package_name, %options);
 234
 235         weaken $METAS{$package_name}
 236             if $mortal;
 237
 238         $meta->add_method(meta => sub{
 239             $self->initialize(ref($_[0]) || $_[0]);
 240         });
 241
 242         $meta->superclasses(@{$superclasses})
 243             if defined $superclasses;
 244
 245         # NOTE:
 246         # process attributes first, so that they can
 247         # install accessors, but locally defined methods
 248         # can then overwrite them. It is maybe a little odd, but
 249         # I think this should be the order of things.
 250         if (defined $attributes) {
 251             if(ref($attributes) eq 'ARRAY'){
 252                 # array of Mouse::Meta::Attribute
 253                 foreach my $attr (@{$attributes}) {
 254                     $meta->add_attribute($attr);
 255                 }
 256             }
 257             else{
 258                 # hash map of name and attribute spec pairs
 259                 while(my($name, $attr) = each %{$attributes}){
 260                     $meta->add_attribute($name => $attr);
 261                 }
 262             }
 263         }
 264         if (defined $methods) {
 265             while(my($method_name, $method_body) = each %{$methods}){
 266                 $meta->add_method($method_name, $method_body);
 267             }
 268         }
 269         if (defined $roles){
 270             Mouse::Util::apply_all_roles($package_name, @{$roles});
 271         }
 272
 273         if($cache_key){
 274             $IMMORTALS{$cache_key} = $meta;
 275         }
 276
 277         return $meta;
 278     }
 279
 280     sub DESTROY{
 281         my($self) = @_;
 282
 283         my $serial_id = $self->{anon_serial_id};
 284
 285         return if !$serial_id;
 286
 287         # @ISA is a magical variable, so we clear it manually.
 288         @{$self->{superclasses}} = () if exists $self->{superclasses};
 289
 290         # Then, clear the symbol table hash
 291         %{$self->namespace} = ();
 292
 293         my $name = $self->name;
 294         delete $METAS{$name};
 295
 296         $name =~ s/ $serial_id \z//xms;
 297
 298         no strict 'refs';
 299         delete ${$name}{ $serial_id . '::' };
 300
 301         return;
 302     }
 303 }
 304
 305 sub throw_error{
 306     my($class, $message, %args) = @_;
 307
 308     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 309     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 310
 311     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 312         Carp::croak($message);
 313     }
 314     else{
 315         Carp::confess($message);
 316     }
 317 }
 318
 319 1;
 320
 321 __END__
 322
 323 =head1 NAME
 324
 325 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 326
 327 =head1 VERSION
 328
 329 This document describes Mouse version 0.40
 330
 331 =head1 SEE ALSO
 332
 333 L<Class::MOP::Class>
 334
 335 L<Class::MOP::Module>
 336
 337 L<Class::MOP::Package>
 338
 339 =cut
 340