lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6 use Scalar::Util qw/blessed weaken/;
   7
   8 use Mouse::Util qw/get_code_info not_supported load_class/;
   9
  10 {
  11     my %METACLASS_CACHE;
  12
  13     # because Mouse doesn't introspect existing classes, we're forced to
  14     # only pay attention to other Mouse classes
  15     sub _metaclass_cache {
  16         my($class, $name) = @_;
  17         return $METACLASS_CACHE{$name};
  18     }
  19
  20     sub initialize {
  21         my($class, $package_name, @args) = @_;
  22
  23         ($package_name && !ref($package_name))
  24             || $class->throw_error("You must pass a package name and it cannot be blessed");
  25
  26         return $METACLASS_CACHE{$package_name}
  27             ||= $class->_construct_meta(package => $package_name, @args);
  28     }
  29
  30     sub class_of{
  31         my($class_or_instance) = @_;
  32         return undef unless defined $class_or_instance;
  33         return $METACLASS_CACHE{ blessed($class_or_instance) || $class_or_instance };
  34     }
  35
  36     # Means of accessing all the metaclasses that have
  37     # been initialized thus far
  38     sub get_all_metaclasses         {        %METACLASS_CACHE         }
  39     sub get_all_metaclass_instances { values %METACLASS_CACHE         }
  40     sub get_all_metaclass_names     { keys   %METACLASS_CACHE         }
  41     sub get_metaclass_by_name       { $METACLASS_CACHE{$_[0]}         }
  42     sub store_metaclass_by_name     { $METACLASS_CACHE{$_[0]} = $_[1] }
  43     sub weaken_metaclass            { weaken($METACLASS_CACHE{$_[0]}) }
  44     sub does_metaclass_exist        { defined $METACLASS_CACHE{$_[0]} }
  45     sub remove_metaclass_by_name    { delete $METACLASS_CACHE{$_[0]}  }
  46
  47 }
  48
  49 sub meta{ Mouse::Meta::Class->initialize(ref $_[0] || $_[0]) }
  50
  51 sub _new{ Carp::croak("Mouse::Meta::Module is an abstract class") }
  52
  53 sub name { $_[0]->{package} }
  54
  55 sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  56 sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  57 sub identifier {
  58     my $self = shift;
  59     return join '-' => (
  60         $self->name,
  61         ($self->version   || ()),
  62         ($self->authority || ()),
  63     );
  64 }
  65
  66 # add_attribute is an abstract method
  67
  68 sub get_attribute_map {        $_[0]->{attributes}          }
  69 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  70 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  71 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  72 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  73
  74 sub namespace{
  75     my $name = $_[0]->{package};
  76     no strict 'refs';
  77     return \%{ $name . '::' };
  78 }
  79
  80 sub add_method {
  81     my($self, $name, $code) = @_;
  82
  83     if(!defined $name){
  84         $self->throw_error("You must pass a defined name");
  85     }
  86     if(ref($code) ne 'CODE'){
  87         not_supported 'add_method for a method object';
  88     }
  89
  90     $self->{methods}->{$name}++; # Moose stores meta object here.
  91
  92     my $pkg = $self->name;
  93     no strict 'refs';
  94     no warnings 'redefine';
  95     *{ $pkg . '::' . $name } = $code;
  96 }
  97
  98 sub _code_is_mine { # taken from Class::MOP::Class
  99     my ( $self, $code ) = @_;
 100
 101     my ( $code_package, $code_name ) = get_code_info($code);
 102
 103     return $code_package && $code_package eq $self->name
 104         || ( $code_package eq 'constant' && $code_name eq '__ANON__' );
 105 }
 106
 107 sub has_method {
 108     my($self, $method_name) = @_;
 109
 110     return 1 if $self->{methods}->{$method_name};
 111     my $code = $self->name->can($method_name);
 112
 113     return $code && $self->_code_is_mine($code);
 114 }
 115
 116 sub get_method{
 117     my($self, $method_name) = @_;
 118
 119     if($self->has_method($method_name)){
 120         my $method_metaclass = $self->method_metaclass;
 121         load_class($method_metaclass);
 122
 123         my $package = $self->name;
 124         return $method_metaclass->new(
 125             body    => $package->can($method_name),
 126             name    => $method_name,
 127             package => $package,
 128         );
 129     }
 130
 131     return undef;
 132 }
 133
 134 sub get_method_list {
 135     my($self) = @_;
 136
 137     return grep { $self->has_method($_) } keys %{ $self->namespace };
 138 }
 139
 140 {
 141     my $ANON_SERIAL = 0;
 142     my $ANON_PREFIX = 'Mouse::Meta::Module::__ANON__::';
 143
 144     my %IMMORTALS;
 145
 146     sub create {
 147         my ($class, $package_name, %options) = @_;
 148
 149         $class->throw_error('You must pass a package name') if @_ == 1;
 150
 151
 152         if(exists $options{superclasses}){
 153             if($class->isa('Mouse::Meta::Class')){
 154                 (ref $options{superclasses} eq 'ARRAY')
 155                     || $class->throw_error("You must pass an ARRAY ref of superclasses");
 156             }
 157             else{ # role
 158                 delete $options{superclasses};
 159             }
 160         }
 161
 162         my $attributes;
 163         if(exists $options{attributes}){
 164             $attributes = delete $options{attributes};
 165            (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 166                || $class->throw_error("You must pass an ARRAY ref of attributes")
 167            }
 168
 169         (ref $options{methods} eq 'HASH')
 170             || $class->throw_error("You must pass a HASH ref of methods")
 171                 if exists $options{methods};
 172
 173         (ref $options{roles} eq 'ARRAY')
 174             || $class->throw_error("You must pass an ARRAY ref of roles")
 175                 if exists $options{roles};
 176
 177
 178         my @extra_options;
 179         my $mortal;
 180         my $cache_key;
 181
 182         if(!defined $package_name){ # anonymous
 183             $mortal = !$options{cache};
 184
 185             # anonymous but immortal
 186             if(!$mortal){
 187                     # something like Super::Class|Super::Class::2=Role|Role::1
 188                     $cache_key = join '=' => (
 189                         join('|',      @{$options{superclasses} || []}),
 190                         join('|', sort @{$options{roles}        || []}),
 191                     );
 192                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 193             }
 194             $package_name = $ANON_PREFIX . ++$ANON_SERIAL;
 195
 196             push @extra_options, (anon_serial_id => $ANON_SERIAL);
 197         }
 198
 199         # instantiate a module
 200         {
 201             no strict 'refs';
 202             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 203             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 204         }
 205
 206         my %initialize_options = %options;
 207         delete @initialize_options{qw(
 208             package
 209             superclasses
 210             attributes
 211             methods
 212             roles
 213         )};
 214         my $meta = $class->initialize( $package_name, %initialize_options, @extra_options);
 215
 216         Mouse::Meta::Module::weaken_metaclass($package_name)
 217             if $mortal;
 218
 219         # FIXME totally lame
 220         $meta->add_method('meta' => sub {
 221             $class->initialize(ref($_[0]) || $_[0]);
 222         });
 223
 224         $meta->superclasses(@{$options{superclasses}})
 225             if exists $options{superclasses};
 226
 227         # NOTE:
 228         # process attributes first, so that they can
 229         # install accessors, but locally defined methods
 230         # can then overwrite them. It is maybe a little odd, but
 231         # I think this should be the order of things.
 232         if (defined $attributes) {
 233             if(ref($attributes) eq 'ARRAY'){
 234                 foreach my $attr (@{$attributes}) {
 235                     $meta->add_attribute($attr->{name} => $attr);
 236                 }
 237             }
 238             else{
 239                 while(my($name, $attr) = each %{$attributes}){
 240                     $meta->add_attribute($name => $attr);
 241                 }
 242             }
 243         }
 244         if (exists $options{methods}) {
 245             foreach my $method_name (keys %{$options{methods}}) {
 246                 $meta->add_method($method_name, $options{methods}->{$method_name});
 247             }
 248         }
 249         if (exists $options{roles}){
 250             Mouse::Util::apply_all_roles($package_name, @{$options{roles}});
 251         }
 252
 253         if(!$mortal && exists $meta->{anon_serial_id}){
 254             $IMMORTALS{$cache_key} = $meta;
 255         }
 256
 257         return $meta;
 258     }
 259
 260     sub DESTROY{
 261         my($self) = @_;
 262
 263         my $serial_id = $self->{anon_serial_id};
 264
 265         return if !$serial_id;
 266
 267         my $stash = $self->namespace;
 268
 269         @{$self->{superclasses}} = () if exists $self->{superclasses};
 270         %{$stash} = ();
 271         Mouse::Meta::Module::remove_metaclass_by_name($self->name);
 272
 273         no strict 'refs';
 274         delete ${$ANON_PREFIX}{ $serial_id . '::' };
 275
 276         return;
 277     }
 278 }
 279
 280 sub throw_error{
 281     my($class, $message, %args) = @_;
 282
 283     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 284     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 285
 286     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 287         Carp::croak($message);
 288     }
 289     else{
 290         Carp::confess($message);
 291     }
 292 }
 293
 294 1;
 295
 296 __END__
 297
 298 =head1 NAME
 299
 300 Mouse::Meta::Module - Common base class for Mouse::Meta::Class and Mouse::Meta::Role
 301
 302 =cut