lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use Mouse::Util qw/:meta get_code_package get_code_ref load_class not_supported/; # enables strict and warnings
   3
   4 use Mouse::Util::TypeConstraints ();
   5
   6 use Carp         ();
   7 use Scalar::Util ();
   8
   9 my %METAS;
  10
  11 sub _metaclass_cache { # DEPRECATED
  12     my($class, $name) = @_;
  13     return $METAS{$name};
  14 }
  15
  16 sub initialize {
  17     my($class, $package_name, @args) = @_;
  18
  19     ($package_name && !ref($package_name))
  20         || $class->throw_error("You must pass a package name and it cannot be blessed");
  21
  22     return $METAS{$package_name}
  23         ||= $class->_construct_meta(package => $package_name, @args);
  24 }
  25
  26 sub class_of{
  27     my($class_or_instance) = @_;
  28     return undef unless defined $class_or_instance;
  29     return $METAS{ ref($class_or_instance) || $class_or_instance };
  30 }
  31
  32 # Means of accessing all the metaclasses that have
  33 # been initialized thus far
  34 #sub get_all_metaclasses         {        %METAS         }
  35 sub get_all_metaclass_instances { values %METAS         }
  36 sub get_all_metaclass_names     { keys   %METAS         }
  37 sub get_metaclass_by_name       { $METAS{$_[0]}         }
  38 #sub store_metaclass_by_name     { $METAS{$_[0]} = $_[1] }
  39 #sub weaken_metaclass            { weaken($METAS{$_[0]}) }
  40 #sub does_metaclass_exist        { defined $METAS{$_[0]} }
  41 #sub remove_metaclass_by_name    { delete $METAS{$_[0]}  }
  42
  43 sub name;
  44
  45 sub namespace;
  46
  47 # The followings are Class::MOP specific methods
  48
  49 #sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  50 #sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  51 #sub identifier {
  52 #    my $self = shift;
  53 #    return join '-' => (
  54 #       $self->name,
  55 #        ($self->version   || ()),
  56 #        ($self->authority || ()),
  57 #    );
  58 #}
  59
  60 # add_attribute is an abstract method
  61
  62 sub get_attribute_map { # DEPRECATED
  63     Carp::cluck('get_attribute_map() has been deprecated');
  64     return $_[0]->{attributes};
  65 }
  66
  67 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  68 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  69 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  70 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  71
  72 # XXX: for backward compatibility
  73 my %foreign = map{ $_ => undef } qw(
  74     Mouse Mouse::Role Mouse::Util Mouse::Util::TypeConstraints
  75     Carp Scalar::Util List::Util
  76 );
  77 sub _code_is_mine{
  78 #    my($self, $code) = @_;
  79
  80     return !exists $foreign{ get_code_package($_[1]) };
  81 }
  82
  83 sub add_method;
  84
  85 sub has_method {
  86     my($self, $method_name) = @_;
  87
  88     defined($method_name)
  89         or $self->throw_error('You must define a method name');
  90
  91     return defined($self->{methods}{$method_name}) || do{
  92         my $code = get_code_ref($self->{package}, $method_name);
  93         $code && $self->_code_is_mine($code);
  94     };
  95 }
  96
  97 sub get_method_body {
  98     my($self, $method_name) = @_;
  99
 100     defined($method_name)
 101         or $self->throw_error('You must define a method name');
 102
 103     return $self->{methods}{$method_name} ||= do{
 104         my $code = get_code_ref($self->{package}, $method_name);
 105         $code && $self->_code_is_mine($code) ? $code : undef;
 106     };
 107 }
 108
 109 sub get_method{
 110     my($self, $method_name) = @_;
 111
 112     if(my $code = $self->get_method_body($method_name)){
 113         my $method_metaclass = $self->method_metaclass;
 114         load_class($method_metaclass);
 115
 116         return $method_metaclass->wrap(
 117             body                 => $code,
 118             name                 => $method_name,
 119             package              => $self->name,
 120             associated_metaclass => $self,
 121         );
 122     }
 123
 124     return undef;
 125 }
 126
 127 sub get_method_list {
 128     my($self) = @_;
 129
 130     return grep { $self->has_method($_) } keys %{ $self->namespace };
 131 }
 132
 133 {
 134     my $ANON_SERIAL = 0;
 135
 136     my %IMMORTALS;
 137
 138     sub create {
 139         my($self, $package_name, %options) = @_;
 140
 141         my $class = ref($self) || $self;
 142         $self->throw_error('You must pass a package name') if @_ < 2;
 143
 144         my $superclasses;
 145         if(exists $options{superclasses}){
 146             if(Mouse::Util::TypeConstraints::_is_a_metarole($self)){
 147                 delete $options{superclasses};
 148             }
 149             else{
 150                 $superclasses = delete $options{superclasses};
 151                 (ref $superclasses eq 'ARRAY')
 152                     || $self->throw_error("You must pass an ARRAY ref of superclasses");
 153             }
 154         }
 155
 156         my $attributes = delete $options{attributes};
 157         if(defined $attributes){
 158             (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 159                 || $self->throw_error("You must pass an ARRAY ref of attributes");
 160         }
 161         my $methods = delete $options{methods};
 162         if(defined $methods){
 163             (ref $methods eq 'HASH')
 164                 || $self->throw_error("You must pass a HASH ref of methods");
 165         }
 166         my $roles = delete $options{roles};
 167         if(defined $roles){
 168             (ref $roles eq 'ARRAY')
 169                 || $self->throw_error("You must pass an ARRAY ref of roles");
 170         }
 171         my $mortal;
 172         my $cache_key;
 173
 174         if(!defined $package_name){ # anonymous
 175             $mortal = !$options{cache};
 176
 177             # anonymous but immortal
 178             if(!$mortal){
 179                     # something like Super::Class|Super::Class::2=Role|Role::1
 180                     $cache_key = join '=' => (
 181                         join('|',      @{$superclasses || []}),
 182                         join('|', sort @{$roles        || []}),
 183                     );
 184                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 185             }
 186             $options{anon_serial_id} = ++$ANON_SERIAL;
 187             $package_name = $class . '::__ANON__::' . $ANON_SERIAL;
 188         }
 189
 190         # instantiate a module
 191         {
 192             no strict 'refs';
 193             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 194             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 195         }
 196
 197         my $meta = $self->initialize( $package_name, %options);
 198
 199         Scalar::Util::weaken $METAS{$package_name}
 200             if $mortal;
 201
 202         $meta->add_method(meta => sub{
 203             $self->initialize(ref($_[0]) || $_[0]);
 204         });
 205
 206         $meta->superclasses(@{$superclasses})
 207             if defined $superclasses;
 208
 209         # NOTE:
 210         # process attributes first, so that they can
 211         # install accessors, but locally defined methods
 212         # can then overwrite them. It is maybe a little odd, but
 213         # I think this should be the order of things.
 214         if (defined $attributes) {
 215             if(ref($attributes) eq 'ARRAY'){
 216                 # array of Mouse::Meta::Attribute
 217                 foreach my $attr (@{$attributes}) {
 218                     $meta->add_attribute($attr);
 219                 }
 220             }
 221             else{
 222                 # hash map of name and attribute spec pairs
 223                 while(my($name, $attr) = each %{$attributes}){
 224                     $meta->add_attribute($name => $attr);
 225                 }
 226             }
 227         }
 228         if (defined $methods) {
 229             while(my($method_name, $method_body) = each %{$methods}){
 230                 $meta->add_method($method_name, $method_body);
 231             }
 232         }
 233         if (defined $roles){
 234             Mouse::Util::apply_all_roles($package_name, @{$roles});
 235         }
 236
 237         if($cache_key){
 238             $IMMORTALS{$cache_key} = $meta;
 239         }
 240
 241         return $meta;
 242     }
 243
 244     sub DESTROY{
 245         my($self) = @_;
 246
 247         my $serial_id = $self->{anon_serial_id};
 248
 249         return if !$serial_id;
 250
 251         # @ISA is a magical variable, so we clear it manually.
 252         @{$self->{superclasses}} = () if exists $self->{superclasses};
 253
 254         # Then, clear the symbol table hash
 255         %{$self->namespace} = ();
 256
 257         my $name = $self->name;
 258         delete $METAS{$name};
 259
 260         $name =~ s/ $serial_id \z//xms;
 261
 262         no strict 'refs';
 263         delete ${$name}{ $serial_id . '::' };
 264
 265         return;
 266     }
 267 }
 268
 269 sub throw_error{
 270     my($class, $message, %args) = @_;
 271
 272     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 273     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 274
 275     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 276         Carp::croak($message);
 277     }
 278     else{
 279         Carp::confess($message);
 280     }
 281 }
 282
 283 1;
 284
 285 __END__
 286
 287 =head1 NAME
 288
 289 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 290
 291 =head1 VERSION
 292
 293 This document describes Mouse version 0.40_01
 294
 295 =head1 SEE ALSO
 296
 297 L<Class::MOP::Class>
 298
 299 L<Class::MOP::Module>
 300
 301 L<Class::MOP::Package>
 302
 303 =cut
 304