lib/Mouse/Meta/Module.pm

   1 package Mouse::Meta::Module;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6 use Scalar::Util qw/blessed weaken/;
   7
   8 use Mouse::Util qw/:meta get_code_info not_supported load_class/;
   9
  10 {
  11     my %METACLASS_CACHE;
  12
  13     # because Mouse doesn't introspect existing classes, we're forced to
  14     # only pay attention to other Mouse classes
  15     sub _metaclass_cache {
  16         my($class, $name) = @_;
  17         return $METACLASS_CACHE{$name};
  18     }
  19
  20     sub initialize {
  21         my($class, $package_name, @args) = @_;
  22
  23         ($package_name && !ref($package_name))
  24             || $class->throw_error("You must pass a package name and it cannot be blessed");
  25
  26         return $METACLASS_CACHE{$package_name}
  27             ||= $class->_construct_meta(package => $package_name, @args);
  28     }
  29
  30     sub class_of{
  31         my($class_or_instance) = @_;
  32         return undef unless defined $class_or_instance;
  33         return $METACLASS_CACHE{ blessed($class_or_instance) || $class_or_instance };
  34     }
  35
  36     # Means of accessing all the metaclasses that have
  37     # been initialized thus far
  38     sub get_all_metaclasses         {        %METACLASS_CACHE         }
  39     sub get_all_metaclass_instances { values %METACLASS_CACHE         }
  40     sub get_all_metaclass_names     { keys   %METACLASS_CACHE         }
  41     sub get_metaclass_by_name       { $METACLASS_CACHE{$_[0]}         }
  42     sub store_metaclass_by_name     { $METACLASS_CACHE{$_[0]} = $_[1] }
  43     sub weaken_metaclass            { weaken($METACLASS_CACHE{$_[0]}) }
  44     sub does_metaclass_exist        { defined $METACLASS_CACHE{$_[0]} }
  45     sub remove_metaclass_by_name    { delete $METACLASS_CACHE{$_[0]}  }
  46
  47 }
  48
  49 sub _new{ Carp::croak("Mouse::Meta::Module is an abstract class") }
  50
  51 sub name { $_[0]->{package} }
  52
  53 sub version   { no strict 'refs'; ${shift->name.'::VERSION'}   }
  54 sub authority { no strict 'refs'; ${shift->name.'::AUTHORITY'} }
  55 sub identifier {
  56     my $self = shift;
  57     return join '-' => (
  58         $self->name,
  59         ($self->version   || ()),
  60         ($self->authority || ()),
  61     );
  62 }
  63
  64 # add_attribute is an abstract method
  65
  66 sub get_attribute_map {        $_[0]->{attributes}          }
  67 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
  68 sub get_attribute     {        $_[0]->{attributes}->{$_[1]} }
  69 sub get_attribute_list{ keys %{$_[0]->{attributes}}         }
  70 sub remove_attribute  { delete $_[0]->{attributes}->{$_[1]} }
  71
  72 sub namespace{
  73     my $name = $_[0]->{package};
  74     no strict 'refs';
  75     return \%{ $name . '::' };
  76 }
  77
  78 sub add_method {
  79     my($self, $name, $code) = @_;
  80
  81     if(!defined $name){
  82         $self->throw_error('You must pass a defined name');
  83     }
  84     if(!defined $code){
  85         $self->throw_error('You must pass a defined code');
  86     }
  87
  88     if(ref($code) ne 'CODE'){
  89         not_supported 'add_method for a method object';
  90     }
  91
  92     $self->{methods}->{$name}++; # Moose stores meta object here.
  93
  94     my $pkg = $self->name;
  95     no strict 'refs';
  96     no warnings 'redefine';
  97     *{ $pkg . '::' . $name } = $code;
  98 }
  99
 100 sub _code_is_mine { # taken from Class::MOP::Class
 101     my ( $self, $code ) = @_;
 102
 103     my ( $code_package, $code_name ) = get_code_info($code);
 104
 105     return $code_package && $code_package eq $self->{package}
 106         || ( $code_package eq 'constant' && $code_name eq '__ANON__' );
 107 }
 108
 109 sub has_method {
 110     my($self, $method_name) = @_;
 111
 112     return 1 if $self->{methods}->{$method_name};
 113
 114     my $code = $self->{package}->can($method_name);
 115
 116     return $code && $self->_code_is_mine($code);
 117 }
 118
 119 sub get_method{
 120     my($self, $method_name) = @_;
 121
 122     if($self->has_method($method_name)){
 123         my $method_metaclass = $self->method_metaclass;
 124         load_class($method_metaclass);
 125
 126         my $package = $self->name;
 127         return $method_metaclass->new(
 128             body    => $package->can($method_name),
 129             name    => $method_name,
 130             package => $package,
 131         );
 132     }
 133
 134     return undef;
 135 }
 136
 137 sub get_method_list {
 138     my($self) = @_;
 139
 140     return grep { $self->has_method($_) } keys %{ $self->namespace };
 141 }
 142
 143 {
 144     my $ANON_SERIAL = 0;
 145     my $ANON_PREFIX = 'Mouse::Meta::Module::__ANON__::';
 146
 147     my %IMMORTALS;
 148
 149     sub create {
 150         my ($class, $package_name, %options) = @_;
 151
 152         $class->throw_error('You must pass a package name') if @_ == 1;
 153
 154
 155         if(exists $options{superclasses}){
 156             if($class->isa('Mouse::Meta::Class')){
 157                 (ref $options{superclasses} eq 'ARRAY')
 158                     || $class->throw_error("You must pass an ARRAY ref of superclasses");
 159             }
 160             else{ # role
 161                 delete $options{superclasses};
 162             }
 163         }
 164
 165         my $attributes;
 166         if(exists $options{attributes}){
 167             $attributes = delete $options{attributes};
 168            (ref $attributes eq 'ARRAY' || ref $attributes eq 'HASH')
 169                || $class->throw_error("You must pass an ARRAY ref of attributes")
 170            }
 171
 172         (ref $options{methods} eq 'HASH')
 173             || $class->throw_error("You must pass a HASH ref of methods")
 174                 if exists $options{methods};
 175
 176         (ref $options{roles} eq 'ARRAY')
 177             || $class->throw_error("You must pass an ARRAY ref of roles")
 178                 if exists $options{roles};
 179
 180
 181         my @extra_options;
 182         my $mortal;
 183         my $cache_key;
 184
 185         if(!defined $package_name){ # anonymous
 186             $mortal = !$options{cache};
 187
 188             # anonymous but immortal
 189             if(!$mortal){
 190                     # something like Super::Class|Super::Class::2=Role|Role::1
 191                     $cache_key = join '=' => (
 192                         join('|',      @{$options{superclasses} || []}),
 193                         join('|', sort @{$options{roles}        || []}),
 194                     );
 195                     return $IMMORTALS{$cache_key} if exists $IMMORTALS{$cache_key};
 196             }
 197             $package_name = $ANON_PREFIX . ++$ANON_SERIAL;
 198
 199             push @extra_options, (anon_serial_id => $ANON_SERIAL);
 200         }
 201
 202         # instantiate a module
 203         {
 204             no strict 'refs';
 205             ${ $package_name . '::VERSION'   } = delete $options{version}   if exists $options{version};
 206             ${ $package_name . '::AUTHORITY' } = delete $options{authority} if exists $options{authority};
 207         }
 208
 209         my %initialize_options = %options;
 210         delete @initialize_options{qw(
 211             package
 212             superclasses
 213             attributes
 214             methods
 215             roles
 216         )};
 217         my $meta = $class->initialize( $package_name, %initialize_options, @extra_options);
 218
 219         Mouse::Meta::Module::weaken_metaclass($package_name)
 220             if $mortal;
 221
 222         # FIXME totally lame
 223         $meta->add_method('meta' => sub {
 224             $class->initialize(ref($_[0]) || $_[0]);
 225         });
 226
 227         $meta->superclasses(@{$options{superclasses}})
 228             if exists $options{superclasses};
 229
 230         # NOTE:
 231         # process attributes first, so that they can
 232         # install accessors, but locally defined methods
 233         # can then overwrite them. It is maybe a little odd, but
 234         # I think this should be the order of things.
 235         if (defined $attributes) {
 236             if(ref($attributes) eq 'ARRAY'){
 237                 foreach my $attr (@{$attributes}) {
 238                     $meta->add_attribute($attr->{name} => $attr);
 239                 }
 240             }
 241             else{
 242                 while(my($name, $attr) = each %{$attributes}){
 243                     $meta->add_attribute($name => $attr);
 244                 }
 245             }
 246         }
 247         if (exists $options{methods}) {
 248             foreach my $method_name (keys %{$options{methods}}) {
 249                 $meta->add_method($method_name, $options{methods}->{$method_name});
 250             }
 251         }
 252         if (exists $options{roles}){
 253             Mouse::Util::apply_all_roles($package_name, @{$options{roles}});
 254         }
 255
 256         if(!$mortal && exists $meta->{anon_serial_id}){
 257             $IMMORTALS{$cache_key} = $meta;
 258         }
 259
 260         return $meta;
 261     }
 262
 263     sub DESTROY{
 264         my($self) = @_;
 265
 266         my $serial_id = $self->{anon_serial_id};
 267
 268         return if !$serial_id;
 269
 270         my $stash = $self->namespace;
 271
 272         @{$self->{superclasses}} = () if exists $self->{superclasses};
 273         %{$stash} = ();
 274         Mouse::Meta::Module::remove_metaclass_by_name($self->name);
 275
 276         no strict 'refs';
 277         delete ${$ANON_PREFIX}{ $serial_id . '::' };
 278
 279         return;
 280     }
 281 }
 282
 283 sub throw_error{
 284     my($class, $message, %args) = @_;
 285
 286     local $Carp::CarpLevel  = $Carp::CarpLevel + 1 + ($args{depth} || 0);
 287     local $Carp::MaxArgNums = 20; # default is 8, usually we use named args which gets messier though
 288
 289     if(exists $args{longmess} && !$args{longmess}){ # intentionaly longmess => 0
 290         Carp::croak($message);
 291     }
 292     else{
 293         Carp::confess($message);
 294     }
 295 }
 296
 297 1;
 298
 299 __END__
 300
 301 =head1 NAME
 302
 303 Mouse::Meta::Module - The base class for Mouse::Meta::Class and Mouse::Meta::Role
 304
 305 =head1 SEE ALSO
 306
 307 L<Class::MOP>
 308
 309 =cut
 310