lib/Mouse/Meta/Method/Accessor.pm

   1 package Mouse::Meta::Method::Accessor;
   2 use Mouse::Util; # enables strict and warnings
   3 use Scalar::Util qw(blessed);
   4
   5 sub _generate_accessor{
   6     my (undef, $attribute, $class, $type) = @_;
   7
   8     my $name          = $attribute->name;
   9     my $default       = $attribute->default;
  10     my $constraint    = $attribute->type_constraint;
  11     my $builder       = $attribute->builder;
  12     my $trigger       = $attribute->trigger;
  13     my $is_weak       = $attribute->is_weak_ref;
  14     my $should_deref  = $attribute->should_auto_deref;
  15     my $should_coerce = (defined($constraint) && $constraint->has_coercion && $attribute->should_coerce);
  16
  17     my $compiled_type_constraint = defined($constraint) ? $constraint->_compiled_type_constraint : undef;
  18
  19     my $self  = '$_[0]';
  20     my $key   = "q{$name}";
  21     my $slot  = "$self\->{$key}";
  22
  23     $type ||= 'accessor';
  24
  25     my $accessor = sprintf(qq{#line 1 "%s for %s (%s)"\n}, $type, $name, __FILE__)
  26                  . "sub {\n";
  27
  28     if ($type eq 'accessor' || $type eq 'writer') {
  29         if($type eq 'accessor'){
  30             $accessor .=
  31                 'if (scalar(@_) >= 2) {' . "\n";
  32         }
  33         else{ # writer
  34             $accessor .=
  35                 'if(@_ < 2){ Carp::confess("Not enough arguments for the writer of '.$name.'") }'.
  36                 '{' . "\n";
  37         }
  38
  39         my $value = '$_[1]';
  40
  41         if (defined $constraint) {
  42             if ($should_coerce) {
  43                 $accessor .=
  44                     "\n".
  45                     'my $val = $constraint->coerce('.$value.');';
  46                 $value = '$val';
  47             }
  48             $accessor .=
  49                 "\n".
  50                 '$compiled_type_constraint->('.$value.') or
  51                     $attribute->verify_type_constraint_error($name, '.$value.', $constraint);' . "\n";
  52         }
  53
  54         # if there's nothing left to do for the attribute we can return during
  55         # this setter
  56         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
  57
  58         $accessor .= "$slot = $value;\n";
  59
  60         if ($is_weak) {
  61             $accessor .= "Scalar::Util::weaken($slot) if ref $slot;\n";
  62         }
  63
  64         if ($trigger) {
  65             $accessor .= '$trigger->('.$self.', '.$value.');' . "\n";
  66         }
  67
  68         $accessor .= "}\n";
  69     }
  70     elsif($type eq 'reader') {
  71         $accessor .= 'Carp::confess("Cannot assign a value to a read-only accessor") if scalar(@_) >= 2;' . "\n";
  72     }
  73     else{
  74         $class->throw_error("Unknown accessor type '$type'");
  75     }
  76
  77     # XXX: an anon class can be a runtime created class
  78     if ($attribute->is_lazy || $class->is_anon_class) {
  79         my $value;
  80
  81         if (defined $builder){
  82             $value = "$self->\$builder()";
  83         }
  84         elsif (ref($default) eq 'CODE'){
  85             $value = "$self->\$default()";
  86         }
  87         else{
  88             $value = '$default';
  89         }
  90
  91         $accessor .= "if(!exists $slot){\n";
  92         if($should_coerce){
  93             $accessor .= "$slot = \$constraint->coerce($value)";
  94         }
  95         elsif(defined $constraint){
  96             $accessor .= "my \$tmp = $value;\n";
  97             $accessor .= "\$compiled_type_constraint->(\$tmp)";
  98             $accessor .= "or \$attribute->verify_type_constraint_error(\$name, \$tmp, \$constraint);\n";
  99             $accessor .= "$slot = \$tmp;\n";
 100         }
 101         else{
 102             $accessor .= "$slot = $value;\n";
 103         }
 104         $accessor .= "}\n";
 105     }
 106
 107     if ($should_deref) {
 108         if ($constraint->is_a_type_of('ArrayRef')) {
 109             $accessor .= "return \@{ $slot || [] } if wantarray;\n";
 110         }
 111         elsif($constraint->is_a_type_of('HashRef')){
 112             $accessor .= "return \%{ $slot || {} } if wantarray;\n";
 113         }
 114         else{
 115             $class->throw_error("Can not auto de-reference the type constraint " . $constraint->name);
 116         }
 117     }
 118
 119     $accessor .= "return $slot;\n}\n";
 120
 121     #print "# class ", $class->name, "\n", $accessor, "\n";
 122     my $code;
 123     my $e = do{
 124         local $@;
 125         $code = eval $accessor;
 126         $@;
 127     };
 128     die $e if $e;
 129
 130     return $code;
 131 }
 132
 133 sub _generate_reader{
 134     my $class = shift;
 135     return $class->_generate_accessor(@_, 'reader');
 136 }
 137
 138 sub _generate_writer{
 139     my $class = shift;
 140     return $class->_generate_accessor(@_, 'writer');
 141 }
 142
 143
 144 sub _generate_predicate {
 145     my (undef, $attribute, $class) = @_;
 146
 147     my $slot = $attribute->name;
 148     return sub{
 149         return exists $_[0]->{$slot};
 150     };
 151 }
 152
 153 sub _generate_clearer {
 154     my (undef, $attribute, $class) = @_;
 155
 156     my $slot = $attribute->name;
 157
 158    return sub{
 159         delete $_[0]->{$slot};
 160     };
 161 }
 162
 163 sub _generate_delegation{
 164     my (undef, $attribute, $class, $reader, $handle_name, $method_to_call) = @_;
 165
 166     return sub {
 167         my $instance = shift;
 168         my $proxy    = $instance->$reader();
 169
 170         my $error = !defined($proxy)                ? ' is not defined'
 171                   : ref($proxy) && !blessed($proxy) ? qq{ is not an object (got '$proxy')}
 172                                                     : undef;
 173         if ($error) {
 174             $instance->meta->throw_error(
 175                 "Cannot delegate $handle_name to $method_to_call because "
 176                     . "the value of "
 177                     . $attribute->name
 178                     . $error
 179              );
 180         }
 181         $proxy->$method_to_call(@_);
 182     };
 183 }
 184
 185
 186 1;