lib/Mouse/Meta/Method/Accessor.pm

   1 package Mouse::Meta::Method::Accessor;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 sub _inline_slot{
   5     my(undef, $self_var, $attr_name) = @_;
   6     return sprintf '%s->{q{%s}}', $self_var, $attr_name;
   7 }
   8
   9 sub _generate_accessor_any{
  10     my($method_class, $type, $attribute, $class) = @_;
  11
  12     my $name          = $attribute->name;
  13     my $default       = $attribute->default;
  14     my $constraint    = $attribute->type_constraint;
  15     my $builder       = $attribute->builder;
  16     my $trigger       = $attribute->trigger;
  17     my $is_weak       = $attribute->is_weak_ref;
  18     my $should_deref  = $attribute->should_auto_deref;
  19     my $should_coerce = (defined($constraint) && $constraint->has_coercion && $attribute->should_coerce);
  20
  21     my $compiled_type_constraint = defined($constraint) ? $constraint->_compiled_type_constraint : undef;
  22
  23     my $self  = '$_[0]';
  24     my $slot  = $method_class->_inline_slot($self, $name);;
  25
  26     my $accessor = sprintf(qq{package %s;\n#line 1 "%s for %s (%s)"\n}, $class->name, $type, $name, __FILE__)
  27                  . "sub {\n";
  28
  29     if ($type eq 'rw' || $type eq 'wo') {
  30         if($type eq 'rw'){
  31             $accessor .=
  32                 'if (scalar(@_) >= 2) {' . "\n";
  33         }
  34         else{ # writer
  35             $accessor .=
  36                 'if(@_ < 2){ Carp::confess("Not enough arguments for the writer of '.$name.'") }'.
  37                 '{' . "\n";
  38         }
  39
  40         my $value = '$_[1]';
  41
  42         if (defined $constraint) {
  43             if ($should_coerce) {
  44                 $accessor .=
  45                     "\n".
  46                     'my $val = $constraint->coerce('.$value.');';
  47                 $value = '$val';
  48             }
  49             $accessor .=
  50                 "\n".
  51                 '$compiled_type_constraint->('.$value.') or
  52                     $attribute->verify_type_constraint_error($name, '.$value.', $constraint);' . "\n";
  53         }
  54
  55         # if there's nothing left to do for the attribute we can return during
  56         # this setter
  57         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
  58
  59         $accessor .= "$slot = $value;\n";
  60
  61         if ($is_weak) {
  62             $accessor .= "Scalar::Util::weaken($slot) if ref $slot;\n";
  63         }
  64
  65         if ($trigger) {
  66             $accessor .= '$trigger->('.$self.', '.$value.');' . "\n";
  67         }
  68
  69         $accessor .= "}\n";
  70     }
  71     elsif($type eq 'ro') {
  72         $accessor .= 'Carp::confess("Cannot assign a value to a read-only accessor") if scalar(@_) >= 2;' . "\n";
  73     }
  74     else{
  75         $class->throw_error("Unknown accessor type '$type'");
  76     }
  77
  78     if ($attribute->is_lazy) {
  79         my $value;
  80
  81         if (defined $builder){
  82             $value = "$self->\$builder()";
  83         }
  84         elsif (ref($default) eq 'CODE'){
  85             $value = "$self->\$default()";
  86         }
  87         else{
  88             $value = '$default';
  89         }
  90
  91         $accessor .= "if(!exists $slot){\n";
  92         if($should_coerce){
  93             $accessor .= "$slot = \$constraint->coerce($value)";
  94         }
  95         elsif(defined $constraint){
  96             $accessor .= "my \$tmp = $value;\n";
  97
  98             $accessor .= "\$compiled_type_constraint->(\$tmp)";
  99             $accessor .= " || \$attribute->verify_type_constraint_error(\$name, \$tmp, \$constraint);\n";
 100             $accessor .= "$slot = \$tmp;\n";
 101         }
 102         else{
 103             $accessor .= "$slot = $value;\n";
 104         }
 105         if ($is_weak) {
 106             $accessor .= "Scalar::Util::weaken($slot) if ref $slot;\n";
 107         }
 108         $accessor .= "}\n";
 109     }
 110
 111     if ($should_deref) {
 112         if ($constraint->is_a_type_of('ArrayRef')) {
 113             $accessor .= "return \@{ $slot || [] } if wantarray;\n";
 114         }
 115         elsif($constraint->is_a_type_of('HashRef')){
 116             $accessor .= "return \%{ $slot || {} } if wantarray;\n";
 117         }
 118         else{
 119             $class->throw_error("Can not auto de-reference the type constraint " . $constraint->name);
 120         }
 121     }
 122
 123     $accessor .= "return $slot;\n}\n";
 124
 125     #print $accessor, "\n";
 126     my $code;
 127     my $e = do{
 128         local $@;
 129         $code = eval $accessor;
 130         $@;
 131     };
 132     die $e if $e;
 133
 134     return $code;
 135 }
 136
 137 sub _generate_accessor{
 138     my $class = shift;
 139     return $class->_generate_accessor_any(rw => @_);
 140 }
 141
 142 sub _generate_reader {
 143     my $class = shift;
 144     return $class->_generate_accessor_any(ro => @_);
 145 }
 146
 147 sub _generate_writer {
 148     my $class = shift;
 149     return $class->_generate_accessor_any(wo => @_);
 150 }
 151
 152 sub _generate_predicate {
 153     my (undef, $attribute, $class) = @_;
 154
 155     my $slot = $attribute->name;
 156     return sub{
 157         return exists $_[0]->{$slot};
 158     };
 159 }
 160
 161 sub _generate_clearer {
 162     my (undef, $attribute, $class) = @_;
 163
 164     my $slot = $attribute->name;
 165     return sub{
 166         delete $_[0]->{$slot};
 167     };
 168 }
 169
 170 1;
 171 __END__
 172
 173 =head1 NAME
 174
 175 Mouse::Meta::Method::Accessor - A Mouse method generator for accessors
 176
 177 =head1 VERSION
 178
 179 This document describes Mouse version 0.42
 180
 181 =head1 SEE ALSO
 182
 183 L<Moose::Meta::Method::Accessor>
 184
 185 =cut