lib/Mouse/Meta/Method/Accessor.pm

   1 package Mouse::Meta::Method::Accessor;
   2 use Mouse::Util; # enables strict and warnings
   3 use Scalar::Util qw(blessed);
   4
   5 sub _generate_accessor{
   6     my (undef, $attribute, $class, $type) = @_;
   7
   8     my $name          = $attribute->name;
   9     my $default       = $attribute->default;
  10     my $constraint    = $attribute->type_constraint;
  11     my $builder       = $attribute->builder;
  12     my $trigger       = $attribute->trigger;
  13     my $is_weak       = $attribute->is_weak_ref;
  14     my $should_deref  = $attribute->should_auto_deref;
  15     my $should_coerce = (defined($constraint) && $constraint->has_coercion && $attribute->should_coerce);
  16
  17     my $compiled_type_constraint = defined($constraint) ? $constraint->_compiled_type_constraint : undef;
  18
  19     my $self  = '$_[0]';
  20     my $key   = "q{$name}";
  21     my $slot  = "$self\->{$key}";
  22
  23     $type ||= 'accessor';
  24
  25     my $accessor = sprintf(qq{#line 1 "%s for %s (%s)"\n}, $type, $name, __FILE__)
  26                  . "sub {\n";
  27
  28     if ($type eq 'accessor' || $type eq 'writer') {
  29         if($type eq 'accessor'){
  30             $accessor .=
  31                 'if (scalar(@_) >= 2) {' . "\n";
  32         }
  33         else{ # writer
  34             $accessor .=
  35                 'if(@_ < 2){ Carp::confess("Not enough arguments for the writer of '.$name.'") }'.
  36                 '{' . "\n";
  37         }
  38
  39         my $value = '$_[1]';
  40
  41         if (defined $constraint) {
  42             if ($should_coerce) {
  43                 $accessor .=
  44                     "\n".
  45                     'my $val = $constraint->coerce('.$value.');';
  46                 $value = '$val';
  47             }
  48             $accessor .=
  49                 "\n".
  50                 '$compiled_type_constraint->('.$value.') or
  51                     $attribute->verify_type_constraint_error($name, '.$value.', $constraint);' . "\n";
  52         }
  53
  54         # if there's nothing left to do for the attribute we can return during
  55         # this setter
  56         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
  57
  58         $accessor .= "$slot = $value;\n";
  59
  60         if ($is_weak) {
  61             $accessor .= "Scalar::Util::weaken($slot) if ref $slot;\n";
  62         }
  63
  64         if ($trigger) {
  65             $accessor .= '$trigger->('.$self.', '.$value.');' . "\n";
  66         }
  67
  68         $accessor .= "}\n";
  69     }
  70     elsif($type eq 'reader') {
  71         $accessor .= 'Carp::confess("Cannot assign a value to a read-only accessor") if scalar(@_) >= 2;' . "\n";
  72     }
  73     else{
  74         $class->throw_error("Unknown accessor type '$type'");
  75     }
  76
  77     if ($attribute->is_lazy) {
  78         my $value;
  79
  80         if (defined $builder){
  81             $value = "$self->\$builder()";
  82         }
  83         elsif (ref($default) eq 'CODE'){
  84             $value = "$self->\$default()";
  85         }
  86         else{
  87             $value = '$default';
  88         }
  89
  90         $accessor .= "if(!exists $slot){\n";
  91         if($should_coerce){
  92             $accessor .= "$slot = \$constraint->coerce($value)";
  93         }
  94         elsif(defined $constraint){
  95             $accessor .= "my \$tmp = $value;\n";
  96             #XXX: The following 'defined and' check is for backward compatibility
  97             $accessor .= "defined(\$tmp) and ";
  98
  99             $accessor .= "\$compiled_type_constraint->(\$tmp)";
 100             $accessor .= " || \$attribute->verify_type_constraint_error(\$name, \$tmp, \$constraint);\n";
 101             $accessor .= "$slot = \$tmp;\n";
 102         }
 103         else{
 104             $accessor .= "$slot = $value;\n";
 105         }
 106         $accessor .= "}\n";
 107     }
 108
 109     if ($should_deref) {
 110         if ($constraint->is_a_type_of('ArrayRef')) {
 111             $accessor .= "return \@{ $slot || [] } if wantarray;\n";
 112         }
 113         elsif($constraint->is_a_type_of('HashRef')){
 114             $accessor .= "return \%{ $slot || {} } if wantarray;\n";
 115         }
 116         else{
 117             $class->throw_error("Can not auto de-reference the type constraint " . $constraint->name);
 118         }
 119     }
 120
 121     $accessor .= "return $slot;\n}\n";
 122
 123     #print "# class ", $class->name, "\n", $accessor, "\n";
 124     my $code;
 125     my $e = do{
 126         local $@;
 127         $code = eval $accessor;
 128         $@;
 129     };
 130     die $e if $e;
 131
 132     return $code;
 133 }
 134
 135 sub _generate_reader{
 136     my $class = shift;
 137     return $class->_generate_accessor(@_, 'reader');
 138 }
 139
 140 sub _generate_writer{
 141     my $class = shift;
 142     return $class->_generate_accessor(@_, 'writer');
 143 }
 144
 145
 146 sub _generate_predicate {
 147     my (undef, $attribute, $class) = @_;
 148
 149     my $slot = $attribute->name;
 150     return sub{
 151         return exists $_[0]->{$slot};
 152     };
 153 }
 154
 155 sub _generate_clearer {
 156     my (undef, $attribute, $class) = @_;
 157
 158     my $slot = $attribute->name;
 159
 160    return sub{
 161         delete $_[0]->{$slot};
 162     };
 163 }
 164
 165 sub _generate_delegation{
 166     my (undef, $attribute, $class, $reader, $handle_name, $method_to_call) = @_;
 167
 168     return sub {
 169         my $instance = shift;
 170         my $proxy    = $instance->$reader();
 171
 172         my $error = !defined($proxy)                ? ' is not defined'
 173                   : ref($proxy) && !blessed($proxy) ? qq{ is not an object (got '$proxy')}
 174                                                     : undef;
 175         if ($error) {
 176             $instance->meta->throw_error(
 177                 "Cannot delegate $handle_name to $method_to_call because "
 178                     . "the value of "
 179                     . $attribute->name
 180                     . $error
 181              );
 182         }
 183         $proxy->$method_to_call(@_);
 184     };
 185 }
 186
 187
 188 1;
 189 __END__
 190
 191 =head1 NAME
 192
 193 Mouse::Meta::Method::Accessor - A Mouse method generator for accessors
 194
 195 =head1 VERSION
 196
 197 This document describes Mouse version 0.37_06
 198
 199 =head1 SEE ALSO
 200
 201 L<Moose::Meta::Method::Accessor>
 202
 203 =cut