lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 sub get_method_list {
  73     my $self = shift;
  74     my $name = $self->name;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}};
  83     wantarray ? @functions : \@functions;
  84 }
  85
  86 sub add_attribute {
  87     my $self = shift;
  88     my $attr = shift;
  89
  90     $self->{'attributes'}{$attr->name} = $attr;
  91 }
  92
  93 sub compute_all_applicable_attributes {
  94     my $self = shift;
  95     my (@attr, %seen);
  96
  97     for my $class ($self->linearized_isa) {
  98         my $meta = $self->_metaclass_cache($class)
  99             or next;
 100
 101         for my $name (keys %{ $meta->get_attribute_map }) {
 102             next if $seen{$name}++;
 103             push @attr, $meta->get_attribute($name);
 104         }
 105     }
 106
 107     return @attr;
 108 }
 109
 110 sub get_attribute_map { $_[0]->{attributes} }
 111 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 112 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 113
 114 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 115
 116 sub clone_object {
 117     my $class    = shift;
 118     my $instance = shift;
 119
 120     (blessed($instance) && $instance->isa($class->name))
 121         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 122
 123     $class->clone_instance($instance, @_);
 124 }
 125
 126 sub clone_instance {
 127     my ($class, $instance, %params) = @_;
 128
 129     (blessed($instance))
 130         || confess "You can only clone instances, ($instance) is not a blessed instance";
 131
 132     my $clone = bless { %$instance }, ref $instance;
 133
 134     foreach my $attr ($class->compute_all_applicable_attributes()) {
 135         if ( defined( my $init_arg = $attr->init_arg ) ) {
 136             if (exists $params{$init_arg}) {
 137                 $clone->{ $attr->name } = $params{$init_arg};
 138             }
 139         }
 140     }
 141
 142     return $clone;
 143
 144 }
 145
 146 sub make_immutable {
 147     my $self = shift;
 148     my %args = @_;
 149     my $name = $self->name;
 150     $self->{is_immutable}++;
 151     $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 152     if ($args{inline_destructor}) {
 153         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 154     }
 155 }
 156
 157 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 158
 159 sub is_immutable { $_[0]->{is_immutable} }
 160
 161 sub attribute_metaclass { "Mouse::Meta::Class" }
 162
 163 sub _install_modifier {
 164     my ( $self, $into, $type, $name, $code ) = @_;
 165     if (eval "require Class::Method::Modifiers::Fast; 1") {
 166         Class::Method::Modifiers::Fast::_install_modifier(
 167             $into,
 168             $type,
 169             $name,
 170             $code
 171         );
 172     }
 173     else {
 174         require Class::Method::Modifiers;
 175         Class::Method::Modifiers::_install_modifier(
 176             $into,
 177             $type,
 178             $name,
 179             $code
 180         );
 181     }
 182 }
 183
 184 sub add_before_method_modifier {
 185     my ( $self, $name, $code ) = @_;
 186     $self->_install_modifier( $self->name, 'before', $name, $code );
 187 }
 188
 189 sub add_around_method_modifier {
 190     my ( $self, $name, $code ) = @_;
 191     $self->_install_modifier( $self->name, 'around', $name, $code );
 192 }
 193
 194 sub add_after_method_modifier {
 195     my ( $self, $name, $code ) = @_;
 196     $self->_install_modifier( $self->name, 'after', $name, $code );
 197 }
 198
 199 sub roles { $_[0]->{roles} }
 200
 201 sub does_role {
 202     my ($self, $role_name) = @_;
 203
 204     (defined $role_name)
 205         || confess "You must supply a role name to look for";
 206
 207     for my $role (@{ $self->{roles} }) {
 208         return 1 if $role->name eq $role_name;
 209     }
 210
 211     return 0;
 212 }
 213
 214 sub create {
 215     my ($self, $package_name, %options) = @_;
 216
 217     (ref $options{superclasses} eq 'ARRAY')
 218         || confess "You must pass an ARRAY ref of superclasses"
 219             if exists $options{superclasses};
 220
 221     (ref $options{attributes} eq 'ARRAY')
 222         || confess "You must pass an ARRAY ref of attributes"
 223             if exists $options{attributes};
 224
 225     (ref $options{methods} eq 'HASH')
 226         || confess "You must pass a HASH ref of methods"
 227             if exists $options{methods};
 228
 229     do {
 230         ( defined $package_name && $package_name )
 231           || confess "You must pass a package name";
 232
 233         my $code = "package $package_name;";
 234         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 235           if exists $options{version};
 236         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 237           if exists $options{authority};
 238
 239         eval $code;
 240         confess "creation of $package_name failed : $@" if $@;
 241     };
 242
 243     my %initialize_options = %options;
 244     delete @initialize_options{qw(
 245         package
 246         superclasses
 247         attributes
 248         methods
 249         version
 250         authority
 251     )};
 252     my $meta = $self->initialize( $package_name => %initialize_options );
 253
 254     # FIXME totally lame
 255     $meta->add_method('meta' => sub {
 256         $self->initialize(ref($_[0]) || $_[0]);
 257     });
 258
 259     $meta->superclasses(@{$options{superclasses}})
 260         if exists $options{superclasses};
 261     # NOTE:
 262     # process attributes first, so that they can
 263     # install accessors, but locally defined methods
 264     # can then overwrite them. It is maybe a little odd, but
 265     # I think this should be the order of things.
 266     if (exists $options{attributes}) {
 267         foreach my $attr (@{$options{attributes}}) {
 268             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 269         }
 270     }
 271     if (exists $options{methods}) {
 272         foreach my $method_name (keys %{$options{methods}}) {
 273             $meta->add_method($method_name, $options{methods}->{$method_name});
 274         }
 275     }
 276     return $meta;
 277 }
 278
 279 {
 280     my $ANON_CLASS_SERIAL = 0;
 281     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 282     sub create_anon_class {
 283         my ( $class, %options ) = @_;
 284         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 285         return $class->create( $package_name, %options );
 286     }
 287 }
 288
 289 1;
 290
 291 __END__
 292
 293 =head1 NAME
 294
 295 Mouse::Meta::Class - hook into the Mouse MOP
 296
 297 =head1 METHODS
 298
 299 =head2 initialize ClassName -> Mouse::Meta::Class
 300
 301 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 302 one instance should exist for a given class.
 303
 304 =head2 new %args -> Mouse::Meta::Class
 305
 306 Creates a new Mouse::Meta::Class. Don't call this directly.
 307
 308 =head2 name -> ClassName
 309
 310 Returns the name of the owner class.
 311
 312 =head2 superclasses -> [ClassName]
 313
 314 Gets (or sets) the list of superclasses of the owner class.
 315
 316 =head2 add_attribute Mouse::Meta::Attribute
 317
 318 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 319 class.
 320
 321 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 322
 323 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 324 this class and its superclasses.
 325
 326 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 327
 328 Returns a mapping of attribute names to their corresponding
 329 L<Mouse::Meta::Attribute> objects.
 330
 331 =head2 has_attribute Name -> Bool
 332
 333 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 334
 335 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 336
 337 Returns the L<Mouse::Meta::Attribute> with the given name.
 338
 339 =head2 linearized_isa -> [ClassNames]
 340
 341 Returns the list of classes in method dispatch order, with duplicates removed.
 342
 343 =head2 clone_object Instance -> Instance
 344
 345 Clones the given C<Instance> which must be an instance governed by this
 346 metaclass.
 347
 348 =head2 clone_instance Instance, Parameters -> Instance
 349
 350 Clones the given C<Instance> and sets any additional parameters.
 351
 352 =cut
 353