lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 sub attribute_metaclass;
  10 sub method_metaclass;
  11
  12 sub constructor_class;
  13 sub destructor_class;
  14
  15 my @MetaClassTypes = qw(
  16     attribute_metaclass
  17     method_metaclass
  18     constructor_class
  19     destructor_class
  20 );
  21
  22 sub _construct_meta {
  23     my($class, %args) = @_;
  24
  25     $args{attributes} = {};
  26     $args{methods}    = {};
  27     $args{roles}      = [];
  28
  29     $args{superclasses} = do {
  30         no strict 'refs';
  31         \@{ $args{package} . '::ISA' };
  32     };
  33
  34     my $self = bless \%args, ref($class) || $class;
  35     if(ref($self) ne __PACKAGE__){
  36         $self->meta->_initialize_object($self, \%args);
  37     }
  38     return $self;
  39 }
  40
  41 sub create_anon_class{
  42     my $self = shift;
  43     return $self->create(undef, @_);
  44 }
  45
  46 sub is_anon_class;
  47
  48 sub roles;
  49
  50 sub calculate_all_roles {
  51     my $self = shift;
  52     my %seen;
  53     return grep { !$seen{ $_->name }++ }
  54            map  { $_->calculate_all_roles } @{ $self->roles };
  55 }
  56
  57 sub superclasses {
  58     my $self = shift;
  59
  60     if (@_) {
  61         foreach my $super(@_){
  62             Mouse::Util::load_class($super);
  63             my $meta = Mouse::Util::get_metaclass_by_name($super);
  64
  65             next if not defined $meta;
  66
  67             if(Mouse::Util::is_a_metarole($meta)){
  68                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  69             }
  70
  71             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  72
  73             $self->_reconcile_with_superclass_meta($meta);
  74         }
  75         @{ $self->{superclasses} } = @_;
  76     }
  77
  78     return @{ $self->{superclasses} };
  79 }
  80
  81 sub _reconcile_with_superclass_meta {
  82     my($self, $super_meta) = @_;
  83
  84     # find incompatible traits
  85     my @incompatibles;
  86     foreach my $metaclass_type(@MetaClassTypes){
  87         my $super_c = $super_meta->$metaclass_type();
  88         my $self_c  = $self->$metaclass_type();
  89
  90         if(!$super_c->isa($self_c)){
  91             push @incompatibles, ($metaclass_type => $super_c);
  92         }
  93     }
  94
  95     my @roles;
  96     foreach my $role($super_meta->meta->calculate_all_roles){
  97         if(!$self->meta->does_role($role->name)){
  98             push @roles, $role->name;
  99         }
 100     }
 101
 102     #print "reconcile($self vs. $super_meta; @roles; @incompatibles)\n";
 103
 104     require Mouse::Util::MetaRole;
 105     Mouse::Util::MetaRole::apply_metaclass_roles(
 106         for_class       => $self,
 107         metaclass       => ref $super_meta,
 108         metaclass_roles => \@roles,
 109         @incompatibles,
 110     );
 111     return;
 112 }
 113
 114 sub find_method_by_name{
 115     my($self, $method_name) = @_;
 116     defined($method_name)
 117         or $self->throw_error('You must define a method name to find');
 118
 119     foreach my $class( $self->linearized_isa ){
 120         my $method = $self->initialize($class)->get_method($method_name);
 121         return $method if defined $method;
 122     }
 123     return undef;
 124 }
 125
 126 sub get_all_methods {
 127     my($self) = @_;
 128     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 129 }
 130
 131 sub get_all_method_names {
 132     my $self = shift;
 133     my %uniq;
 134     return grep { $uniq{$_}++ == 0 }
 135             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 136             $self->linearized_isa;
 137 }
 138
 139 sub find_attribute_by_name{
 140     my($self, $name) = @_;
 141     my $attr;
 142     foreach my $class($self->linearized_isa){
 143         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 144         $attr = $meta->get_attribute($name) and last;
 145     }
 146     return $attr;
 147 }
 148
 149 sub add_attribute {
 150     my $self = shift;
 151
 152     my($attr, $name);
 153
 154     if(blessed $_[0]){
 155         $attr = $_[0];
 156
 157         $attr->isa('Mouse::Meta::Attribute')
 158             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 159
 160         $name = $attr->name;
 161     }
 162     else{
 163         # _process_attribute
 164         $name = shift;
 165
 166         my %args = (@_ == 1) ? %{$_[0]} : @_;
 167
 168         defined($name)
 169             or $self->throw_error('You must provide a name for the attribute');
 170
 171         if ($name =~ s/^\+//) { # inherited attributes
 172             my $inherited_attr = $self->find_attribute_by_name($name)
 173                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 174
 175             $attr = $inherited_attr->clone_and_inherit_options(%args);
 176         }
 177         else{
 178             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 179             $args{traits} = \@traits if @traits;
 180
 181             $attr = $attribute_class->new($name, %args);
 182         }
 183     }
 184
 185     weaken( $attr->{associated_class} = $self );
 186
 187     $self->{attributes}{$attr->name} = $attr;
 188     $attr->install_accessors();
 189
 190     if(Mouse::Util::_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 191         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 192     }
 193     return $attr;
 194 }
 195
 196 sub compute_all_applicable_attributes { # DEPRECATED
 197     Carp::cluck('compute_all_applicable_attributes() has been deprecated. Use get_all_attributes() instead');
 198
 199     return shift->get_all_attributes(@_)
 200 }
 201
 202 sub linearized_isa;
 203
 204 sub new_object;
 205
 206 sub clone_object {
 207     my $class  = shift;
 208     my $object = shift;
 209     my $args   = $object->Mouse::Object::BUILDARGS(@_);
 210
 211     (blessed($object) && $object->isa($class->name))
 212         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 213
 214     my $cloned = bless { %$object }, ref $object;
 215     $class->_initialize_object($cloned, $args);
 216
 217     return $cloned;
 218 }
 219
 220 sub clone_instance { # DEPRECATED
 221     my ($class, $instance, %params) = @_;
 222
 223     Carp::cluck('clone_instance() has been deprecated. Use clone_object() instead');
 224
 225     return $class->clone_object($instance, %params);
 226 }
 227
 228
 229 sub immutable_options {
 230     my ( $self, @args ) = @_;
 231
 232     return (
 233         inline_constructor => 1,
 234         inline_destructor  => 1,
 235         constructor_name   => 'new',
 236         @args,
 237     );
 238 }
 239
 240
 241 sub make_immutable {
 242     my $self = shift;
 243     my %args = $self->immutable_options(@_);
 244
 245     $self->{is_immutable}++;
 246
 247     $self->{strict_constructor} = $args{strict_constructor};
 248
 249     if ($args{inline_constructor}) {
 250         my $c = $self->constructor_class;
 251         Mouse::Util::load_class($c);
 252         $self->add_method($args{constructor_name} =>
 253             $c->_generate_constructor($self, \%args));
 254     }
 255
 256     if ($args{inline_destructor}) {
 257         my $c = $self->destructor_class;
 258         Mouse::Util::load_class($c);
 259         $self->add_method(DESTROY =>
 260             $c->_generate_destructor($self, \%args));
 261     }
 262
 263     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 264     # at the end of a source file.
 265     return 1;
 266 }
 267
 268 sub make_mutable {
 269     my($self) = @_;
 270     $self->{is_immutable} = 0;
 271     return;
 272 }
 273
 274 sub is_immutable;
 275 sub is_mutable   { !$_[0]->is_immutable }
 276
 277 sub _install_modifier_pp{
 278     my( $self, $type, $name, $code ) = @_;
 279     my $into = $self->name;
 280
 281     my $original = $into->can($name)
 282         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 283
 284     my $modifier_table = $self->{modifiers}{$name};
 285
 286     if(!$modifier_table){
 287         my(@before, @after, @around, $cache, $modified);
 288
 289         $cache = $original;
 290
 291         $modified = sub {
 292             for my $c (@before) { $c->(@_) }
 293
 294             if(wantarray){ # list context
 295                 my @rval = $cache->(@_);
 296
 297                 for my $c(@after){ $c->(@_) }
 298                 return @rval;
 299             }
 300             elsif(defined wantarray){ # scalar context
 301                 my $rval = $cache->(@_);
 302
 303                 for my $c(@after){ $c->(@_) }
 304                 return $rval;
 305             }
 306             else{ # void context
 307                 $cache->(@_);
 308
 309                 for my $c(@after){ $c->(@_) }
 310                 return;
 311             }
 312         };
 313
 314         $self->{modifiers}{$name} = $modifier_table = {
 315             original => $original,
 316
 317             before   => \@before,
 318             after    => \@after,
 319             around   => \@around,
 320
 321             cache    => \$cache, # cache for around modifiers
 322         };
 323
 324         $self->add_method($name => $modified);
 325     }
 326
 327     if($type eq 'before'){
 328         unshift @{$modifier_table->{before}}, $code;
 329     }
 330     elsif($type eq 'after'){
 331         push @{$modifier_table->{after}}, $code;
 332     }
 333     else{ # around
 334         push @{$modifier_table->{around}}, $code;
 335
 336         my $next = ${ $modifier_table->{cache} };
 337         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 338     }
 339
 340     return;
 341 }
 342
 343 sub _install_modifier {
 344     my ( $self, $type, $name, $code ) = @_;
 345
 346     # load Class::Method::Modifiers first
 347     my $no_cmm_fast = do{
 348         local $@;
 349         eval q{ use Class::Method::Modifiers::Fast 0.041 () };
 350         $@;
 351     };
 352
 353     my $impl;
 354     if($no_cmm_fast){
 355         $impl = \&_install_modifier_pp;
 356     }
 357     else{
 358         my $install_modifier = Class::Method::Modifiers::Fast->can('install_modifier');
 359         $impl = sub {
 360             my ( $self, $type, $name, $code ) = @_;
 361             my $into = $self->name;
 362             $install_modifier->($into, $type, $name, $code);
 363
 364             $self->add_method($name => do{
 365                 no strict 'refs';
 366                 \&{ $into . '::' . $name };
 367             });
 368             return;
 369         };
 370     }
 371
 372     # replace this method itself :)
 373     {
 374         no warnings 'redefine';
 375         *_install_modifier = $impl;
 376     }
 377
 378     $self->$impl( $type, $name, $code );
 379 }
 380
 381 sub add_before_method_modifier {
 382     my ( $self, $name, $code ) = @_;
 383     $self->_install_modifier( 'before', $name, $code );
 384 }
 385
 386 sub add_around_method_modifier {
 387     my ( $self, $name, $code ) = @_;
 388     $self->_install_modifier( 'around', $name, $code );
 389 }
 390
 391 sub add_after_method_modifier {
 392     my ( $self, $name, $code ) = @_;
 393     $self->_install_modifier( 'after', $name, $code );
 394 }
 395
 396 sub add_override_method_modifier {
 397     my ($self, $name, $code) = @_;
 398
 399     if($self->has_method($name)){
 400         $self->throw_error("Cannot add an override method if a local method is already present");
 401     }
 402
 403     my $package = $self->name;
 404
 405     my $super_body = $package->can($name)
 406         or $self->throw_error("You cannot override '$name' because it has no super method");
 407
 408     $self->add_method($name => sub {
 409         local $Mouse::SUPER_PACKAGE = $package;
 410         local $Mouse::SUPER_BODY    = $super_body;
 411         local @Mouse::SUPER_ARGS    = @_;
 412
 413         $code->(@_);
 414     });
 415     return;
 416 }
 417
 418 sub add_augment_method_modifier {
 419     my ($self, $name, $code) = @_;
 420     if($self->has_method($name)){
 421         $self->throw_error("Cannot add an augment method if a local method is already present");
 422     }
 423
 424     my $super = $self->find_method_by_name($name)
 425         or $self->throw_error("You cannot augment '$name' because it has no super method");
 426
 427     my $super_package = $super->package_name;
 428     my $super_body    = $super->body;
 429
 430     $self->add_method($name => sub{
 431         local $Mouse::INNER_BODY{$super_package} = $code;
 432         local $Mouse::INNER_ARGS{$super_package} = [@_];
 433         $super_body->(@_);
 434     });
 435     return;
 436 }
 437
 438 sub does_role {
 439     my ($self, $role_name) = @_;
 440
 441     (defined $role_name)
 442         || $self->throw_error("You must supply a role name to look for");
 443
 444     for my $class ($self->linearized_isa) {
 445         my $meta = Mouse::Util::get_metaclass_by_name($class)
 446             or next;
 447
 448         for my $role (@{ $meta->roles }) {
 449
 450             return 1 if $role->does_role($role_name);
 451         }
 452     }
 453
 454     return 0;
 455 }
 456
 457 1;
 458 __END__
 459
 460 =head1 NAME
 461
 462 Mouse::Meta::Class - The Mouse class metaclass
 463
 464 =head1 VERSION
 465
 466 This document describes Mouse version 0.50_03
 467
 468 =head1 METHODS
 469
 470 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 471
 472 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 473 one instance should exist for a given class.
 474
 475 =head2 C<< name -> ClassName >>
 476
 477 Returns the name of the owner class.
 478
 479 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 480
 481 Gets (or sets) the list of superclasses of the owner class.
 482
 483 =head2 C<< add_method(name => CodeRef) >>
 484
 485 Adds a method to the owner class.
 486
 487 =head2 C<< has_method(name) -> Bool >>
 488
 489 Returns whether we have a method with the given name.
 490
 491 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 492
 493 Returns a L<Mouse::Meta::Method> with the given name.
 494
 495 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 496
 497 =head2 C<< get_method_list -> Names >>
 498
 499 Returns a list of method names which are defined in the local class.
 500 If you want a list of all applicable methods for a class, use the
 501 C<get_all_methods> method.
 502
 503 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 504
 505 Return the list of all L<Mouse::Meta::Method> instances associated with
 506 the class and its superclasses.
 507
 508 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 509
 510 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 511 class.
 512
 513 =head2 C<< has_attribute(Name) -> Bool >>
 514
 515 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 516
 517 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 518
 519 Returns the L<Mouse::Meta::Attribute> with the given name.
 520
 521 =head2 C<< get_attribute_list -> Names >>
 522
 523 Returns a list of attribute names which are defined in the local
 524 class. If you want a list of all applicable attributes for a class,
 525 use the C<get_all_attributes> method.
 526
 527 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 528
 529 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 530 this class and its superclasses.
 531
 532 =head2 C<< linearized_isa -> [ClassNames] >>
 533
 534 Returns the list of classes in method dispatch order, with duplicates removed.
 535
 536 =head2 C<< new_object(Parameters) -> Instance >>
 537
 538 Creates a new instance.
 539
 540 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 541
 542 Clones the given instance which must be an instance governed by this
 543 metaclass.
 544
 545 =head2 C<< throw_error(Message, Parameters) >>
 546
 547 Throws an error with the given message.
 548
 549 =head1 SEE ALSO
 550
 551 L<Mouse::Meta::Module>
 552
 553 L<Moose::Meta::Class>
 554
 555 L<Class::MOP::Class>
 556
 557 =cut
 558