lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Mouse::Meta::Method::Constructor;
   6 use Mouse::Meta::Method::Destructor;
   7 use Scalar::Util qw/blessed/;
   8 use Mouse::Util qw/get_linear_isa/;
   9 use Carp 'confess';
  10
  11 do {
  12     my %METACLASS_CACHE;
  13
  14     # because Mouse doesn't introspect existing classes, we're forced to
  15     # only pay attention to other Mouse classes
  16     sub _metaclass_cache {
  17         my $class = shift;
  18         my $name  = shift;
  19         return $METACLASS_CACHE{$name};
  20     }
  21
  22     sub initialize {
  23         my $class = shift;
  24         my $name  = shift;
  25         $METACLASS_CACHE{$name} = $class->new(name => $name)
  26             if !exists($METACLASS_CACHE{$name});
  27         return $METACLASS_CACHE{$name};
  28     }
  29 };
  30
  31 sub new {
  32     my $class = shift;
  33     my %args  = @_;
  34
  35     $args{attributes} = {};
  36     $args{superclasses} = do {
  37         no strict 'refs';
  38         \@{ $args{name} . '::ISA' };
  39     };
  40     $args{roles} ||= [];
  41
  42     bless \%args, $class;
  43 }
  44
  45 sub name { $_[0]->{name} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     @{ $self->{superclasses} };
  56 }
  57
  58 sub add_method {
  59     my $self = shift;
  60     my $name = shift;
  61     my $code = shift;
  62
  63     my $pkg = $self->name;
  64
  65     no strict 'refs';
  66     no warnings 'redefine';
  67     $self->{'methods'}->{$name}++; # Moose stores meta object here.
  68     *{ $pkg . '::' . $name } = $code;
  69 }
  70
  71 # copied from Class::Inspector
  72 my $get_methods_for_class = sub {
  73     my $self = shift;
  74     my $name = shift;
  75
  76     no strict 'refs';
  77     # Get all the CODE symbol table entries
  78     my @functions =
  79       grep !/^(?:has|with|around|before|after|blessed|extends|confess|override|super)$/,
  80       grep { defined &{"${name}::$_"} }
  81       keys %{"${name}::"};
  82     push @functions, keys %{$self->{'methods'}->{$name}} if $self;
  83     wantarray ? @functions : \@functions;
  84 };
  85
  86 sub get_method_list {
  87     my $self = shift;
  88     $get_methods_for_class->($self, $self->name);
  89 }
  90
  91 sub add_attribute {
  92     my $self = shift;
  93     my $attr = shift;
  94
  95     $self->{'attributes'}{$attr->name} = $attr;
  96 }
  97
  98 sub compute_all_applicable_attributes {
  99     my $self = shift;
 100     my (@attr, %seen);
 101
 102     for my $class ($self->linearized_isa) {
 103         my $meta = $self->_metaclass_cache($class)
 104             or next;
 105
 106         for my $name (keys %{ $meta->get_attribute_map }) {
 107             next if $seen{$name}++;
 108             push @attr, $meta->get_attribute($name);
 109         }
 110     }
 111
 112     return @attr;
 113 }
 114
 115 sub get_attribute_map { $_[0]->{attributes} }
 116 sub has_attribute     { exists $_[0]->{attributes}->{$_[1]} }
 117 sub get_attribute     { $_[0]->{attributes}->{$_[1]} }
 118
 119 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 120
 121 sub clone_object {
 122     my $class    = shift;
 123     my $instance = shift;
 124
 125     (blessed($instance) && $instance->isa($class->name))
 126         || confess "You must pass an instance of the metaclass (" . $class->name . "), not ($instance)";
 127
 128     $class->clone_instance($instance, @_);
 129 }
 130
 131 sub clone_instance {
 132     my ($class, $instance, %params) = @_;
 133
 134     (blessed($instance))
 135         || confess "You can only clone instances, ($instance) is not a blessed instance";
 136
 137     my $clone = bless { %$instance }, ref $instance;
 138
 139     foreach my $attr ($class->compute_all_applicable_attributes()) {
 140         if ( defined( my $init_arg = $attr->init_arg ) ) {
 141             if (exists $params{$init_arg}) {
 142                 $clone->{ $attr->name } = $params{$init_arg};
 143             }
 144         }
 145     }
 146
 147     return $clone;
 148
 149 }
 150
 151 sub make_immutable {
 152     my $self = shift;
 153     my %args = (
 154         inline_constructor => 1,
 155         @_,
 156     );
 157
 158     my $name = $self->name;
 159     $self->{is_immutable}++;
 160
 161     if ($args{inline_constructor}) {
 162         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 163     }
 164
 165     if ($args{inline_destructor}) {
 166         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 167     }
 168 }
 169
 170 sub make_mutable { confess "Mouse does not currently support 'make_mutable'" }
 171
 172 sub is_immutable { $_[0]->{is_immutable} }
 173
 174 sub attribute_metaclass { "Mouse::Meta::Class" }
 175
 176 sub _install_modifier {
 177     my ( $self, $into, $type, $name, $code ) = @_;
 178     if (eval "require Class::Method::Modifiers::Fast; 1") {
 179         Class::Method::Modifiers::Fast::_install_modifier(
 180             $into,
 181             $type,
 182             $name,
 183             $code
 184         );
 185     }
 186     else {
 187         require Class::Method::Modifiers;
 188         Class::Method::Modifiers::_install_modifier(
 189             $into,
 190             $type,
 191             $name,
 192             $code
 193         );
 194     }
 195 }
 196
 197 sub add_before_method_modifier {
 198     my ( $self, $name, $code ) = @_;
 199     $self->_install_modifier( $self->name, 'before', $name, $code );
 200 }
 201
 202 sub add_around_method_modifier {
 203     my ( $self, $name, $code ) = @_;
 204     $self->_install_modifier( $self->name, 'around', $name, $code );
 205 }
 206
 207 sub add_after_method_modifier {
 208     my ( $self, $name, $code ) = @_;
 209     $self->_install_modifier( $self->name, 'after', $name, $code );
 210 }
 211
 212 sub roles { $_[0]->{roles} }
 213
 214 sub does_role {
 215     my ($self, $role_name) = @_;
 216
 217     (defined $role_name)
 218         || confess "You must supply a role name to look for";
 219
 220     for my $role (@{ $self->{roles} }) {
 221         return 1 if $role->name eq $role_name;
 222     }
 223
 224     return 0;
 225 }
 226
 227 sub create {
 228     my ($self, $package_name, %options) = @_;
 229
 230     (ref $options{superclasses} eq 'ARRAY')
 231         || confess "You must pass an ARRAY ref of superclasses"
 232             if exists $options{superclasses};
 233
 234     (ref $options{attributes} eq 'ARRAY')
 235         || confess "You must pass an ARRAY ref of attributes"
 236             if exists $options{attributes};
 237
 238     (ref $options{methods} eq 'HASH')
 239         || confess "You must pass a HASH ref of methods"
 240             if exists $options{methods};
 241
 242     do {
 243         ( defined $package_name && $package_name )
 244           || confess "You must pass a package name";
 245
 246         my $code = "package $package_name;";
 247         $code .= "\$$package_name\:\:VERSION = '" . $options{version} . "';"
 248           if exists $options{version};
 249         $code .= "\$$package_name\:\:AUTHORITY = '" . $options{authority} . "';"
 250           if exists $options{authority};
 251
 252         eval $code;
 253         confess "creation of $package_name failed : $@" if $@;
 254     };
 255
 256     my %initialize_options = %options;
 257     delete @initialize_options{qw(
 258         package
 259         superclasses
 260         attributes
 261         methods
 262         version
 263         authority
 264     )};
 265     my $meta = $self->initialize( $package_name => %initialize_options );
 266
 267     # FIXME totally lame
 268     $meta->add_method('meta' => sub {
 269         $self->initialize(ref($_[0]) || $_[0]);
 270     });
 271
 272     $meta->superclasses(@{$options{superclasses}})
 273         if exists $options{superclasses};
 274     # NOTE:
 275     # process attributes first, so that they can
 276     # install accessors, but locally defined methods
 277     # can then overwrite them. It is maybe a little odd, but
 278     # I think this should be the order of things.
 279     if (exists $options{attributes}) {
 280         foreach my $attr (@{$options{attributes}}) {
 281             Mouse::Meta::Attribute->create($meta, $attr->{name}, %$attr);
 282         }
 283     }
 284     if (exists $options{methods}) {
 285         foreach my $method_name (keys %{$options{methods}}) {
 286             $meta->add_method($method_name, $options{methods}->{$method_name});
 287         }
 288     }
 289     return $meta;
 290 }
 291
 292 {
 293     my $ANON_CLASS_SERIAL = 0;
 294     my $ANON_CLASS_PREFIX = 'Mouse::Meta::Class::__ANON__::SERIAL::';
 295     sub create_anon_class {
 296         my ( $class, %options ) = @_;
 297         my $package_name = $ANON_CLASS_PREFIX . ++$ANON_CLASS_SERIAL;
 298         return $class->create( $package_name, %options );
 299     }
 300 }
 301
 302 1;
 303
 304 __END__
 305
 306 =head1 NAME
 307
 308 Mouse::Meta::Class - hook into the Mouse MOP
 309
 310 =head1 METHODS
 311
 312 =head2 initialize ClassName -> Mouse::Meta::Class
 313
 314 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 315 one instance should exist for a given class.
 316
 317 =head2 new %args -> Mouse::Meta::Class
 318
 319 Creates a new Mouse::Meta::Class. Don't call this directly.
 320
 321 =head2 name -> ClassName
 322
 323 Returns the name of the owner class.
 324
 325 =head2 superclasses -> [ClassName]
 326
 327 Gets (or sets) the list of superclasses of the owner class.
 328
 329 =head2 add_attribute Mouse::Meta::Attribute
 330
 331 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 332 class.
 333
 334 =head2 compute_all_applicable_attributes -> (Mouse::Meta::Attribute)
 335
 336 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 337 this class and its superclasses.
 338
 339 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 340
 341 Returns a mapping of attribute names to their corresponding
 342 L<Mouse::Meta::Attribute> objects.
 343
 344 =head2 has_attribute Name -> Bool
 345
 346 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 347
 348 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 349
 350 Returns the L<Mouse::Meta::Attribute> with the given name.
 351
 352 =head2 linearized_isa -> [ClassNames]
 353
 354 Returns the list of classes in method dispatch order, with duplicates removed.
 355
 356 =head2 clone_object Instance -> Instance
 357
 358 Clones the given C<Instance> which must be an instance governed by this
 359 metaclass.
 360
 361 =head2 clone_instance Instance, Parameters -> Instance
 362
 363 Clones the given C<Instance> and sets any additional parameters.
 364
 365 =cut
 366