lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Method::Constructor;
   7 use Mouse::Meta::Method::Destructor;
   8 use Mouse::Meta::Module;
   9 our @ISA = qw(Mouse::Meta::Module);
  10
  11 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  12 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  13
  14 sub constructor_class()   { 'Mouse::Meta::Method::Constructor' }
  15 sub destructor_class()    { 'Mouse::Meta::Method::Destructor'  }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class;
  42
  43 sub roles;
  44
  45 sub calculate_all_roles {
  46     my $self = shift;
  47     my %seen;
  48     return grep { !$seen{ $_->name }++ }
  49            map  { $_->calculate_all_roles } @{ $self->roles };
  50 }
  51
  52 sub superclasses {
  53     my $self = shift;
  54
  55     if (@_) {
  56         foreach my $super(@_){
  57             Mouse::Util::load_class($super);
  58             my $meta = Mouse::Util::get_metaclass_by_name($super);
  59             if($meta && $meta->isa('Mouse::Meta::Role')){
  60                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  61             }
  62         }
  63         @{ $self->{superclasses} } = @_;
  64     }
  65
  66     return @{ $self->{superclasses} };
  67 }
  68
  69 sub find_method_by_name{
  70     my($self, $method_name) = @_;
  71     defined($method_name)
  72         or $self->throw_error('You must define a method name to find');
  73
  74     foreach my $class( $self->linearized_isa ){
  75         my $method = $self->initialize($class)->get_method($method_name);
  76         return $method if defined $method;
  77     }
  78     return undef;
  79 }
  80
  81 sub get_all_methods {
  82     my($self) = @_;
  83     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  84 }
  85
  86 sub get_all_method_names {
  87     my $self = shift;
  88     my %uniq;
  89     return grep { $uniq{$_}++ == 0 }
  90             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  91             $self->linearized_isa;
  92 }
  93
  94 sub find_attribute_by_name{
  95     my($self, $name) = @_;
  96     my $attr;
  97     foreach my $class($self->linearized_isa){
  98         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  99         $attr = $meta->get_attribute($name) and last;
 100     }
 101     return $attr;
 102 }
 103
 104 sub add_attribute {
 105     my $self = shift;
 106
 107     my($attr, $name);
 108
 109     if(blessed $_[0]){
 110         $attr = $_[0];
 111
 112         $attr->isa('Mouse::Meta::Attribute')
 113             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 114
 115         $name = $attr->name;
 116     }
 117     else{
 118         # _process_attribute
 119         $name = shift;
 120
 121         my %args = (@_ == 1) ? %{$_[0]} : @_;
 122
 123         defined($name)
 124             or $self->throw_error('You must provide a name for the attribute');
 125
 126         if ($name =~ s/^\+//) { # inherited attributes
 127             my $inherited_attr = $self->find_attribute_by_name($name)
 128                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 129
 130             $attr = $inherited_attr->clone_and_inherit_options(%args);
 131         }
 132         else{
 133             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 134             $args{traits} = \@traits if @traits;
 135
 136             $attr = $attribute_class->new($name, %args);
 137         }
 138     }
 139
 140     weaken( $attr->{associated_class} = $self );
 141
 142     $self->{attributes}{$attr->name} = $attr;
 143     $attr->install_accessors();
 144
 145     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 146         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 147     }
 148     return $attr;
 149 }
 150
 151 sub compute_all_applicable_attributes {
 152     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 153         if _MOUSE_VERBOSE;
 154     return shift->get_all_attributes(@_)
 155 }
 156
 157 sub get_all_attributes {
 158     my $self = shift;
 159     my (@attr, %seen);
 160
 161     for my $class ($self->linearized_isa) {
 162         my $meta = Mouse::Util::get_metaclass_by_name($class)
 163             or next;
 164
 165         for my $name ($meta->get_attribute_list) {
 166             next if $seen{$name}++;
 167             push @attr, $meta->get_attribute($name);
 168         }
 169     }
 170
 171     return @attr;
 172 }
 173
 174 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 175
 176 sub new_object {
 177     my $self = shift;
 178     my %args = (@_ == 1 ? %{$_[0]} : @_);
 179
 180     my $object = bless {}, $self->name;
 181
 182     $self->_initialize_object($object, \%args);
 183     return $object;
 184 }
 185
 186 sub _initialize_object{
 187     my($self, $object, $args) = @_;
 188
 189     my @triggers_queue;
 190
 191     foreach my $attribute ($self->get_all_attributes) {
 192         my $from = $attribute->init_arg;
 193         my $key  = $attribute->name;
 194
 195         if (defined($from) && exists($args->{$from})) {
 196             $object->{$key} = $attribute->_coerce_and_verify($args->{$from}, $object);
 197
 198             weaken($object->{$key})
 199                 if ref($object->{$key}) && $attribute->is_weak_ref;
 200
 201             if ($attribute->has_trigger) {
 202                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 203             }
 204         }
 205         else {
 206             if ($attribute->has_default || $attribute->has_builder) {
 207                 unless ($attribute->is_lazy) {
 208                     my $default = $attribute->default;
 209                     my $builder = $attribute->builder;
 210                     my $value =   $builder                ? $object->$builder()
 211                                 : ref($default) eq 'CODE' ? $object->$default()
 212                                 :                           $default;
 213
 214                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);
 215
 216                     weaken($object->{$key})
 217                         if ref($object->{$key}) && $attribute->is_weak_ref;
 218                 }
 219             }
 220             else {
 221                 if ($attribute->is_required) {
 222                     $self->throw_error("Attribute (".$attribute->name.") is required");
 223                 }
 224             }
 225         }
 226     }
 227
 228     foreach my $trigger_and_value(@triggers_queue){
 229         my($trigger, $value) = @{$trigger_and_value};
 230         $trigger->($object, $value);
 231     }
 232
 233     if($self->is_anon_class){
 234         $object->{__METACLASS__} = $self;
 235     }
 236
 237     return $object;
 238 }
 239
 240 sub clone_object {
 241     my $class  = shift;
 242     my $object = shift;
 243     my %params = (@_ == 1) ? %{$_[0]} : @_;
 244
 245     (blessed($object) && $object->isa($class->name))
 246         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 247
 248     my $cloned = bless { %$object }, ref $object;
 249     $class->_initialize_object($cloned, \%params);
 250
 251     return $cloned;
 252 }
 253
 254 sub clone_instance {
 255     my ($class, $instance, %params) = @_;
 256
 257     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 258         if _MOUSE_VERBOSE;
 259     return $class->clone_object($instance, %params);
 260 }
 261
 262 sub make_immutable {
 263     my $self = shift;
 264     my %args = (
 265         inline_constructor => 1,
 266         inline_destructor  => 1,
 267         constructor_name   => 'new',
 268         @_,
 269     );
 270
 271     $self->{is_immutable}++;
 272
 273     if ($args{inline_constructor}) {
 274         $self->add_method($args{constructor_name} =>
 275             $self->constructor_class->_generate_constructor($self, \%args));
 276     }
 277
 278     if ($args{inline_destructor}) {
 279         $self->add_method(DESTROY =>
 280             $self->destructor_class->_generate_destructor($self, \%args));
 281     }
 282
 283     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 284     # at the end of a source file.
 285     return 1;
 286 }
 287
 288 sub make_mutable { not_supported }
 289
 290 sub is_immutable {  $_[0]->{is_immutable} }
 291 sub is_mutable   { !$_[0]->{is_immutable} }
 292
 293 sub _install_modifier_pp{
 294     my( $self, $type, $name, $code ) = @_;
 295     my $into = $self->name;
 296
 297     my $original = $into->can($name)
 298         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 299
 300     my $modifier_table = $self->{modifiers}{$name};
 301
 302     if(!$modifier_table){
 303         my(@before, @after, @around, $cache, $modified);
 304
 305         $cache = $original;
 306
 307         $modified = sub {
 308             for my $c (@before) { $c->(@_) }
 309
 310             if(wantarray){ # list context
 311                 my @rval = $cache->(@_);
 312
 313                 for my $c(@after){ $c->(@_) }
 314                 return @rval;
 315             }
 316             elsif(defined wantarray){ # scalar context
 317                 my $rval = $cache->(@_);
 318
 319                 for my $c(@after){ $c->(@_) }
 320                 return $rval;
 321             }
 322             else{ # void context
 323                 $cache->(@_);
 324
 325                 for my $c(@after){ $c->(@_) }
 326                 return;
 327             }
 328         };
 329
 330         $self->{modifiers}{$name} = $modifier_table = {
 331             original => $original,
 332
 333             before   => \@before,
 334             after    => \@after,
 335             around   => \@around,
 336
 337             cache    => \$cache, # cache for around modifiers
 338         };
 339
 340         $self->add_method($name => $modified);
 341     }
 342
 343     if($type eq 'before'){
 344         unshift @{$modifier_table->{before}}, $code;
 345     }
 346     elsif($type eq 'after'){
 347         push @{$modifier_table->{after}}, $code;
 348     }
 349     else{ # around
 350         push @{$modifier_table->{around}}, $code;
 351
 352         my $next = ${ $modifier_table->{cache} };
 353         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 354     }
 355
 356     return;
 357 }
 358
 359 sub _install_modifier {
 360     my ( $self, $type, $name, $code ) = @_;
 361
 362     # load Class::Method::Modifiers first
 363     my $no_cmm_fast = do{
 364         local $@;
 365         eval q{ require Class::Method::Modifiers::Fast };
 366         $@;
 367     };
 368
 369     my $impl;
 370     if($no_cmm_fast){
 371         $impl = \&_install_modifier_pp;
 372     }
 373     else{
 374         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 375         $impl = sub {
 376             my ( $self, $type, $name, $code ) = @_;
 377             my $into = $self->name;
 378             $install_modifier->($into, $type, $name, $code);
 379
 380             $self->add_method($name => do{
 381                 no strict 'refs';
 382                 \&{ $into . '::' . $name };
 383             });
 384             return;
 385         };
 386     }
 387
 388     # replace this method itself :)
 389     {
 390         no warnings 'redefine';
 391         *_install_modifier = $impl;
 392     }
 393
 394     $self->$impl( $type, $name, $code );
 395 }
 396
 397 sub add_before_method_modifier {
 398     my ( $self, $name, $code ) = @_;
 399     $self->_install_modifier( 'before', $name, $code );
 400 }
 401
 402 sub add_around_method_modifier {
 403     my ( $self, $name, $code ) = @_;
 404     $self->_install_modifier( 'around', $name, $code );
 405 }
 406
 407 sub add_after_method_modifier {
 408     my ( $self, $name, $code ) = @_;
 409     $self->_install_modifier( 'after', $name, $code );
 410 }
 411
 412 sub add_override_method_modifier {
 413     my ($self, $name, $code) = @_;
 414
 415     if($self->has_method($name)){
 416         $self->throw_error("Cannot add an override method if a local method is already present");
 417     }
 418
 419     my $package = $self->name;
 420
 421     my $super_body = $package->can($name)
 422         or $self->throw_error("You cannot override '$name' because it has no super method");
 423
 424     $self->add_method($name => sub {
 425         local $Mouse::SUPER_PACKAGE = $package;
 426         local $Mouse::SUPER_BODY    = $super_body;
 427         local @Mouse::SUPER_ARGS    = @_;
 428
 429         $code->(@_);
 430     });
 431     return;
 432 }
 433
 434 sub add_augment_method_modifier {
 435     my ($self, $name, $code) = @_;
 436     if($self->has_method($name)){
 437         $self->throw_error("Cannot add an augment method if a local method is already present");
 438     }
 439
 440     my $super = $self->find_method_by_name($name)
 441         or $self->throw_error("You cannot augment '$name' because it has no super method");
 442
 443     my $super_package = $super->package_name;
 444     my $super_body    = $super->body;
 445
 446     $self->add_method($name => sub{
 447         local $Mouse::INNER_BODY{$super_package} = $code;
 448         local $Mouse::INNER_ARGS{$super_package} = [@_];
 449         $super_body->(@_);
 450     });
 451     return;
 452 }
 453
 454 sub does_role {
 455     my ($self, $role_name) = @_;
 456
 457     (defined $role_name)
 458         || $self->throw_error("You must supply a role name to look for");
 459
 460     for my $class ($self->linearized_isa) {
 461         my $meta = Mouse::Util::get_metaclass_by_name($class)
 462             or next;
 463
 464         for my $role (@{ $meta->roles }) {
 465
 466             return 1 if $role->does_role($role_name);
 467         }
 468     }
 469
 470     return 0;
 471 }
 472
 473 1;
 474 __END__
 475
 476 =head1 NAME
 477
 478 Mouse::Meta::Class - The Mouse class metaclass
 479
 480 =head1 VERSION
 481
 482 This document describes Mouse version 0.40
 483
 484 =head1 METHODS
 485
 486 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 487
 488 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 489 one instance should exist for a given class.
 490
 491 =head2 C<< name -> ClassName >>
 492
 493 Returns the name of the owner class.
 494
 495 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 496
 497 Gets (or sets) the list of superclasses of the owner class.
 498
 499 =head2 C<< add_method(name => CodeRef) >>
 500
 501 Adds a method to the owner class.
 502
 503 =head2 C<< has_method(name) -> Bool >>
 504
 505 Returns whether we have a method with the given name.
 506
 507 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 508
 509 Returns a L<Mouse::Meta::Method> with the given name.
 510
 511 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 512
 513 =head2 C<< get_method_list -> Names >>
 514
 515 Returns a list of method names which are defined in the local class.
 516 If you want a list of all applicable methods for a class, use the
 517 C<get_all_methods> method.
 518
 519 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 520
 521 Return the list of all L<Mouse::Meta::Method> instances associated with
 522 the class and its superclasses.
 523
 524 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 525
 526 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 527 class.
 528
 529 =head2 C<< has_attribute(Name) -> Bool >>
 530
 531 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 532
 533 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 534
 535 Returns the L<Mouse::Meta::Attribute> with the given name.
 536
 537 =head2 C<< get_attribute_list -> Names >>
 538
 539 Returns a list of attribute names which are defined in the local
 540 class. If you want a list of all applicable attributes for a class,
 541 use the C<get_all_attributes> method.
 542
 543 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 544
 545 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 546 this class and its superclasses.
 547
 548 =head2 C<< linearized_isa -> [ClassNames] >>
 549
 550 Returns the list of classes in method dispatch order, with duplicates removed.
 551
 552 =head2 C<< new_object(Parameters) -> Instance >>
 553
 554 Creates a new instance.
 555
 556 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 557
 558 Clones the given instance which must be an instance governed by this
 559 metaclass.
 560
 561 =head2 C<< throw_error(Message, Parameters) >>
 562
 563 Throws an error with the given message.
 564
 565 =head1 SEE ALSO
 566
 567 L<Moose::Meta::Class>
 568
 569 L<Class::MOP::Class>
 570
 571 =cut
 572