lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util qw/blessed weaken/;
   6
   7 use Mouse::Util qw/get_linear_isa not_supported/;
   8
   9 use Mouse::Meta::Method::Constructor;
  10 use Mouse::Meta::Method::Destructor;
  11 use Mouse::Meta::Module;
  12
  13 use base qw(Mouse::Meta::Module);
  14
  15 sub method_metaclass(){ 'Mouse::Meta::Method' } # required for get_method()
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     #return Mouse::Meta::Class->initialize($class)->new_object(%args)
  30     #    if $class ne __PACKAGE__;
  31
  32     return bless \%args, ref($class) || $class;
  33 }
  34
  35 sub create_anon_class{
  36     my $self = shift;
  37     return $self->create(undef, @_);
  38 }
  39
  40 sub is_anon_class{
  41     return exists $_[0]->{anon_serial_id};
  42 }
  43
  44 sub roles { $_[0]->{roles} }
  45
  46 sub superclasses {
  47     my $self = shift;
  48
  49     if (@_) {
  50         Mouse::load_class($_) for @_;
  51         @{ $self->{superclasses} } = @_;
  52     }
  53
  54     return @{ $self->{superclasses} };
  55 }
  56
  57 sub find_method_by_name{
  58     my($self, $method_name) = @_;
  59     defined($method_name)
  60         or $self->throw_error('You must define a method name to find');
  61     foreach my $class( $self->linearized_isa ){
  62         my $method = $self->initialize($class)->get_method($method_name);
  63         return $method if defined $method;
  64     }
  65     return undef;
  66 }
  67
  68 sub get_all_methods {
  69     my($self) = @_;
  70     return map{ $self->find_method_by_name($self) } $self->get_all_method_names;
  71 }
  72
  73 sub get_all_method_names {
  74     my $self = shift;
  75     my %uniq;
  76     return grep { $uniq{$_}++ == 0 }
  77             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  78             $self->linearized_isa;
  79 }
  80
  81 sub add_attribute {
  82     my $self = shift;
  83
  84     my($attr, $name);
  85
  86     if(blessed $_[0]){
  87         $attr = $_[0];
  88
  89         $attr->isa('Mouse::Meta::Attribute')
  90             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
  91
  92         $name = $attr->name;
  93     }
  94     else{
  95         # _process_attribute
  96         $name = shift;
  97
  98         my %args = (@_ == 1) ? %{$_[0]} : @_;
  99
 100         defined($name)
 101             or $self->throw_error('You must provide a name for the attribute');
 102
 103         if ($name =~ s/^\+//) { # inherited attributes
 104             my $inherited_attr;
 105
 106             foreach my $class($self->linearized_isa){
 107                 my $meta = Mouse::Meta::Module::get_metaclass_by_name($class) or next;
 108                 $inherited_attr = $meta->get_attribute($name) and last;
 109             }
 110
 111             defined($inherited_attr)
 112                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 113
 114             $attr = $inherited_attr->clone_and_inherit_options($name, \%args);
 115         }
 116         else{
 117             my($attribute_class, @traits) = Mouse::Meta::Attribute->interpolate_class($name, \%args);
 118             $args{traits} = \@traits if @traits;
 119
 120             $attr = $attribute_class->new($name, \%args);
 121         }
 122     }
 123
 124     weaken( $attr->{associated_class} = $self );
 125
 126     $self->{attributes}{$attr->name} = $attr;
 127     $attr->install_accessors();
 128
 129     if(!$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 130         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 131     }
 132     return $attr;
 133 }
 134
 135 sub compute_all_applicable_attributes { shift->get_all_attributes(@_) }
 136 sub get_all_attributes {
 137     my $self = shift;
 138     my (@attr, %seen);
 139
 140     for my $class ($self->linearized_isa) {
 141         my $meta = $self->_metaclass_cache($class)
 142             or next;
 143
 144         for my $name (keys %{ $meta->get_attribute_map }) {
 145             next if $seen{$name}++;
 146             push @attr, $meta->get_attribute($name);
 147         }
 148     }
 149
 150     return @attr;
 151 }
 152
 153 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 154
 155 sub new_object {
 156     my $self = shift;
 157     my %args = (@_ == 1 ? %{$_[0]} : @_);
 158
 159     my $instance = bless {}, $self->name;
 160
 161     $self->_initialize_instance($instance, \%args);
 162     return $instance;
 163 }
 164
 165 sub _initialize_instance{
 166     my($self, $instance, $args) = @_;
 167
 168     my @triggers_queue;
 169
 170     foreach my $attribute ($self->get_all_attributes) {
 171         my $from = $attribute->init_arg;
 172         my $key  = $attribute->name;
 173
 174         if (defined($from) && exists($args->{$from})) {
 175             $args->{$from} = $attribute->coerce_constraint($args->{$from})
 176                 if $attribute->should_coerce;
 177
 178             $attribute->verify_against_type_constraint($args->{$from});
 179
 180             $instance->{$key} = $args->{$from};
 181
 182             weaken($instance->{$key})
 183                 if ref($instance->{$key}) && $attribute->is_weak_ref;
 184
 185             if ($attribute->has_trigger) {
 186                 push @triggers_queue, [ $attribute->trigger, $args->{$from} ];
 187             }
 188         }
 189         else {
 190             if ($attribute->has_default || $attribute->has_builder) {
 191                 unless ($attribute->is_lazy) {
 192                     my $default = $attribute->default;
 193                     my $builder = $attribute->builder;
 194                     my $value = $attribute->has_builder
 195                               ? $instance->$builder
 196                               : ref($default) eq 'CODE'
 197                                   ? $default->($instance)
 198                                   : $default;
 199
 200                     $value = $attribute->coerce_constraint($value)
 201                         if $attribute->should_coerce;
 202                     $attribute->verify_against_type_constraint($value);
 203
 204                     $instance->{$key} = $value;
 205
 206                     weaken($instance->{$key})
 207                         if ref($instance->{$key}) && $attribute->is_weak_ref;
 208                 }
 209             }
 210             else {
 211                 if ($attribute->is_required) {
 212                     $self->throw_error("Attribute (".$attribute->name.") is required");
 213                 }
 214             }
 215         }
 216     }
 217
 218     foreach my $trigger_and_value(@triggers_queue){
 219         my($trigger, $value) = @{$trigger_and_value};
 220         $trigger->($instance, $value);
 221     }
 222
 223     if($self->is_anon_class){
 224         $instance->{__METACLASS__} = $self;
 225     }
 226
 227     return $instance;
 228 }
 229
 230 sub clone_object {
 231     my $class    = shift;
 232     my $instance = shift;
 233     my %params   = (@_ == 1) ? %{$_[0]} : @_;
 234
 235     (blessed($instance) && $instance->isa($class->name))
 236         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($instance)");
 237
 238     my $clone = bless { %$instance }, ref $instance;
 239
 240     foreach my $attr ($class->get_all_attributes()) {
 241         if ( defined( my $init_arg = $attr->init_arg ) ) {
 242             if (exists $params{$init_arg}) {
 243                 $clone->{ $attr->name } = $params{$init_arg};
 244             }
 245         }
 246     }
 247
 248     return $clone;
 249 }
 250
 251 sub clone_instance {
 252     my ($class, $instance, %params) = @_;
 253
 254     Carp::cluck('clone_instance has been deprecated. Use clone_object instead');
 255     return $class->clone_object($instance, %params);
 256 }
 257
 258 sub make_immutable {
 259     my $self = shift;
 260     my %args = (
 261         inline_constructor => 1,
 262         inline_destructor  => 1,
 263         @_,
 264     );
 265
 266     $self->{is_immutable}++;
 267
 268     if ($args{inline_constructor}) {
 269         $self->add_method('new' => Mouse::Meta::Method::Constructor->generate_constructor_method_inline( $self ));
 270     }
 271
 272     if ($args{inline_destructor}) {
 273         $self->add_method('DESTROY' => Mouse::Meta::Method::Destructor->generate_destructor_method_inline( $self ));
 274     }
 275
 276     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 277     # at the end of a source file.
 278     return 1;
 279 }
 280
 281 sub make_mutable { not_supported }
 282
 283 sub is_immutable {  $_[0]->{is_immutable} }
 284 sub is_mutable   { !$_[0]->{is_immutable} }
 285
 286 sub _install_modifier {
 287     my ( $self, $into, $type, $name, $code ) = @_;
 288
 289     # which is modifer class available?
 290     my $modifier_class = do {
 291         if (eval "require Class::Method::Modifiers::Fast; 1") {
 292             'Class::Method::Modifiers::Fast';
 293         } elsif (eval "require Class::Method::Modifiers; 1") {
 294             'Class::Method::Modifiers';
 295         } else {
 296             Carp::croak("Method modifiers require the use of Class::Method::Modifiers or Class::Method::Modifiers::Fast. Please install it from CPAN and file a bug report with this application.");
 297         }
 298     };
 299     my $modifier = $modifier_class->can('_install_modifier');
 300
 301     # replace this method itself :)
 302     {
 303         no warnings 'redefine';
 304         *_install_modifier = sub {
 305             my ( $self, $into, $type, $name, $code ) = @_;
 306             $modifier->(
 307                 $into,
 308                 $type,
 309                 $name,
 310                 $code
 311             );
 312             $self->{methods}{$name}++; # register it to the method map
 313             return;
 314         };
 315     }
 316
 317     # call me. for first time.
 318     $self->_install_modifier( $into, $type, $name, $code );
 319 }
 320
 321 sub add_before_method_modifier {
 322     my ( $self, $name, $code ) = @_;
 323     $self->_install_modifier( $self->name, 'before', $name, $code );
 324 }
 325
 326 sub add_around_method_modifier {
 327     my ( $self, $name, $code ) = @_;
 328     $self->_install_modifier( $self->name, 'around', $name, $code );
 329 }
 330
 331 sub add_after_method_modifier {
 332     my ( $self, $name, $code ) = @_;
 333     $self->_install_modifier( $self->name, 'after', $name, $code );
 334 }
 335
 336 sub add_override_method_modifier {
 337     my ($self, $name, $code) = @_;
 338
 339     my $package = $self->name;
 340
 341     my $body = $package->can($name)
 342         or $self->throw_error("You cannot override '$name' because it has no super method");
 343
 344     $self->add_method($name => sub { $code->($package, $body, @_) });
 345 }
 346
 347 sub does_role {
 348     my ($self, $role_name) = @_;
 349
 350     (defined $role_name)
 351         || $self->throw_error("You must supply a role name to look for");
 352
 353     for my $class ($self->linearized_isa) {
 354         my $meta = Mouse::Meta::Module::class_of($class);
 355         next unless $meta && $meta->can('roles');
 356
 357         for my $role (@{ $meta->roles }) {
 358
 359             return 1 if $role->does_role($role_name);
 360         }
 361     }
 362
 363     return 0;
 364 }
 365
 366 1;
 367
 368 __END__
 369
 370 =head1 NAME
 371
 372 Mouse::Meta::Class - hook into the Mouse MOP
 373
 374 =head1 METHODS
 375
 376 =head2 initialize ClassName -> Mouse::Meta::Class
 377
 378 Finds or creates a Mouse::Meta::Class instance for the given ClassName. Only
 379 one instance should exist for a given class.
 380
 381 =head2 name -> ClassName
 382
 383 Returns the name of the owner class.
 384
 385 =head2 superclasses -> [ClassName]
 386
 387 Gets (or sets) the list of superclasses of the owner class.
 388
 389 =head2 add_attribute (name => spec | Mouse::Meta::Attribute)
 390
 391 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 392 class.
 393
 394 =head2 get_all_attributes -> (Mouse::Meta::Attribute)
 395
 396 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 397 this class and its superclasses.
 398
 399 =head2 get_attribute_map -> { name => Mouse::Meta::Attribute }
 400
 401 Returns a mapping of attribute names to their corresponding
 402 L<Mouse::Meta::Attribute> objects.
 403
 404 =head2 get_attribute_list -> { name => Mouse::Meta::Attribute }
 405
 406 This returns a list of attribute names which are defined in the local
 407 class. If you want a list of all applicable attributes for a class,
 408 use the C<get_all_attributes> method.
 409
 410 =head2 has_attribute Name -> Bool
 411
 412 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 413
 414 =head2 get_attribute Name -> Mouse::Meta::Attribute | undef
 415
 416 Returns the L<Mouse::Meta::Attribute> with the given name.
 417
 418 =head2 linearized_isa -> [ClassNames]
 419
 420 Returns the list of classes in method dispatch order, with duplicates removed.
 421
 422 =head2 new_object Parameters -> Instance
 423
 424 Create a new instance.
 425
 426 =head2 clone_object Instance -> Instance
 427
 428 Clones the given C<Instance> which must be an instance governed by this
 429 metaclass.
 430
 431 =head1 BUGS
 432
 433 All complex software has bugs lurking in it, and this module is no
 434 exception. If you find a bug please either email me, or add the bug
 435 to cpan-RT.
 436
 437 =cut
 438