lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 sub method_metaclass;
  10 sub attribute_metaclass;
  11
  12 sub constructor_class;
  13 sub destructor_class;
  14
  15 sub _construct_meta {
  16     my($class, %args) = @_;
  17
  18     $args{attributes} = {};
  19     $args{methods}    = {};
  20     $args{roles}      = [];
  21
  22     $args{superclasses} = do {
  23         no strict 'refs';
  24         \@{ $args{package} . '::ISA' };
  25     };
  26
  27     my $self = bless \%args, ref($class) || $class;
  28     if(ref($self) ne __PACKAGE__){
  29         $self->meta->_initialize_object($self, \%args);
  30     }
  31     return $self;
  32 }
  33
  34 sub create_anon_class{
  35     my $self = shift;
  36     return $self->create(undef, @_);
  37 }
  38
  39 sub is_anon_class;
  40
  41 sub roles;
  42
  43 sub calculate_all_roles {
  44     my $self = shift;
  45     my %seen;
  46     return grep { !$seen{ $_->name }++ }
  47            map  { $_->calculate_all_roles } @{ $self->roles };
  48 }
  49
  50 sub superclasses {
  51     my $self = shift;
  52
  53     if (@_) {
  54         foreach my $super(@_){
  55             Mouse::Util::load_class($super);
  56             my $meta = Mouse::Util::get_metaclass_by_name($super);
  57             if(Mouse::Util::is_a_metarole($meta)){
  58                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  59             }
  60         }
  61         @{ $self->{superclasses} } = @_;
  62     }
  63
  64     return @{ $self->{superclasses} };
  65 }
  66
  67 sub find_method_by_name{
  68     my($self, $method_name) = @_;
  69     defined($method_name)
  70         or $self->throw_error('You must define a method name to find');
  71
  72     foreach my $class( $self->linearized_isa ){
  73         my $method = $self->initialize($class)->get_method($method_name);
  74         return $method if defined $method;
  75     }
  76     return undef;
  77 }
  78
  79 sub get_all_methods {
  80     my($self) = @_;
  81     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  82 }
  83
  84 sub get_all_method_names {
  85     my $self = shift;
  86     my %uniq;
  87     return grep { $uniq{$_}++ == 0 }
  88             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  89             $self->linearized_isa;
  90 }
  91
  92 sub find_attribute_by_name{
  93     my($self, $name) = @_;
  94     my $attr;
  95     foreach my $class($self->linearized_isa){
  96         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
  97         $attr = $meta->get_attribute($name) and last;
  98     }
  99     return $attr;
 100 }
 101
 102 sub add_attribute {
 103     my $self = shift;
 104
 105     my($attr, $name);
 106
 107     if(blessed $_[0]){
 108         $attr = $_[0];
 109
 110         $attr->isa('Mouse::Meta::Attribute')
 111             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 112
 113         $name = $attr->name;
 114     }
 115     else{
 116         # _process_attribute
 117         $name = shift;
 118
 119         my %args = (@_ == 1) ? %{$_[0]} : @_;
 120
 121         defined($name)
 122             or $self->throw_error('You must provide a name for the attribute');
 123
 124         if ($name =~ s/^\+//) { # inherited attributes
 125             my $inherited_attr = $self->find_attribute_by_name($name)
 126                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 127
 128             $attr = $inherited_attr->clone_and_inherit_options(%args);
 129         }
 130         else{
 131             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 132             $args{traits} = \@traits if @traits;
 133
 134             $attr = $attribute_class->new($name, %args);
 135         }
 136     }
 137
 138     weaken( $attr->{associated_class} = $self );
 139
 140     $self->{attributes}{$attr->name} = $attr;
 141     $attr->install_accessors();
 142
 143     if(Mouse::Util::_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 144         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 145     }
 146     return $attr;
 147 }
 148
 149 sub compute_all_applicable_attributes {
 150     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 151         if Mouse::Util::_MOUSE_VERBOSE;
 152     return shift->get_all_attributes(@_)
 153 }
 154
 155 sub linearized_isa;
 156
 157 sub new_object;
 158
 159 sub clone_object {
 160     my $class  = shift;
 161     my $object = shift;
 162     my %params = (@_ == 1) ? %{$_[0]} : @_;
 163
 164     (blessed($object) && $object->isa($class->name))
 165         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 166
 167     my $cloned = bless { %$object }, ref $object;
 168     $class->_initialize_object($cloned, \%params);
 169
 170     return $cloned;
 171 }
 172
 173 sub clone_instance {
 174     my ($class, $instance, %params) = @_;
 175
 176     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 177         if Mouse::Util::_MOUSE_VERBOSE;
 178     return $class->clone_object($instance, %params);
 179 }
 180
 181 sub make_immutable {
 182     my $self = shift;
 183     my %args = (
 184         inline_constructor => 1,
 185         inline_destructor  => 1,
 186         constructor_name   => 'new',
 187         @_,
 188     );
 189
 190     $self->{is_immutable}++;
 191
 192     if ($args{inline_constructor}) {
 193         my $c = $self->constructor_class;
 194         Mouse::Util::load_class($c);
 195         $self->add_method($args{constructor_name} =>
 196             $c->_generate_constructor($self, \%args));
 197     }
 198
 199     if ($args{inline_destructor}) {
 200         my $c = $self->destructor_class;
 201         Mouse::Util::load_class($c);
 202         $self->add_method(DESTROY =>
 203             $c->_generate_destructor($self, \%args));
 204     }
 205
 206     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 207     # at the end of a source file.
 208     return 1;
 209 }
 210
 211 sub make_mutable { not_supported }
 212
 213 sub is_immutable {  $_[0]->{is_immutable} }
 214 sub is_mutable   { !$_[0]->{is_immutable} }
 215
 216 sub _install_modifier_pp{
 217     my( $self, $type, $name, $code ) = @_;
 218     my $into = $self->name;
 219
 220     my $original = $into->can($name)
 221         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 222
 223     my $modifier_table = $self->{modifiers}{$name};
 224
 225     if(!$modifier_table){
 226         my(@before, @after, @around, $cache, $modified);
 227
 228         $cache = $original;
 229
 230         $modified = sub {
 231             for my $c (@before) { $c->(@_) }
 232
 233             if(wantarray){ # list context
 234                 my @rval = $cache->(@_);
 235
 236                 for my $c(@after){ $c->(@_) }
 237                 return @rval;
 238             }
 239             elsif(defined wantarray){ # scalar context
 240                 my $rval = $cache->(@_);
 241
 242                 for my $c(@after){ $c->(@_) }
 243                 return $rval;
 244             }
 245             else{ # void context
 246                 $cache->(@_);
 247
 248                 for my $c(@after){ $c->(@_) }
 249                 return;
 250             }
 251         };
 252
 253         $self->{modifiers}{$name} = $modifier_table = {
 254             original => $original,
 255
 256             before   => \@before,
 257             after    => \@after,
 258             around   => \@around,
 259
 260             cache    => \$cache, # cache for around modifiers
 261         };
 262
 263         $self->add_method($name => $modified);
 264     }
 265
 266     if($type eq 'before'){
 267         unshift @{$modifier_table->{before}}, $code;
 268     }
 269     elsif($type eq 'after'){
 270         push @{$modifier_table->{after}}, $code;
 271     }
 272     else{ # around
 273         push @{$modifier_table->{around}}, $code;
 274
 275         my $next = ${ $modifier_table->{cache} };
 276         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 277     }
 278
 279     return;
 280 }
 281
 282 sub _install_modifier {
 283     my ( $self, $type, $name, $code ) = @_;
 284
 285     # load Class::Method::Modifiers first
 286     my $no_cmm_fast = do{
 287         local $@;
 288         eval q{ require Class::Method::Modifiers::Fast };
 289         $@;
 290     };
 291
 292     my $impl;
 293     if($no_cmm_fast){
 294         $impl = \&_install_modifier_pp;
 295     }
 296     else{
 297         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 298         $impl = sub {
 299             my ( $self, $type, $name, $code ) = @_;
 300             my $into = $self->name;
 301             $install_modifier->($into, $type, $name, $code);
 302
 303             $self->add_method($name => do{
 304                 no strict 'refs';
 305                 \&{ $into . '::' . $name };
 306             });
 307             return;
 308         };
 309     }
 310
 311     # replace this method itself :)
 312     {
 313         no warnings 'redefine';
 314         *_install_modifier = $impl;
 315     }
 316
 317     $self->$impl( $type, $name, $code );
 318 }
 319
 320 sub add_before_method_modifier {
 321     my ( $self, $name, $code ) = @_;
 322     $self->_install_modifier( 'before', $name, $code );
 323 }
 324
 325 sub add_around_method_modifier {
 326     my ( $self, $name, $code ) = @_;
 327     $self->_install_modifier( 'around', $name, $code );
 328 }
 329
 330 sub add_after_method_modifier {
 331     my ( $self, $name, $code ) = @_;
 332     $self->_install_modifier( 'after', $name, $code );
 333 }
 334
 335 sub add_override_method_modifier {
 336     my ($self, $name, $code) = @_;
 337
 338     if($self->has_method($name)){
 339         $self->throw_error("Cannot add an override method if a local method is already present");
 340     }
 341
 342     my $package = $self->name;
 343
 344     my $super_body = $package->can($name)
 345         or $self->throw_error("You cannot override '$name' because it has no super method");
 346
 347     $self->add_method($name => sub {
 348         local $Mouse::SUPER_PACKAGE = $package;
 349         local $Mouse::SUPER_BODY    = $super_body;
 350         local @Mouse::SUPER_ARGS    = @_;
 351
 352         $code->(@_);
 353     });
 354     return;
 355 }
 356
 357 sub add_augment_method_modifier {
 358     my ($self, $name, $code) = @_;
 359     if($self->has_method($name)){
 360         $self->throw_error("Cannot add an augment method if a local method is already present");
 361     }
 362
 363     my $super = $self->find_method_by_name($name)
 364         or $self->throw_error("You cannot augment '$name' because it has no super method");
 365
 366     my $super_package = $super->package_name;
 367     my $super_body    = $super->body;
 368
 369     $self->add_method($name => sub{
 370         local $Mouse::INNER_BODY{$super_package} = $code;
 371         local $Mouse::INNER_ARGS{$super_package} = [@_];
 372         $super_body->(@_);
 373     });
 374     return;
 375 }
 376
 377 sub does_role {
 378     my ($self, $role_name) = @_;
 379
 380     (defined $role_name)
 381         || $self->throw_error("You must supply a role name to look for");
 382
 383     for my $class ($self->linearized_isa) {
 384         my $meta = Mouse::Util::get_metaclass_by_name($class)
 385             or next;
 386
 387         for my $role (@{ $meta->roles }) {
 388
 389             return 1 if $role->does_role($role_name);
 390         }
 391     }
 392
 393     return 0;
 394 }
 395
 396 1;
 397 __END__
 398
 399 =head1 NAME
 400
 401 Mouse::Meta::Class - The Mouse class metaclass
 402
 403 =head1 VERSION
 404
 405 This document describes Mouse version 0.40_07
 406
 407 =head1 METHODS
 408
 409 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 410
 411 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 412 one instance should exist for a given class.
 413
 414 =head2 C<< name -> ClassName >>
 415
 416 Returns the name of the owner class.
 417
 418 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 419
 420 Gets (or sets) the list of superclasses of the owner class.
 421
 422 =head2 C<< add_method(name => CodeRef) >>
 423
 424 Adds a method to the owner class.
 425
 426 =head2 C<< has_method(name) -> Bool >>
 427
 428 Returns whether we have a method with the given name.
 429
 430 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 431
 432 Returns a L<Mouse::Meta::Method> with the given name.
 433
 434 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 435
 436 =head2 C<< get_method_list -> Names >>
 437
 438 Returns a list of method names which are defined in the local class.
 439 If you want a list of all applicable methods for a class, use the
 440 C<get_all_methods> method.
 441
 442 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 443
 444 Return the list of all L<Mouse::Meta::Method> instances associated with
 445 the class and its superclasses.
 446
 447 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 448
 449 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 450 class.
 451
 452 =head2 C<< has_attribute(Name) -> Bool >>
 453
 454 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 455
 456 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 457
 458 Returns the L<Mouse::Meta::Attribute> with the given name.
 459
 460 =head2 C<< get_attribute_list -> Names >>
 461
 462 Returns a list of attribute names which are defined in the local
 463 class. If you want a list of all applicable attributes for a class,
 464 use the C<get_all_attributes> method.
 465
 466 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 467
 468 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 469 this class and its superclasses.
 470
 471 =head2 C<< linearized_isa -> [ClassNames] >>
 472
 473 Returns the list of classes in method dispatch order, with duplicates removed.
 474
 475 =head2 C<< new_object(Parameters) -> Instance >>
 476
 477 Creates a new instance.
 478
 479 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 480
 481 Clones the given instance which must be an instance governed by this
 482 metaclass.
 483
 484 =head2 C<< throw_error(Message, Parameters) >>
 485
 486 Throws an error with the given message.
 487
 488 =head1 SEE ALSO
 489
 490 L<Moose::Meta::Class>
 491
 492 L<Class::MOP::Class>
 493
 494 =cut
 495